Wolfram 语言与系统参考资料中心

Cot

参见
- Tan
- Coth
- Cos
- ArcCot
- CotDegrees
- Degree
- TrigToExp
- TrigExpand
相关指南
- 三角函数
技术笔记
- 初等超越函数
- 参见
  - Tan
  - Coth
  - Cos
  - ArcCot
  - CotDegrees
  - Degree
  - TrigToExp
  - TrigExpand
- 相关指南
  - 三角函数
- 技术笔记
  - 初等超越函数

Cot

Cot[z]

给出 z 的余切.

背景

Cot 是余切函数，三角学中的基本函数之一. 它被定义为正切函数的倒数：. 直角三角形中一个锐角的余切值在教科书上的等价定义是角的邻直角边与对边长度的比值.
当变量是的简单有理数倍时，Cot 会自动计算出精确值. 对一些更复杂的有理倍数，FunctionExpand 有时可用于算得显式的精确值. TrigFactorList 可将包含 Cot 的表达式因式分解为包含 Sin 和 Cos 的单项式. 若要使用角度值的变量，则可用符号 Degree 作为乘数（例如 Cot[30 Degree]）. 当给出精确数值表达式作为变量时，Cot 可以算出任意精度的数值结果. 对包含 Cot 的符号表达式，其他适用的操作运算有 TrigToExp、TrigExpand、Simplify 和 FullSimplify.
Cot 自动逐项作用于列表和矩阵. 相比之下，MatrixFunction 则可用于给出整个方阵的余切值（即用矩阵幂次代替普通幂次的余切函数的幂级数）而不是单个矩阵元素的余切值.
Cot 是周期函数，周期为，可由 FunctionPeriod 算出. Cot 满足恒等式，这其实与勾股定理等价. 余切函数的定义可由等式扩展到复数变量上，其中是自然对数的底数. Cot 在且是整数的这些点处取得极值 ComplexInfinity. Cot[z] 在原点处的级数展开为 $sum_(k=0)^infty((-1)^k 2^(2 k) TemplateBox[{{2, , k}}, BernoulliB] )/((2 k)!)z^(2 k-1)$ ，可由伯努利数 BernoulliB 构成的项表示.
Cot 的反函数是 ArcCot. 双曲余切函数是 Coth. 其他相关的数学函数有 Tan 和 Cos.

范例

打开所有单元关闭所有单元

基本范例 (6)

自变量以弧度为单位：

Wolfram Language code: Cot[Pi / 3]

用 Degree 指定自变量以度为单位：

Wolfram Language code: Cot[60Degree]

在一实数子集上绘图：

Wolfram Language code: Plot[Cot[x], {x, -Pi, Pi}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[Cot[z], {z, -π - 2I, π + 2I}, PlotLegends -> Automatic]

在 0级数展开：

Wolfram Language code: Series[Cot[x], {x, 0, 10}]

奇点处的渐近展开式：

Wolfram Language code: Series[Cot[x], {x, -π, 5}]

范围 (46)

数值计算 (6)

数值运算：

Wolfram Language code: Cot[1.2]

以高精度计算：

Wolfram Language code: N[Cot[12 / 10], 50]

输出精度与输入精度相一致：

Wolfram Language code: Cot[1.20000000000000000000000]

Cot 可接受复数：

Wolfram Language code: Cot[2.5 + I]

在高精度条件下高效计算 Cot：

Wolfram Language code: Cot[1.2`500]//Timing

Wolfram Language code: Cot[1.2`100000];//Timing

自动逐项计算数组中每个元素的值：

Wolfram Language code: Cot[ {{5π / 6, π / 2}, {3π / 2, -π / 6}}]

或用 MatrixFunction 计算矩阵形式的Cot 函数：

Wolfram Language code: MatrixFunction[Cot[#]&, {{5π / 6, π / 2}, {3π / 2, -π / 6}}]

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: Cot[Interval[{-π / 4, π / 4}]]

Wolfram Language code: Cot[CenteredInterval[1, 1 / 100]]

Wolfram Language code: Cot[CenteredInterval[2 + 3I, (1 + I) / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: Cot[Around[3, 0.01]]

特殊值 (5)

Cot 在固定点上的值：

Wolfram Language code: Table[Cot[n(π/6)], {n, 1, 5}]

无穷处的值：

Wolfram Language code: Cot[Infinity]

Wolfram Language code: Cot[ComplexInfinity]

Cot 的零点：

Wolfram Language code: Assuming[m∈Integers, Refine[Cot[π((1/2) + m)]]]

用 Solve 求 Cot 的零点：

Wolfram Language code: sol = Solve[Cot[x] == 0 && 0 < x < π, x]

替换结果：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[Cot[x], {x, 0, π}, Epilog -> Style[Point[{xzero, Cot[xzero]}], PointSize[Large], Red]]

Cot 的奇点：

Wolfram Language code: Assuming[m∈Integers, FullSimplify[Refine[Cot[π m]]]]

自动生成简单精确值：

Wolfram Language code: Cot[Pi / 6]

更复杂的情形需要使用 FunctionExpand：

Wolfram Language code: Cot[Pi / 8]

Wolfram Language code: FunctionExpand[%]

可视化 (3)

绘制 Cot 函数：

Wolfram Language code: Plot[Cot[x], {x, -π, π}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[Cot[z]], {z, -π - I, π + I}, IconizedObject[«PlotOptions»]]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[Cot[z]], {z, -π - I, π + I}, IconizedObject[«PlotOptions»]]

，绘制极坐标图：

Wolfram Language code:

Table[PolarPlot[Cot[k ϕ], {ϕ, 0.01, 3π}, Sequence[Frame -> True, Exclusions -> All, FrameTicks -> {{{-1, -0.5, 0, 0.5, 1}, None}, {{-1, -0.5, 0, 0.5, 1}, None}}, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-1, 1}, {-1, 1}}]], {k, 1, 4}]

函数属性 (13)

Cot 的实定义域：

Wolfram Language code: FunctionDomain[Cot[x], x]

复定义域：

Wolfram Language code: FunctionDomain[Cot[z], z, Complexes]

Cot 的值域是所有实数：

Wolfram Language code: FunctionRange[Cot[x], x, y]

Cot 是周期为的周期函数：

Wolfram Language code: FunctionPeriod[Cot[x], x]

Cot 是一个奇函数：

Wolfram Language code: Cot[-x]

Cot 具有镜像属性：

Wolfram Language code: FullSimplify[Cot[Conjugate[z]] == Conjugate[Cot[z]]]

Cot 不是解析函数：

Wolfram Language code: FunctionAnalytic[Cot[x], x]

但是，它是亚纯函数：

Wolfram Language code: FunctionMeromorphic[Cot[x], x]

Cot 在特定范围内是单调的：

Wolfram Language code: FunctionMonotonicity[Cot[x], x]

Wolfram Language code: FunctionMonotonicity[{Cot[x], 0 < x < π / 2}, x]

Cot 不是单射函数：

Wolfram Language code: FunctionInjective[Cot[x], x]

Wolfram Language code: Plot[{Cot[x], 1}, {x, -2π, 2π}]

Cot 是满射函数：

Wolfram Language code: FunctionSurjective[Cot[x], x]

Wolfram Language code: Plot[{Cot[x], 20}, {x, -2π, 2π}]

Cot 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[Cot[x], x]

在 π 的倍数处，Cot 有奇点和断点：

Wolfram Language code: FunctionSingularities[Cot[x], x]

Wolfram Language code: FunctionDiscontinuities[Cot[x], x]

Cot 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[Cot[x], x]

TraditionalForm 格式：

Wolfram Language code: Cot[α]//TraditionalForm

微分 (3)

一阶导数：

Wolfram Language code: D[Cot[x], x]

高阶导数：

Wolfram Language code: Table[D[Cot[x], {x, n}], {n, 1, 3}]

Wolfram Language code: Plot[Evaluate[%], {x, -π, π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

阶导数的公式：

Wolfram Language code: D[Cot[x], {x, n}]

Wolfram Language code: Table[%, {n, 1, 3}]//Activate//Simplify

积分 (3)

Cot 的不定积分：

Wolfram Language code: Integrate[Cot[x], x]

Cot 在一个周期上的定积分：

Wolfram Language code: Integrate[Cot[x], {x, -(π/2), (π/2)}, PrincipalValue -> True]

更多积分：

Wolfram Language code: Integrate[Cot[x]Sin[x], x]

Wolfram Language code: Integrate[Cot[z]^a, z]

级数展开式 (3)

使用 Series 求泰勒级数展开：

Wolfram Language code: Series[Cot[x], {x, π / 2, 7}]

围绕绘制 Cot 的前三个近似值：

Wolfram Language code:

terms = Normal@Table[Series[Cot[x], {x, π / 2, m}], {m, 0, 5, 2}];
Plot[{Cot[x], terms}, {x, 0, π}, PlotRange -> {{0, π}, Automatic}]

Cot 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[Cot[x], {x, 0, n}]

Cot 可被应用于幂级数：

Wolfram Language code: Cot[(π/2) + x + (x^2/2) + (x^3/3) + O[x]^4]

函数恒等式和化简 (6)

倍角的 Cot：

Wolfram Language code: Expand[Cot[2x], Trig -> True]

和的 Cot：

Wolfram Language code: TrigExpand[Cot[x + y]]

转换多倍角表达式：

Wolfram Language code: TrigExpand[Cot[4x]]

Wolfram Language code: TrigReduce[%]

将三角函数的和形式转换为积形式：

Wolfram Language code: TrigFactor[Cot[x] + Cot[y]]

假定为实数变量和，进行展开：

Wolfram Language code: ComplexExpand[Cot[x + I y]]

转换为复数指数：

Wolfram Language code: TrigToExp[Cot[z]]

函数表示 (4)

用 Tan 表示：

Wolfram Language code: Simplify[Tan[(Pi/2) - x]]

用 Jacobi 函数表示：

Wolfram Language code: Simplify[JacobiCS[z, 0]]

Wolfram Language code: Simplify[I JacobiNS[I z, 1]]

用 SphericalHarmonicY 表示：

Wolfram Language code: Simplify[Sqrt[1 / 2]SphericalHarmonicY[1, 0, θ, 0] / SphericalHarmonicY[1, -1, θ, 0]]

用 Mathieu 函数表示：

Wolfram Language code: Simplify[(MathieuC[1, 0, z]/MathieuS[1, 0, z])]

应用 (4)

生成去除极点的图形：

Wolfram Language code: Plot[Cot[x], {x, -Pi / 2, 3 / 2Pi}, Exclusions -> Sin[x] == 0]

在复平面生成图形：

Wolfram Language code: Plot3D[Re[Cot[x + I y]], {x, -Pi, Pi}, {y, 0, 3}]

余切函数将抛物线等角映射到单位圆盘中：

Wolfram Language code:

With[{parabola = Table[1 - x ^ 2 / 4 + I x, {x, 0, 20, 1 / 10}], pnts = Point[ReIm@#]&, opts = {Axes -> True, PlotRange -> All}}, 
{Graphics[pnts[parabola], opts], 
	Graphics[pnts[Cot[π / 4.Sqrt[parabola]] ^ 2], opts]}]

求解微分方程：

Wolfram Language code: DSolve[y'[x] + y[x] + Cot[x] == 0, y[x], x]

属性和关系 (12)

自动应用余切函数的基本奇偶性和周期性：

Wolfram Language code: Cot[x + Pi]

Wolfram Language code: Cot[-x]

Wolfram Language code: Cot[I x]

Wolfram Language code: 1 / Cot[x]

用 TrigFactorList 将 Cot 因式分解为 Sin 和 Cos：

Wolfram Language code: Cos[x] / Sin[x]

Wolfram Language code: TrigFactorList[Cot[x]]

包含三角函数的复杂表达式不会自动化简：

Wolfram Language code: Cot[z] + Tan[z]

Wolfram Language code: Simplify[%]

对参数进行假定的化简：

Wolfram Language code: Cot[-x + k Pi]

Wolfram Language code: Simplify[%, k∈Integers]

由反函数组成：

Wolfram Language code: {Cot[ArcCot[z]], Cot[2ArcCot[z]], Cot[3ArcCot[z]]}

Wolfram Language code: FunctionExpand[%]//Together

1 弧度是度：

Wolfram Language code: Cot[1] == CotDegrees[180 / π]//Simplify

求解三角方程：

Wolfram Language code: Reduce[Cot[z]^2 - 2Cot[z + Pi / 4] == 4, z]

求解零点和极点：

Wolfram Language code: Reduce[Cot[α x + β] == 0, x]

Wolfram Language code: Reduce[1 / Cot[α x + β] == 0, x]

求超越方程的数值根：

Wolfram Language code: FindRoot[Cot[z]^2 + 3Cot[z + Pi / 6] + z == 4, {z, 2}]

Cot 出现在许多数学方程的特例中：

Wolfram Language code:

{BesselJ[-(1/2), z] / BesselJ[(1/2), z], (MathieuC[1, 0, z]/MathieuS[1, 0, z]), JacobiCS[z, 0], JacobiSC[(π/2) - z, 0], JacobiNS[I z, 1], JacobiSN[(π I/2) - I z, 1], HypergeometricPFQ[{}, {(1/2)}, -z] / HypergeometricPFQ[{}, {(3/2)}, -z]}

计算符号余数和数值余数：

Wolfram Language code: Table[Residue[Cot[z]^k, {z, 0}], {k, 10}]

Wolfram Language code: (1/2π I)NIntegrate[Cot[z], {z, -(1/4), -(I/4), +(1/4), +(I/4), -(1/4)}]

Cot 是一个数值函数：

Wolfram Language code: Attributes[Cot]

Wolfram Language code: NumericQ[Cot[2 + E]]

可能存在的问题 (3)

机器精度输入不足以获得正确结果：

Wolfram Language code: Cot[10. ^ 30]

使用精确输入，得到正确结果：

Wolfram Language code: N[Cot[10 ^ 30], 20]

需要增大 $MaxExtraPrecision 的值：

Wolfram Language code: N[Cot[10 ^ 100], 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[Cot[10 ^ 100], 20]]

输出的精度可能比输入精度小得多：

Wolfram Language code: Cot[1.5707963267948966192213216916397514421]

巧妙范例 (6)

计算余切的积：

Wolfram Language code: Underoverscript[∏, k = 1, n - 1] Cot[z + (k π/n)]

假设是一个整数，对结果进行化简：

Wolfram Language code: Simplify[%, (n/2)∈Integers]

假设是一个整数，对结果进行化简：

Wolfram Language code: Simplify[%%, (n - 1/2)∈Integers]

对余切函数进行积分：

Wolfram Language code: Integrate[Cot[ArcTan[z]], z]

在整数点绘制 Cot：

Wolfram Language code: ArrayPlot[Table[ArcCot[Abs[Cot[x y]]], {x, -20, 20}, {y, -20, 20}]]

给出嵌套根式表示：

Wolfram Language code: Cot[(π/2^12)]//FunctionExpand

连分数是高度正则化的：

Wolfram Language code: ContinuedFraction[Cot[1], 22]

n 为整数时，Cot[n] 是一个超越数：

Wolfram Language code: Element[Cot[1], Algebraics]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Cot

更多信息

背景

范例

基本范例 (6)

范围 (46)

数值计算 (6)

特殊值 (5)

可视化 (3)

函数属性 (13)

微分 (3)

积分 (3)

级数展开式 (3)

函数恒等式和化简 (6)

函数表示 (4)

应用 (4)

属性和关系 (12)

可能存在的问题 (3)

巧妙范例 (6)

文本

CMS

APA

BibTeX

BibLaTeX

Cot

更多信息

背景

范例

基本范例 (6)

范围 (46)

数值计算 (6)

特殊值 (5)

可视化 (3)

函数属性 (13)

微分 (3)

积分 (3)

级数展开式 (3)

函数恒等式和化简 (6)

函数表示 (4)

应用 (4)

属性和关系 (12)

可能存在的问题 (3)

巧妙范例 (6)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX