WOLFRAM

Wolfram 语言与系统参考资料中心

CreateSemanticSearchIndex[source]

从 source 中的数据创建搜索索引.

CreateSemanticSearchIndex[{source1,…}]

用一系列资源创建搜索索引 sourcei.

CreateSemanticSearchIndex[{source1val1,…}]

将资源 sourcei 与值 vali 关联在一起.

CreateSemanticSearchIndex[data,"name"]

为搜索索引指定名称.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
数据源  
注释  
选项  
DistanceFunction  
FeatureExtractor  
GeneratedAssetLocation  
Method  
OverwriteTarget  
WorkingPrecision  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

CreateSemanticSearchIndex

CreateSemanticSearchIndex[source]

从 source 中的数据创建搜索索引.

CreateSemanticSearchIndex[{source1,…}]

用一系列资源创建搜索索引 sourcei.

CreateSemanticSearchIndex[{source1val1,…}]

将资源 sourcei 与值 vali 关联在一起.

CreateSemanticSearchIndex[data,"name"]

为搜索索引指定名称.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

创建一个新的 SemanticSearchIndex：

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Alice in Wonderland"], "Alice"]

通过语义相似度在文本中搜索：

Wolfram Language code: Short /@ SemanticSearch[index, "talking insect", MaxItems -> 4]

创建包含多个带有标签的资源的索引：

Wolfram Language code: index = CreateSemanticSearchIndex[{ResourceData["Alice in Wonderland"] -> "Alice", ResourceData["Death in Venice"] -> "Venice"}]

获取最相似的项的标签：

Wolfram Language code: SemanticSearch[index, "insects"]

范围  (6)

数据源  (4)

从字符串创建索引：

Wolfram Language code: CreateSemanticSearchIndex["Cats, with their mysterious charm and playful antics, effortlessly capture our hearts, prancing gracefully through sunbeams, curling up in cozy spots, and purring softly, reminding us of the joy they bring."]

从文件创建索引：

Wolfram Language code: CreateSemanticSearchIndex[File["ExampleData/USConstitution.txt"]]

从 URL 创建索引：

Wolfram Language code: CreateSemanticSearchIndex[URL["http://www.wolfram.com"]]

创建具有特定名称的索引：

Wolfram Language code: CreateSemanticSearchIndex[ResourceData["Alice in Wonderland"], "Alice"]

注释  (2)

用标签注释资源：

Wolfram Language code: index = CreateSemanticSearchIndex[{ResourceData["Friends, Romans, Countrymen"] -> "Caesar", ResourceData["JFK Inaugural Address"] -> "JFK"}]

每个数据块都会继承相应的源的标签：

Wolfram Language code: index["Label"]

执行搜索时返回标签：

Wolfram Language code: SemanticSearch[index, "honour"]

用带有标记的元数据为资源添加注释：

Wolfram Language code: CreateSemanticSearchIndex[{ResourceData["Alice in Wonderland"] -> <|"Author" -> "Lewis Carroll", "Date" -> 1865 |>, ResourceData["Friends, Romans, Countrymen"] -> <|"Author" -> "William Shakespeare", "Date" -> 1609|>}]

用单独的 Association 指定注释：

Wolfram Language code: CreateSemanticSearchIndex[{ResourceData["Alice in Wonderland"], ResourceData["Friends, Romans, Countrymen"]} -> {<|"Author" -> "Lewis Carroll", "Date" -> 1865|>, <|"Author" -> "William Shakespeare", "Date" -> 1609|>}]

选项  (10)

DistanceFunction  (1)

自定义索引的距离函数：

Wolfram Language code: CreateSemanticSearchIndex[{"beautiful", "mysterious", "vibrant", "ancient"}, DistanceFunction -> CosineDistance]

默认情况下，使用 EuclideanDistance：

Wolfram Language code: CreateSemanticSearchIndex[{"beautiful", "mysterious", "vibrant", "ancient"}]["Database"]["DistanceFunction"]

FeatureExtractor  (1)

训练自定义特征提取器：

Wolfram Language code: fe = FeatureExtraction[TextWords@ResourceData["Declaration of Independence"]]

用它从另一个文本中提取特征：

Wolfram Language code: CreateSemanticSearchIndex[ResourceData["A Far Country"], FeatureExtractor -> fe]

GeneratedAssetLocation  (3)

指定存储数据库的自定义位置：

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Declaration of Independence"], GeneratedAssetLocation -> "CloudObject"]

检索位置：

Wolfram Language code: index["Location"]

默认情况下，数据库存储在本地对象中：

Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10]]["Location"]

将矢量数据库存储在文件中：

Wolfram Language code: file = File[FileNameJoin[{$TemporaryDirectory, "testfile"}]]
Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10], GeneratedAssetLocation -> file]

检索位置：

Wolfram Language code: %["Location"]

根据文件参考重新创建数据库：

Wolfram Language code: SemanticSearchIndex[File["/private/var/folders/05/v_ct9frn7zv4vy6f2q18y2r80000gn/T/testfile"]]

Method  (2)

创建包含多个非常短的条目的文本：

Wolfram Language code: text = "abacus: a calculator that performs arithmetic functions by manually sliding counters on rods or in groovesa tablet placed horizontally on top of the capital of a column as an aid in supporting the architrave abaft: at or near or toward the stern of a ship or tail of an airplanepreposition abalone: any of various large edible marine gastropods of the genus Haliotis having an ear-shaped shell with pearly interior abandoned: forsaken by owner or inhabitants free from constraint";

整个文本将作为一个块嵌入：

Wolfram Language code: CreateSemanticSearchIndex[text]

调整条目的最小和最大长度，将其划分成更多相关的部分：

Wolfram Language code: CreateSemanticSearchIndex[text, Method -> {"MinimumItemLength" -> 1, "MaximumItemLength" -> 64}]

创建多个文本段落：

Wolfram Language code: definitions = Map[StringJoin[#, ": ", WordDefinition[#]]&, RandomWord[50]]; Short[definitions]

用非标准分隔符将它们连接起来：

Wolfram Language code: text = StringRiffle[definitions, " !!! "];

默认的段落和句子划分会产生较差的结果：

Wolfram Language code: First@CreateSemanticSearchIndex[text]["Items"]

用自定义的分割模式在指定的分隔符处进行划分：

Wolfram Language code: First@CreateSemanticSearchIndex[text, Method -> <|"SplitPattern" -> StringExpression["!!!"], "MinimumItemLength" -> 4|>]["Items"]

OverwriteTarget  (2)

索引的位置由其名称自动确定：

Wolfram Language code: CreateSemanticSearchIndex[StringRiffle[RandomWord[10]], "myDB"]

如果采用默认的 OverwriteTargetAutomatic，将生成一个新的索引名称以避免冲突：

Wolfram Language code: CreateSemanticSearchIndex[StringRiffle[RandomWord[10]], "myDB"]

如果想强制覆盖，可使用 OverwriteTargetTrue：

Wolfram Language code: CreateSemanticSearchIndex[StringRiffle[RandomWord[10]], "myDB", OverwriteTarget -> True]

用 OverwriteTargetFalse 进行更严格的检查：

Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10], "myDB", OverwriteTarget -> False]

OverwriteTargetFalse 还将防止在不同位置重复使用相同的索引名称：

Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10], "myDB", GeneratedAssetLocation -> File["myDBfile"], OverwriteTarget -> False]

创建一个文件：

Wolfram Language code: CreateFile@File["myIndexfile"]

默认情况下，现有文件不会被覆盖：

Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10], GeneratedAssetLocation -> File["myIndexfile"]]

用 OverwriteTargetTrue 覆盖现有文件：

Wolfram Language code: CreateSemanticSearchIndex[RandomWord[10], GeneratedAssetLocation -> File["myIndexfile"], OverwriteTarget -> True]

WorkingPrecision  (1)

自定义嵌入向量的工作精度：

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Shakespeare's Sonnets"], WorkingPrecision -> "Integer8"]

工作精度被存储在索引的向量数据库中：

Wolfram Language code: index["Database"]

获取精度值：

Wolfram Language code: index["Database"]["WorkingPrecision"]

应用  (2)

创建单词及其定义之间的反向映射：

Wolfram Language code: data = Map[StringRiffle[WordDefinition[#]] -> #&, WordList[]];

用映射构建索引：

Wolfram Language code: CreateSemanticSearchIndex[data, "definitions"]

通过将查询与定义进行匹配在字典中进行反向查找：

Wolfram Language code: SemanticSearch["definitions", "small land insect"]

从书中检索引文：

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Shakespeare's Sonnets"]]

在不确知原文的情况下搜索引文：

Wolfram Language code: SemanticSearch[index, "a day in the summer", MaxItems -> 1]

属性和关系  (1)

创建索引并获取嵌入的内容：

Wolfram Language code: text = "This is a sentence." semanticEmbeddings = Normal@CreateSemanticSearchIndex[text]["Embeddings"]; Short[semanticEmbeddings]

FeatureExtract 可使用指定的 "SentenceVector" 提取器来创建类似的嵌入：

Wolfram Language code: featureEmbeddings = FeatureExtract[{text}, "SentenceVector"]; Short@featureEmbeddings

可能存在的问题  (2)

输入字符串始终被解释为文本：

Wolfram Language code: CreateSemanticSearchIndex["https://www.wolfram.com"]["Items"]

要访问该链接，请使用 URL 封装：

Wolfram Language code: CreateSemanticSearchIndex[URL["https://www.wolfram.com"]]["Items"]//First//Short

用 File 导入文件的内容：

Wolfram Language code: File
Wolfram Language code: CreateSemanticSearchIndex[File["ExampleData/USConstitution.txt"]]["Items"]//First//Short

包含多个短条目的文本：

Wolfram Language code: text = "abacus: a calculator that performs arithmetic functions by manually sliding counters on rods or in groovesa tablet placed horizontally on top of the capital of a column as an aid in supporting the architrave abaft: at or near or toward the stern of a ship or tail of an airplanepreposition abalone: any of various large edible marine gastropods of the genus Haliotis having an ear-shaped shell with pearly interior abandoned: forsaken by owner or inhabitants free from constraint";

不会进行分段，因为字符串的长度小于默认的最大值：

Wolfram Language code: index = CreateSemanticSearchIndex[text, Method -> {"MinimumItemLength" -> 1}]

减小最大长度以确保进行分段：

Wolfram Language code: index = CreateSemanticSearchIndex[text, Method -> {"MinimumItemLength" -> 1, "MaximumItemLength" -> 64}]
Wolfram Research (2024)，CreateSemanticSearchIndex，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html （更新于 2025 年）.

文本

Wolfram Research (2024)，CreateSemanticSearchIndex，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html （更新于 2025 年）.

CMS

Wolfram 语言. 2024. "CreateSemanticSearchIndex." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html.

APA

Wolfram 语言. (2024). CreateSemanticSearchIndex. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html 年

BibTeX

@misc{reference.wolfram_2026_createsemanticsearchindex, author="Wolfram Research", title="{CreateSemanticSearchIndex}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_createsemanticsearchindex, organization={Wolfram Research}, title={CreateSemanticSearchIndex}, year={2025}, url={https://reference.wolfram.com/language/ref/CreateSemanticSearchIndex.html}, note=[Accessed: 08-September-2026]}