WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CreateSemanticSearchIndex[source]

source 内のデータから検索索引を作成する．

CreateSemanticSearchIndex[{source1,…}]

ソース sourceiの集合から検索索引を作成する．

CreateSemanticSearchIndex[{source1val1,…}]

ソース sourceiを値 valiに関連付ける．

CreateSemanticSearchIndex[data,"name"]

検索索引に指定された名前を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
データソース  
注釈  
オプション  
DistanceFunction  
FeatureExtractor  
GeneratedAssetLocation  
Method  
OverwriteTarget  
WorkingPrecision  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

CreateSemanticSearchIndex

CreateSemanticSearchIndex[source]

source 内のデータから検索索引を作成する．

CreateSemanticSearchIndex[{source1,…}]

ソース sourceiの集合から検索索引を作成する．

CreateSemanticSearchIndex[{source1val1,…}]

ソース sourceiを値 valiに関連付ける．

CreateSemanticSearchIndex[data,"name"]

検索索引に指定された名前を与える．

詳細とオプション

  • CreateSemanticSearchIndexは，内容の意味的検索に使える特徴をテキストから抽出するために使われる．
  • 次は，source の可能な値である．
  • "string"プレーンな文字列
    File["path"]個々のファイル
    URL["url"]"url"のテキスト表現
    CloudObject[…]クラウドオブジェクト
    LocalObject[…]ローカルオブジェクト
    ContentObject[…]コンテンツオブジェクト
    {source1,source2,…}ソースのリスト
  • ソースには注釈が付けられる．同じソースからのものには同じ注釈が付けられる．
  • 次は，注釈を指定する可能な方法である．
  • {source1val1,…}ソースと関連付けられた値のリスト
    {source1,…}{val1,…}ソースと値の間の規則
  • 次は，許容される valiの形式である．
  • "string"文字列ラベル
    <|"tag1"v1,…|>タグとメタデータ値の連想
  • CreateSemanticSearchIndexは，以下のオプションをサポートする．
  • DistanceFunction EuclideanDistance使用する距離関数
    FeatureExtractor "MiniLM"テキストの断片から特徴をどのように抽出するか
    GeneratedAssetLocation $GeneratedAssetLocation索引の場所
    Method Automaticメソッドの詳細
    OverwriteTarget Automatic既存の場所に上書きするかどうか
    ProgressReporting$ProgressReporting計算の進捗状況を報告するかどうか
    WorkingPrecision "Real32"浮動小数点演算の精度
  • DistanceFunctionの可能な値には，EuclideanDistance，SquaredEuclideanDistance，CosineDistance，JaccardDissimilarity，HammingDistanceがある．
  • 次は，FeatureExtractorの可能な値である．
  • "MiniLM"SentenceBERTに基づくローカルモデル
    LLMConfigurationLLMに基づく文の埋込み
    fカスタムの抽出関数
  • カスタムの抽出器 f は，文字列のリストに作用して同じ長さのベクトルのリストを生成しなければならない．
  • より細かいオプションは，Method<|opt1val1|>を使って与えることができる．次は，optiの可能な値である．
  • "ContextPadding"断片間の最小のオーバーラップ
    "MaximumItemLength"テキストの断片の最大の長さ
    "MinimumItemLength"テキストの断片の最小の長さ
    "SplitPattern"Automatic長い文字列をどこで分割するか
  • 自動"SplitPattern"は，ラグラフ，改行，単語内のソーステキストを分割して，"MinimumItemLength"から"MaximumItemLength"までの長さの断片を作成しようとする．
  • 次は，WorkingPrecisionの可能な設定である．
  • "Integer8"-128から127までの符号付き8ビット整数
    "Real32"単精度実数（32ビット）
    "Real64"倍精度実数（64ビット）

例題

すべて開く すべて閉じる

例  (2)

新たなSemanticSearchIndexを作成する：

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Alice in Wonderland"], "Alice"]

意味的類似性でテキストの検索を行う：

Wolfram Language code: Short /@ SemanticSearch[index, "talking insect", MaxItems -> 4]

複数のラベル付きソースから索引を作成する：

Wolfram Language code: index = CreateSemanticSearchIndex[{ResourceData["Alice in Wonderland"] -> "Alice", ResourceData["Death in Venice"] -> "Venice"}]

最も類似している項目のラベルを回復する：

Wolfram Language code: SemanticSearch[index, "insects"]

スコープ  (6)

データソース  (4)

文字列から索引を作成する：

Wolfram Language code: CreateSemanticSearchIndex["Cats, with their mysterious charm and playful antics, effortlessly capture our hearts, prancing gracefully through sunbeams, curling up in cozy spots, and purring softly, reminding us of the joy they bring."]

ファイルから索引を作成する：

Wolfram Language code: CreateSemanticSearchIndex[File["ExampleData/USConstitution.txt"]]

URLから索引を作成する：

Wolfram Language code: CreateSemanticSearchIndex[URL["http://www.wolfram.com"]]

特定の名前で索引を作成する：

Wolfram Language code: CreateSemanticSearchIndex[ResourceData["Alice in Wonderland"], "Alice"]

注釈  (2)

ソースにラベルで注釈を付ける：

Wolfram Language code: index = CreateSemanticSearchIndex[{ResourceData["Friends, Romans, Countrymen"] -> "Caesar", ResourceData["JFK Inaugural Address"] -> "JFK"}]

各断片が対応するソースsラベルを継承する：

Wolfram Language code: index["Label"]

検索を実行するとラベルが返される：

Wolfram Language code: SemanticSearch[index, "honour"]

タグ付けされたメタデータがある注釈付きソース：

Wolfram Language code: CreateSemanticSearchIndex[{ResourceData["Alice in Wonderland"] -> <|"Author" -> "Lewis Carroll", "Date" -> 1865 |>, ResourceData["Friends, Romans, Countrymen"] -> <|"Author" -> "William Shakespeare", "Date" -> 1609|>}]

別のAssociationで注釈をん指定する：

Wolfram Language code: CreateSemanticSearchIndex[{ResourceData["Alice in Wonderland"], ResourceData["Friends, Romans, Countrymen"]} -> {<|"Author" -> "Lewis Carroll", "Date" -> 1865|>, <|"Author" -> "William Shakespeare", "Date" -> 1609|>}]

オプション  (11)

DistanceFunction  (1)

索引についてカスタムの距離関数を指定する：

Wolfram Language code: CreateSemanticSearchIndex[{"beautiful", "mysterious", "vibrant", "ancient"}, DistanceFunction -> CosineDistance]

デフォルトで，EuclideanDistanceが使われる：

Wolfram Language code: CreateSemanticSearchIndex[{"beautiful", "mysterious", "vibrant", "ancient"}]["Database"]["DistanceFunction"]

FeatureExtractor  (2)

カスタムの特徴抽出器を訓練する：

Wolfram Language code: fe = FeatureExtraction[TextWords@ResourceData["Declaration of Independence"]]

これを使って別のテキストから特徴を抽出する：

Wolfram Language code: CreateSemanticSearchIndex[ResourceData["A Far Country"], FeatureExtractor -> fe]

LLMベースの特徴抽出器を使う：

Wolfram Language code: CreateSemanticSearchIndex[{"hi there"}, FeatureExtractor -> LLMConfiguration["Model" -> {"OpenAI", "text-embedding-3-small"}]]

GeneratedAssetLocation  (3)

索引を格納するカスタムの場所を指定する：

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Declaration of Independence"], GeneratedAssetLocation -> "CloudObject"]

場所を取り出す：

Wolfram Language code: index["Location"]

デフォルトで，索引はローカルオブジェクトに格納される：

Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10]]["Location"]

ベクトル索引をファイルに格納する：

Wolfram Language code: file = File[FileNameJoin[{$TemporaryDirectory, "testfile"}]]
Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10], GeneratedAssetLocation -> file]

場所を取り出す：

Wolfram Language code: %["Location"]

ファイル参照からデータベースを再構築する：

Wolfram Language code: SemanticSearchIndex[File["/private/var/folders/05/v_ct9frn7zv4vy6f2q18y2r80000gn/T/testfile"]]

Method  (2)

複数の非常に短い項目を含むテキストを作成する：

Wolfram Language code: text = "abacus: a calculator that performs arithmetic functions by manually sliding counters on rods or in groovesa tablet placed horizontally on top of the capital of a column as an aid in supporting the architrave abaft: at or near or toward the stern of a ship or tail of an airplanepreposition abalone: any of various large edible marine gastropods of the genus Haliotis having an ear-shaped shell with pearly interior abandoned: forsaken by owner or inhabitants free from constraint";

テキスト全体が単一の断片として埋め込まれる：

Wolfram Language code: CreateSemanticSearchIndex[text]

項目の最短と最長の長さを調整して，より関連生が高いセクションに分割する：

Wolfram Language code: CreateSemanticSearchIndex[text, Method -> {"MinimumItemLength" -> 1, "MaximumItemLength" -> 64}]

数パラグラフのテキストを作成する：

Wolfram Language code: definitions = Map[StringJoin[#, ": ", WordDefinition[#]]&, RandomWord[50]]; Short[definitions]

非標準的な分離記号で上記パラグラフを繋ぐ：

Wolfram Language code: text = StringRiffle[definitions, " !!! "];

デフォルトの自動的なパラグラフと文の分離による結果は好ましいものではない：

Wolfram Language code: First@CreateSemanticSearchIndex[text]["Items"]

カスタムの分離パターンを使ってカスタムの分離記号を使って分離する：

Wolfram Language code: First@CreateSemanticSearchIndex[text, Method -> <|"SplitPattern" -> StringExpression["!!!"], "MinimumItemLength" -> 4|>]["Items"]

OverwriteTarget  (2)

索引の自動的な場所はその名前によって決定される：

Wolfram Language code: CreateSemanticSearchIndex[StringRiffle[RandomWord[10]], "myDB"]

デフォルトのOverwriteTargetAutomaticでは，衝突を避けるために新たな索引名が生成される：

Wolfram Language code: CreateSemanticSearchIndex[StringRiffle[RandomWord[10]], "myDB"]

強制的に上書きしたければOverwriteTargetTrueを使うとよい：

Wolfram Language code: CreateSemanticSearchIndex[StringRiffle[RandomWord[10]], "myDB", OverwriteTarget -> True]

OverwriteTargetFalseを使って厳密にチェックする：

Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10], "myDB", OverwriteTarget -> False]

OverwriteTargetFalseは，同じ索引名を別の場所で再度使用することも防ぐ：

Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10], "myDB", GeneratedAssetLocation -> File["myDBfile"], OverwriteTarget -> False]

ファイルを作成する：

Wolfram Language code: CreateFile@File["myIndexfile"]

デフォルトで，既存のファイルは上書きされない：

Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10], GeneratedAssetLocation -> File["myIndexfile"]]

OverwriteTargetTrueを使って既存のファイルを上書きする：

Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10], GeneratedAssetLocation -> File["myIndexfile"], OverwriteTarget -> True]

WorkingPrecision  (1)

ベクトルの埋込みにカスタムの作業精度を指定する：

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Shakespeare's Sonnets"], WorkingPrecision -> "Integer8"]

作業精度は索引のベクトルデータベースに格納される：

Wolfram Language code: index["Database"]

精度値を取り出す：

Wolfram Language code: index["Database"]["WorkingPrecision"]

アプリケーション  (2)

単語とその定義の間の逆マッピングを作成する：

Wolfram Language code: data = Map[StringRiffle[WordDefinition[#]] -> #&, WordList[]];

マッピングを使って索引を構築する：

Wolfram Language code: CreateSemanticSearchIndex[data, "definitions"]

クエリと定義をマッチングすることで辞書の逆検索を行う：

Wolfram Language code: SemanticSearch["definitions", "small land insect"]

書籍から引用する：

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Shakespeare's Sonnets"]]

厳密な言葉遣いが分からない状態で引用を検索する：

Wolfram Language code: SemanticSearch[index, "a day in the summer", MaxItems -> 1]

特性と関係  (1)

索引を作成し，埋込みを取り出す：

Wolfram Language code: text = "This is a sentence." semanticEmbeddings = Normal@CreateSemanticSearchIndex[text]["Embeddings"]; Short[semanticEmbeddings]

FeatureExtractは，指定された"SentenceVector"抽出器を使って同様の埋込みが作成できる：

Wolfram Language code: featureEmbeddings = FeatureExtract[{text}, "SentenceVector"]; Short@featureEmbeddings

考えられる問題  (2)

入力文字列は常にテキストとして解釈される：

Wolfram Language code: CreateSemanticSearchIndex["https://www.wolfram.com"]["Items"]

リンクを辿る場合はURLラッパーを使う：

Wolfram Language code: CreateSemanticSearchIndex[URL["https://www.wolfram.com"]]["Items"]//First//Short

Fileを使ってコンテンツをインポートする：

Wolfram Language code: File
Wolfram Language code: CreateSemanticSearchIndex[File["ExampleData/USConstitution.txt"]]["Items"]//First//Short

小さな項目が複数あるテキスト：

Wolfram Language code: text = "abacus: a calculator that performs arithmetic functions by manually sliding counters on rods or in groovesa tablet placed horizontally on top of the capital of a column as an aid in supporting the architrave abaft: at or near or toward the stern of a ship or tail of an airplanepreposition abalone: any of various large edible marine gastropods of the genus Haliotis having an ear-shaped shell with pearly interior abandoned: forsaken by owner or inhabitants free from constraint";

文字列の長さがデフォルトの最大長より短いので分割は行われない：

Wolfram Language code: index = CreateSemanticSearchIndex[text, Method -> {"MinimumItemLength" -> 1}]

項目の最大長を短くすると分割が行われる：

Wolfram Language code: index = CreateSemanticSearchIndex[text, Method -> {"MinimumItemLength" -> 1, "MaximumItemLength" -> 64}]
Wolfram Research (2024), CreateSemanticSearchIndex, Wolfram言語関数， https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html （2025年に更新）.

テキスト

Wolfram Research (2024), CreateSemanticSearchIndex, Wolfram言語関数， https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html （2025年に更新）.

CMS

Wolfram Language. 2024. "CreateSemanticSearchIndex." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html.

APA

Wolfram Language. (2024). CreateSemanticSearchIndex. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html

BibTeX

@misc{reference.wolfram_2026_createsemanticsearchindex, author="Wolfram Research", title="{CreateSemanticSearchIndex}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_createsemanticsearchindex, organization={Wolfram Research}, title={CreateSemanticSearchIndex}, year={2025}, url={https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html}, note=[Accessed: 09-September-2026]}