Wolfram 语言与系统参考资料中心

CreateSystemModel

CreateSystemModel[sys]

根据系统模型 sys 创建一个 Modelica SystemModel.

CreateSystemModel[eqns,t]

创建自变量为 t 的系统方程 eqns 的模型.

CreateSystemModel[…,tspec]

创建变量和参数类型指定为 tspec 的模型.

CreateSystemModel[…,spec]

创建一个模型，其中参数值、初始值和模型关系由 spec 给出.

CreateSystemModel

CreateSystemModel[sys]

根据系统模型 sys 创建一个 Modelica SystemModel.

CreateSystemModel[eqns,t]

创建自变量为 t 的系统方程 eqns 的模型.

CreateSystemModel[…,tspec]

创建变量和参数类型指定为 tspec 的模型.

CreateSystemModel[…,spec]

创建一个模型，其中参数值、初始值和模型关系由 spec 给出.

范例

打开所有单元关闭所有单元

基本范例 (3)

基于 StateSpaceModel 创建模型：

Wolfram Language code: CreateSystemModel[StateSpaceModel[{{{0}}, {{1}}, {{1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

创建一个基于 TransferFunctionModel 的模型，并为其指定一个自定义名称：

Wolfram Language code: CreateSystemModel["MyTF", TransferFunctionModel[{{{1 + 2*s}}, 1 + s}, s]]

在现有界面周围用方程构建模型：

Wolfram Language code: model = CreateSystemModel[{v[t] == r i[t]}, t, <|"ExtendsModels" -> "Modelica.Electrical.Analog.Interfaces.OnePort"|>];

Wolfram Language code: model["ModelicaDisplay"]

范围 (50)

系统模型 (11)

创建一个单入单出模型 TransferFunctionModel：

Wolfram Language code: CreateSystemModel[TransferFunctionModel[{{{1 + 2*s}}, 1 + s}, s]]

创建一个单入单出模型 StateSpaceModel：

Wolfram Language code: CreateSystemModel[StateSpaceModel[{{{0}}, {{1}}, {{1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

多入多出：

Wolfram Language code:

CreateSystemModel[TransferFunctionModel[{{{1, 1, 1}, {1, 1, 1}}, 
  {{2 + s, 3 + s, 4 + s}, 
   {3 + s, 4 + s, 5 + s}}}, s]]

用传递函数模型中的参数创建模型：

Wolfram Language code:

CreateSystemModel[TransferFunctionModel[{{{p1 + 2*s}}, p2 + s}, 
 s]]

指定状态-空间模型的参数：

Wolfram Language code:

CreateSystemModel[StateSpaceModel[{{{a, 0}, {0, b}}, {{1, 0}, {0, 1}}, {{1, 1}}, {{0, 0}}}, 
 SamplingPeriod -> None, SystemsModelLabels -> None]]

定义传递函数模型的参数值：

Wolfram Language code:

CreateSystemModel[TransferFunctionModel[{{{p1 + 2*s}}, p2 + s}, 
 s], <|"ParameterValues" -> {p1 -> 1, p2 -> 2}|>]

给出状态-空间模型的参数值：

Wolfram Language code:

CreateSystemModel[StateSpaceModel[{{{a, 0}, {0, b}}, {{1, 0}, {0, 1}}, {{1, 1}}, {{0, 0}}}, 
 SamplingPeriod -> None, SystemsModelLabels -> None], <|"ParameterValues" -> {a -> 1, b -> 2}|>]

给出参数的类型和值：

Wolfram Language code:

CreateSystemModel[StateSpaceModel[{{{a, 0}, {0, b}}, {{1, 0}, {0, 1}}, {{1, 1}}, {{0, 0}}}, 
 SamplingPeriod -> None, SystemsModelLabels -> None], {a∈Reals, b∈"Modelica.Units.SI.Current"}, <|"ParameterValues" -> {a -> 1, b -> 2}|>]

根据离散传递函数模型创建模型：

Wolfram Language code:

CreateSystemModel[TransferFunctionModel[{{{1}}, (-1 + z)*(-0.605 + z)}, z, 
 SamplingPeriod -> 1]]

根据离散状态-空间模型创建模型：

Wolfram Language code:

CreateSystemModel[StateSpaceModel[{{{1, 0, 0}, {0, 2, 0}, {0, 0, 3}}, {{1}, {1}, {1}}, {{1, 1, 1}}, {{0}}}, 
 SamplingPeriod -> 2, SystemsModelLabels -> None]]

使用描述器系统：

Wolfram Language code:

CreateSystemModel[StateSpaceModel[{{{3, 0}, {0, 4}}, {{5}, {6}}, {{7, 8}}, {{9}}, {{1, 0}, {0, 2}}}, 
 SamplingPeriod -> None, SystemsModelLabels -> None]]

根据仿射状态空间模型创建模型：

Wolfram Language code:

CreateSystemModel[AffineStateSpaceModel[{{x2^2, x1 - x2}, {{1}, {1}}, 
  {x1}, {{0}}}, {x1, x2}, Automatic, {Automatic}, Automatic, 
 SamplingPeriod -> None]]

根据非线性状态空间模型创建模型：

Wolfram Language code:

CreateSystemModel[NonlinearStateSpaceModel[{{u1 - x1*x2, 
   1 + u1*x2}, {x1}}, {x1, x2}, 
 {u1}, {Automatic}, Automatic, SamplingPeriod -> None]]

根据离散输入输出模型创建模型：

Wolfram Language code:

CreateSystemModel[DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, 
    {{{{u1[0]}, {u1[1]}, {u1[2]}}}, {{0, 2, 1}}, 1, {"Discrete", 1}, {"Discrete", 1}, {1}, 
     {MissingDataMethod -> None, ResamplingMethod -> {"Interpolation", Int ... ime", "LastValue", "OutputCount", "OutputVariables", "Path", 
  "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StateCount", 
  "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]]

微分方程 (12)

创建一个方程组成的 ODE 方程组：

Wolfram Language code: model = CreateSystemModel[{u[t] == u'[t]}, t];

Wolfram Language code: model["ModelicaDisplay"]

指定任意阶数的方程. 自动完成高阶导数的减化：

Wolfram Language code: model = CreateSystemModel[{x''[t] + 1 / 10x'[t] + Sin[x[t]] == 1 / 2 Cos[t], x[0] == 0, x'[0] == 0}, t];

Wolfram Language code: model["ModelicaDisplay"]

定义多个方程组成的方程组：

Wolfram Language code:

model = CreateSystemModel[{Subscript[y, 1]'[t] == Subscript[y, 1][t] + Subscript[y, 2][t], Subscript[y, 2]'[t] == Subscript[y, 1][t] + Sin[t]}, t];

Wolfram Language code: model["ModelicaDisplay"]

定义一个带有代数约束的方程组，导致高指数 (high-index) 问题：

Wolfram Language code: model = CreateSystemModel[{x'[t] == y[t] ^ 2 + x[t]y[t], 2x[t] ^ 2 + y[t] ^ 2 == 1, x[0] == 0, y[0] == 1}, t];

Wolfram Language code: model["ModelicaDisplay"]

可用 WhenEvent 指定混合方程：

Wolfram Language code: model = CreateSystemModel[{y'[x] == -y[x], WhenEvent[y[x] < 0.1, y[x] -> y[x] + 0.1 * x], y[0] == 1}, x];

Wolfram Language code: model["ModelicaDisplay"]

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, {"y"}]

声明一个仅在离散时间变化的变量 a：

Wolfram Language code:

eqs = {y''[t] == -9.8, WhenEvent[y[t] - a[t] < 0, y'[t] -> -0.75 y'[t]], WhenEvent[Mod[t, 1] == 0, a[t] -> a[t] - 1], y[0] == 14, y'[0] == 5, a[0] == 13};

Wolfram Language code: model = CreateSystemModel[eqs, t, <|"DiscreteVariables" -> {a}|>];

模拟并绘制楼梯上弹跳球的模型：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, {"y", "a"}, Filling -> {2 -> 0}]

Wolfram 语言函数会被自动转换为 Modelica 等效模型：

Wolfram Language code: model = CreateSystemModel[{y'[x] == Floor[x], y[0] == 1}, x];

Wolfram Language code: model["ModelicaDisplay"]

指定缺省参数值：

Wolfram Language code:

model = CreateSystemModel[{x'[t] == par x[t], x'[0] == 2}, t, 
	<|"ParameterValues" -> {par -> 10}|>];

Wolfram Language code: model["ModelicaDisplay"]

指定 start 值：

Wolfram Language code: model = CreateSystemModel[{x'[t] == par x[t]}, t, <|"InitialValues" -> {x -> 10}|>];

Wolfram Language code: model["ModelicaDisplay"]

指定变量和参数的类型：

Wolfram Language code: model = CreateSystemModel[{x'[t] == par x[t], x'[0] == 0}, t, {par∈Reals, x∈"Modelica.Units.SI.Position"}];

Wolfram Language code: model["ModelicaDisplay"]

用 Indexed 表示数组：

Wolfram Language code: model = CreateSystemModel[{Indexed[u, 1]'[t] == 1, Indexed[u, 2]'[t] == 2}, t];

Wolfram Language code: model["ModelicaDisplay"]

方程中使用的函数被转换成 Modelica 中的函数：

Wolfram Language code: model = CreateSystemModel[{Unevaluated[Function[#1 + Sin[#2]]][1, u[t]] == u'[t]}, t];

Wolfram Language code: model["ModelicaDisplay"]

关联和函数 (4)

Association 被转换为一条记录：

Wolfram Language code: model = CreateSystemModel[<|par -> 9.8, x[t] -> None|>, t];

Wolfram Language code: model["ModelicaDisplay"]

用记录存储粒子的运动：

Wolfram Language code:

model = CreateSystemModel["particle", <|m -> 1, x[t] -> None, v[t] -> None|>, t, {"m"∈"Modelica.Units.SI.Mass", "x"∈"Modelica.Units.SI.Position", "v"∈"Modelica.Units.SI.Velocity"}];

Wolfram Language code: model["ModelicaDisplay"]

创建一个类别，分类规范函数来自 Function：

Wolfram Language code: model = CreateSystemModel[Function[r, (4/3)π r^3]];

Wolfram Language code: model["ModelicaDisplay"]

用 Module 引入保护变量：

Wolfram Language code: model = CreateSystemModel[Function[x, Module[{z = 3}, x + z]]];

Wolfram Language code: model["ModelicaDisplay"]

区域和 Graphics3D (2)

嵌入维度为 3 的区域可生成具有可视化和动态属性的对象：

Wolfram Language code: model = CreateSystemModel["MyCylinder", Cylinder[]]

用 "Modelica.Mechanics.MultiBody" 组件存储如 RegionMeasure、RegionCentroid 和 MomentOfInertia 这样的数据：

Wolfram Language code: model["LocalComponents"]

Graphics3D 对象输出，以制作可视化效果：

Wolfram Language code: CreateSystemModel["MyBallCAD", Graphics3D[Ball[]]]

DiscretizeGraphics 或 BoundaryDiscretizeGraphics 也许能够从 Graphics3D 生成一个区域：

Wolfram Language code: reg = DiscretizeGraphics[Graphics3D[Ball[]]];

Wolfram Language code: CreateSystemModel["ball", reg]

拟合模型与神经网络 (2)

使用 FittedModel 创建一个输入-输出块：

Wolfram Language code: data = {{0, 0.5}, {1, 1}, {2, 1.5}, {3, 2}, {4, 2.5}, {5, 3}};

Wolfram Language code: nlm = NonlinearModelFit[data, Log[a + b x ^ 2], {a, b}, x]

Wolfram Language code: model = CreateSystemModel[nlm]

给出一个输入，模拟并绘图：

Wolfram Language code:

Show[ListPlot[data], SystemModelPlot[model, {"y"}, 5, <|"Inputs" -> {"u" -> Function[t, t]}|>, PlotStyle -> RGBColor[0.880722, 0.611041, 0.142051]]]

根据经训练的或初始化的 NetChain 或 NetGraph 创建输入输出模块：

Wolfram Language code: model = CreateSystemModel[NetInitialize[NetChain[{LinearLayer[2, "Input" -> 1]}]]]

给出输入、模拟和绘图：

Wolfram Language code: SystemModelPlot[model, {"y[1]", "y[2]"}, 5, <|"Inputs" -> {"u[1]" -> Sin}|>]

模型命名 (3)

为创建的模型指定一个自定义名称：

Wolfram Language code:

model = CreateSystemModel["MySSM", StateSpaceModel[{{{0}}, {{1}}, {{1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]];

显示模型名称：

Wolfram Language code: model["ModelName"]

在包内创建模型：

Wolfram Language code:

model = CreateSystemModel["MyPackage.MySSM", StateSpaceModel[{{{0}}, {{1}}, {{1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]];

显示模型名称：

Wolfram Language code: model["ModelName"]

如果没有给出名称，则生成一个唯一的名称：

Wolfram Language code:

model = CreateSystemModel[StateSpaceModel[{{{0}}, {{1}}, {{1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]];

显示生成的模型名称：

Wolfram Language code: model["ModelName"]

为模型指定一个自定义名称：

Wolfram Language code: SetSystemModel[model, <|"ModelName" -> "MyModel"|>];

显示新的模型名称：

Wolfram Language code: model["ModelName"]

类型和连接器 (4)

创建一个输出块：

Wolfram Language code: eqs = {y[t] == Sin[t]};

将其作为实值返回：

Wolfram Language code: conns = {y∈"Modelica.Blocks.Interfaces.RealOutput"};

创建模型：

Wolfram Language code: model = CreateSystemModel[eqs, t, conns];

Wolfram Language code: model["ModelicaDisplay"]

创建一个衍生块：

Wolfram Language code: eqs = {y[t] == u'[t]};

定义输入和输出连接器：

Wolfram Language code: conns = {u∈"Modelica.Blocks.Interfaces.RealInput", y∈"Modelica.Blocks.Interfaces.RealOutput"};

创建模型：

Wolfram Language code: model = CreateSystemModel[eqs, t, conns];

Wolfram Language code: model["ModelicaDisplay"]

使用 Electrical 库中的连接器创建电阻：

Wolfram Language code:

eqs = {v[t] == r i[t], i[t] == QuantityVariable["p.i", "ElectricCurrent"][t], QuantityVariable["n.i", "ElectricCurrent"][t] == -QuantityVariable["p.i", "ElectricCurrent"][t], v[t] == QuantityVariable["p.v", "ElectricPotential"][t] - QuantityVariable["n.v", "ElectricPotential"][t]};

Wolfram Language code:

model = CreateSystemModel[eqs, t, {p∈"Modelica.Electrical.Analog.Interfaces.PositivePin", n∈"Modelica.Electrical.Analog.Interfaces.NegativePin"}];

Wolfram Language code: model["ModelicaDisplay"]

使用缩写形式来指代连接器：

Wolfram Language code: conns = {u∈"Interfaces.RealInput", y∈"Interfaces.RealOutput"};

Wolfram Language code: model = CreateSystemModel[{y[t] == u'[t]}, t, conns];

Wolfram Language code: model["ModelicaDisplay"]

初始值和参数值 (6)

给出变量的 start 值：

Wolfram Language code: model = CreateSystemModel[{x'[t] == par x[t]}, t, <|"InitialValues" -> {x -> 10}|>];

Wolfram Language code: model["ModelicaDisplay"]

给出参数的 start 值：

Wolfram Language code: model = CreateSystemModel[{x'[t] == par x[t]}, t, <|"InitialValues" -> {par -> 10}|>];

Wolfram Language code: model["ModelicaDisplay"]

如果 start 值和初始化方程同时存在，初始化方程的优先级较高：

Wolfram Language code: model = CreateSystemModel[{x'[t] == -x[t], x[0] == 2}, t, <|"InitialValues" -> {x -> 10}|>];

Wolfram Language code: model["ModelicaDisplay"]

Wolfram Language code: SystemModelPlot[model, {"x"}, 5]

用参数作为初始值：

Wolfram Language code: model = CreateSystemModel[{x'[t] == -x[t]}, t, <|"ParameterValues" -> {par -> 5}, "InitialValues" -> {x -> par}|>];

Wolfram Language code: model["ModelicaDisplay"]

给出参数值：

Wolfram Language code: model = CreateSystemModel[{x'[t] == par x[t]}, t, <|"ParameterValues" -> {par -> 10}|>];

Wolfram Language code: model["ModelicaDisplay"]

给出依赖于另一个参数的参数：

Wolfram Language code: model = CreateSystemModel[{x'[t] == p1 x[t], x[0] == p2}, t, <|"ParameterValues" -> {p1 -> -2, p2 -> -p1}|>];

Wolfram Language code: model["ModelicaDisplay"]

在部分模型上构建 (3)

创建一个模块，对输入加 1：

Wolfram Language code: eqs = {y[t] == u[t] + 1};

创建模块，扩展 SISO 模块的接口：

Wolfram Language code: model = CreateSystemModel[eqs, t, <|"ExtendsModels" -> "Blocks.Interfaces.SISO"|>];

Wolfram Language code: model["ModelicaDisplay"]

用简化形式指代现有界面：

Wolfram Language code: model = CreateSystemModel[{v[t] == r i[t]}, t, <|"ExtendsModels" -> "Analog.Interfaces.OnePort"|>];

Wolfram Language code: model["ModelicaDisplay"]

根据成对的字符串列表创建一个细目：

Wolfram Language code: model = CreateSystemModel[{{"a", ""}, {"b", "b case"}}, <|"ExtendsModels" -> "Enumeration"|>];

Wolfram Language code: model["ModelicaDisplay"]

仿真设置 (3)

给模型一个开始和停止时间：

Wolfram Language code:

model = CreateSystemModel[{u'[t] == Cos[u[t]]}, t, <|"SimulationSettings" -> {"StartTime" -> 1, 
	"StopTime" -> 5}|>]

模拟模型并绘图：

Wolfram Language code: SystemModelPlot[model, {"u"}]

选择 Runge–Kutta 法进行仿真：

Wolfram Language code:

model = CreateSystemModel[StateSpaceModel[{{{0}}, {{1}}, {{1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None], <|"SimulationSettings" -> {"Method" -> "RungeKutta"}|>];

显示模型仿真设置：

Wolfram Language code: model["SimulationSettings"]

设置模型的实时同步：

Wolfram Language code:

model = CreateSystemModel[StateSpaceModel[{{{0}}, {{1}}, {{1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None], <|"SimulationSettings" -> {"SynchronizeWithRealTime" -> True}|>];

显示模型仿真设置：

Wolfram Language code: model["SimulationSettings"]

选项 (2)

GeneratedAssetLocation (2)

默认情况下，从区域创建的模型会将资产文件导出到 $WolframDocumentsDirectory：

Wolfram Language code: model = CreateSystemModel[Cylinder[]]

使用 GeneratedAssetLocation 为资源指定一个位置：

Wolfram Language code: model = CreateSystemModel[Cylinder[], GeneratedAssetLocation -> FileNameJoin[{$TemporaryDirectory, "cyl.obj"}]]

默认情况下，从神经网络创建的模型将 ONNX 文件导出到 $WolframDocumentsDirectory：

Wolfram Language code: net = NetInitialize[NetChain[{LinearLayer[3, "Input" -> 2]}]];

Wolfram Language code: model = CreateSystemModel[net]

使用 GeneratedAssetLocation 指定结果的位置：

Wolfram Language code: model = CreateSystemModel[net, GeneratedAssetLocation -> FileNameJoin[{$TemporaryDirectory, "MyNet.onnx"}]]

应用 (7)

定义弹跳球的方程：

Wolfram Language code: eqs = {v[t] == h'[t], v'[t] == -9.81, WhenEvent[h[t] ≤ 0, v[t] -> -k v[t]], h[0] == 1};

创建模型：

Wolfram Language code: model = CreateSystemModel[eqs, t];

假定恢复系数为 95%，对模型进行仿真：

Wolfram Language code: sim = SystemModelSimulate[model, 10, <|"ParameterValues" -> {"k" -> 0.95}|>];

绘制高度随时间变化的情况：

Wolfram Language code: SystemModelPlot[sim, "h"]

创建 Lotka–Volterra 方程的模型，模拟掠食者-猎物关系：

Wolfram Language code: eqs = {pred'[t] == pred[t](δ prey[t] - γ), prey'[t] == prey[t](α - β pred[t])};

定义两个状态的初值，

Wolfram Language code: ieqs = {prey[0] == 10, pred[0] == 10};

定义参数值：

Wolfram Language code: pars = {α -> 0.1, β -> 0.02, γ -> 0.4, δ -> 0.02};

创建模型：

Wolfram Language code: model = CreateSystemModel[Join[eqs, ieqs], t, <|"ParameterValues" -> pars|>];

显示随着时间的推移掠食者和猎物的族群规模：

Wolfram Language code: sim = SystemModelSimulate[model, 100];

Wolfram Language code: SystemModelPlot[sim, {"pred", "prey"}]

较大的猎物增长参数将加快系统循环的速度：

Wolfram Language code: sims = SystemModelSimulate[model, 100, <|"ParameterValues" -> {"alpha" -> {0.1, 0.2, 0.3, 0.4}}|>];

Wolfram Language code: Partition[Map[SystemModelPlot[#, {"prey", "pred"}, PlotLabel -> α == #["alpha"]]&, sims], 2]//Grid

模拟两个连在一起的池子，第二个池子有泄漏的地方：

设置方程，包括初始方程和参数：

Wolfram Language code: pressureEqns = {p1[t] == ρ g h1[t], p2[t] == ρ g h2[t]};

Wolfram Language code: flowRate = (p1[t] - p2[t])(π pipeDia ^ 4) / (128 μ pipeLen);

Wolfram Language code: massConservation = {a1 h1'[t] == -flowRate, a2 h2'[t] == flowRate - a2 h2[t] / 10};

Wolfram Language code: eqns = Join[pressureEqns, massConservation, {h1[0] == 1, h2[0] == 0}];

创建模型，用给定参数值作为默认值：

Wolfram Language code: pars = {pipeLen -> 0.1, pipeDia -> 0.2, ρ -> 0.2, μ -> 2 10 ^ -3, g -> 9.81, a1 -> 1, a2 -> 1};

Wolfram Language code: model = CreateSystemModel[eqns, t, <|"ParameterValues" -> pars|>];

仿真：

Wolfram Language code: sim = SystemModelSimulate[model, 80];

随着时间的推移，最终两个池子都会被排干，因为第二个池子有泄漏：

Wolfram Language code: SystemModelPlot[sim, {"h1", "h2"}]

创建只在一个方向有阻尼的机械平移阻尼器：

Wolfram Language code: eqs = {f[t] == If[vrel[t] > 0, d * vrel[t], 0], vrel[t] == s⎵rel'[t]};

定义阻尼常数：

Wolfram Language code: pvals = {d -> 1};

用 Translational Mechanics library 中的部分界面创建阻尼：

Wolfram Language code: partial = "Translational.Interfaces.PartialCompliant";

Wolfram Language code: CreateSystemModel["UniDamper", eqs, t, <|"ParameterValues" -> pvals, "ExtendsModels" -> partial|>];

与双向阻尼器相比较：

Wolfram Language code: model = SystemModel["DocumentationExamples.Modeling.DamperCompare"]

Wolfram Language code: sim = SystemModelSimulate[model, 8]

Wolfram Language code: SystemModelPlot[sim, {"massUniDir.s", "massBiDir.s"}, PlotRange -> All]

创建数字低通滤波器：

Wolfram Language code: a = LeastSquaresFilterKernel[{"Lowpass", 0.1}, 20];

把滤波器转换为传递函数：

Wolfram Language code: h = ListZTransform[a, z];

Wolfram Language code: tf = TransferFunctionModel[h, z, SamplingPeriod -> 0.01]//TransferFunctionCancel

创建滤波器模型：

Wolfram Language code: lowpass = CreateSystemModel[tf];

创建信号发生源：

Wolfram Language code:

signal = CreateSystemModel["Signal", {y[t] == Abs[Sin[t Cos[2t]]]t}, t, <|"ExtendsModels" -> "Modelica.Blocks.Interfaces.SignalSource"|>];

把信号源连接到滤波器：

Wolfram Language code:

model = ConnectSystemModelComponents["FilteredSignal", {"signal"∈signal, "filter"∈lowpass}, {"signal.y""filter.u"}]

仿真并绘制输出信号和滤波后的信号：

Wolfram Language code:

sim = SystemModelSimulate[model, 10];
SystemModelPlot[sim, {"signal.y", "filter.y"}]

将区域与世界的组件一起使用以创建新模型，其中的物体会受到重力影响：

Wolfram Language code: model = CreateSystemModel["MyCylinder", Cylinder[]];

Wolfram Language code:

model2 = ConnectSystemModelComponents["FallingCylinder", {"cyl"∈"MyCylinder", "world"∈"Modelica.Mechanics.MultiBody.World"
	}, {}]

仿真并绘制质心的位置：

Wolfram Language code: sim = SystemModelSimulate[model2, 10];

Wolfram Language code: SystemModelPlot[sim, {"cyl.frame_a.r_0[2]"}]

可视化平行六面体的旋转现象：

Wolfram Language code: book = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {0, 1 / 2, 0}, {0, 0, 2 / 100}}];

Wolfram Language code: model = CreateSystemModel["Book", book]

通过更改世界组件中的参数来关闭重力，并为角速度提供一个初始值：

Wolfram Language code:

model2 = ConnectSystemModelComponents["RotatingBook", {"book"∈"Book", "world"∈"Modelica.Mechanics.MultiBody.World"}, {}, <|"ParameterValues" -> {"world.gravityType" -> QuantityVariable["Modelica.Mechanics.MultiBody.Types.GravityTypes.NoGravity", IndependentPhysicalQuantity[""]]}, "InitialValues" -> {"book.body.w_a" -> {0.1, 3, 0}}|>]

仿真并获取固定到物体上的框架的旋转矩阵：

Wolfram Language code: sim = SystemModelSimulate["RotatingBook", 10];

Wolfram Language code:

ℛ[t_] = {sim[{"book.frame_a.R.T[1,1]", "book.frame_a.R.T[2,1]", "book.frame_a.R.T[3,1]"}, t], 
	sim[{"book.frame_a.R.T[1,2]", "book.frame_a.R.T[2,2]", "book.frame_a.R.T[3,2]"}, t], 
	sim[{"book.frame_a.R.T[1,3]", "book.frame_a.R.T[2,3]", "book.frame_a.R.T[3,3]"}, t]};

可视化物体的旋转：

Wolfram Language code:

Manipulate[Graphics3D[{EdgeForm[Thick], GeometricTransformation[book, Composition[TranslationTransform[RegionCentroid[book]], LinearFractionalTransform[{ℛ[t]}], TranslationTransform[-RegionCentroid[book]]]]}, PlotRange -> {{-1 / 2, 3 / 2}, {-1 / 2, 3 / 2}, {-1, 1}}, Boxed -> False], {t, 0, 10, 0.1}, SaveDefinitions -> True]

属性和关系 (3)

SystemModel 属性可用来从模型中提取信息：

Wolfram Language code: origModel = SystemModel["DocumentationExamples.Basic.DiffEq"];

用来自现有模型的方程创建新模型，改变一个参数：

Wolfram Language code: eqs = origModel["SystemEquations", t];

Wolfram Language code: ivals = origModel["InitialValues"];

Wolfram Language code: newModel = CreateSystemModel[eqs, t, <|"ParameterValues" -> {"a" -> 2}, "InitialValues" -> ivals|>];

Wolfram Language code: newModel["ModelicaDisplay"]

仿真并比较两个模型：

Wolfram Language code: origSim = SystemModelSimulate[origModel, 5];

Wolfram Language code: newSim = SystemModelSimulate[newModel, 5];

Wolfram Language code: SystemModelPlot[{origSim, newSim}, {"y", "z"}]

特殊字符被转换成较长的格式：

Wolfram Language code: model = CreateSystemModel[{α'[t] == β[t], β'[t] == 0, α[0] == 0, β[0] == 0}, t];

Wolfram Language code: model["ModelicaDisplay"]

Subscript 被转换为 _：

Wolfram Language code: model = CreateSystemModel[{Subscript[x, 1]'[t] == -Subscript[x, 1][t], Subscript[x, 2][t] == 2Subscript[x, 1][t]}, t];

Wolfram Language code: model["ModelicaDisplay"]

可能存在的问题 (2)

除非明确保存，否则不保存模型：

Wolfram Language code: model = CreateSystemModel["NoSave", {x'[t] == par x[t]}, t];

退出 Wolfram 语言内核后，模型消失：

Wolfram Language code: Quit[]

Wolfram Language code: SystemModel["NoSave", "Summary"]

CreateSystemModel 支持 Wolfram 语音函数的子集：

Wolfram Language code: CreateSystemModel[{Subscript[x, 1]'[t] == Gamma[Subscript[x, 1][t]]}, t]

Top

	par_i∈type_i	参数类型 type_i
	var_i∈type_i	变量类型 type_i

域	力变量	流变量
电路	电压	电流
磁路	磁位	磁通量
平移力学	位置	力
转动力学	角度	转矩
三维力学	位置向量，定向对象	切割力向量，切割扭矩向量
流体流动系统	压力，比焓	质量流率，焓流率
热传导系统	温度	热流率
示意图	实数，整数，布尔值	-

"ParameterValues"	{p₁val₁,…}	参数值
"InitialValues"	{v₁val₁,…}	初始值
"ExtendsModels"	{partial₁,…}	所基于的部分模型
"DiscreteVariables"	{v₁,v₂,…}	仅在事件发生时变化的变量
"SimulationSettings"	{opt₁val₁,…}	模型仿真选项

	"DASSL"	DASSL DAE 求解器
	"CVODES"	CVODES ODE 求解器

	"InterpolationPoints"	插值点数
	"Tolerance"	自适应步长的公差

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

CreateSystemModel

更多信息和选项

范例

基本范例 (3)

范围 (50)

系统模型 (11)

微分方程 (12)

关联和函数 (4)

区域和 Graphics3D (2)

拟合模型与神经网络 (2)

模型命名 (3)

类型和连接器 (4)

初始值和参数值 (6)

在部分模型上构建 (3)

仿真设置 (3)

选项 (2)

GeneratedAssetLocation (2)

应用 (7)

属性和关系 (3)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

	"Method"	仿真方法
	"StartTime"	仿真开始时间
	"StopTime"	仿真停止时间

	"Euler"	显式 1 阶欧拉方法
	"Heun"	2 阶 Heun 方法
	"RungeKutta"	显式四阶 Runge-Kutta 法

CreateSystemModel

更多信息和选项

范例

基本范例 (3)

范围 (50)

系统模型 (11)

微分方程 (12)

关联和函数 (4)

区域和 Graphics3D (2)

拟合模型与神经网络 (2)

模型命名 (3)

类型和连接器 (4)

初始值和参数值 (6)

在部分模型上构建 (3)

仿真设置 (3)

选项 (2)

GeneratedAssetLocation (2)

应用 (7)

属性和关系 (3)

可能存在的问题 (2)

参见

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX