WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Cube[]

原点を中心とした，辺の長さが単位長の正立方体を表す．

Cube[l]

辺の長さが l の立方体を表す．

Cube[{θ,ϕ},…]

z 軸について θ 度，y 軸について ϕ 度回転された立方体を表す．

Cube[{x,y,z},…]

{x,y,z}に作られた立方体を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
グラフィックス  
指定  
スタイル付け  
領域  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Cube

Cube[]

原点を中心とした，辺の長さが単位長の正立方体を表す．

Cube[l]

辺の長さが l の立方体を表す．

Cube[{θ,ϕ},…]

z 軸について θ 度，y 軸について ϕ 度回転された立方体を表す．

Cube[{x,y,z},…]

{x,y,z}に作られた立方体を表す．

詳細とオプション

  • Cubeは単位立方体としても知られている．
  • Cubeは，幾何領域としてあるいはグラフィックスプリミティブとして使うことができる．
  • Cube[]はCube[{0,0,0},1]に等しい．
  • Cube[l]はCube[{0,0,0},l]に等しい．
  • CanonicalizePolyhedronを使って立方体を明示的なPolyhedronオブジェクトに変換することができる．
  • CubeはGraphics3Dで使うことができる．
  • グラフィックスでは，点と辺の長さはScaled式とDynamic式で測ることができる．
  • グラフィックスの描画は，FaceForm，EdgeForm，Opacity，Texture，色等の指示子の影響を受ける．
  • グラフィックスでは，次のオプションと設定が使える．
  • VertexColorsAutomatic補間される頂点の色
    VertexTextureCoordinatesNoneテクスチャの座標

例題

すべて開く すべて閉じる

例  (3)

立方体：

Wolfram Language code: Graphics3D[Cube[]]

スタイルが付いた立方体：

Wolfram Language code: ℛ = Cube[];
Wolfram Language code: {Graphics3D[{Pink, ℛ}], Graphics3D[{EdgeForm[Thick], ℛ}], Graphics3D[{EdgeForm[Dashed], ℛ}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

体積と重心：

Wolfram Language code: ℛ = Cube[{1, 2, 3}, 2];
Wolfram Language code: Volume[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

スコープ  (11)

グラフィックス  (8)

指定  (5)

単一の立方体：

Wolfram Language code: Graphics3D[Cube[]]

単位立方体：

Wolfram Language code: Graphics3D[Cube[], PlotRange -> 1.1]

辺の長さが明示的に指定された単位立方体：

Wolfram Language code: Graphics3D[Cube[1], PlotRange -> 1.1]

辺の長さが2の立方体：

Wolfram Language code: Graphics3D[Cube[2], PlotRange -> 1.1]

辺の長さが1/2で中心が(1/2, 1/2, 1/2)の立方体：

Wolfram Language code: Graphics3D[Cube[{1, 1, 1} / 2, 1 / 2], PlotRange -> 1.1]

軸の周りで45°回転された単位立方体：

Wolfram Language code: Graphics3D[Cube[{45°, 0}], PlotRange -> 2]

軸の周りで45°回転された単位立方体：

Wolfram Language code: Graphics3D[Cube[{0, 45°}], PlotRange -> 2]

辺の長さが2で， 軸の周りで45°， 軸の周りで45°回転された立方体：

Wolfram Language code: Graphics3D[Cube[{45°, 45°}, 2], PlotRange -> 2]

辺の長さが1，中心が(1/2, 1/2, 1/2)で， 軸の周りで45°， 軸の周りで45°回転された立方体：

Wolfram Language code: Graphics3D[Cube[{1, 1, 1} / 2, {45°, 45°}, 1], PlotRange -> 2]

スタイル付け  (3)

FaceFormとEdgeFormを使って面と辺のスタイルが指定できる：

Wolfram Language code: ℛ = Cube[];
Wolfram Language code: Graphics3D[{EdgeForm[{Thick, Dashed, Blue}], FaceForm[{Pink, Opacity[0.7]}], ℛ}, Boxed -> False]

Textureを面に適用する：

Wolfram Language code: ℛ = Cube[{0, 0, 0}, VertexTextureCoordinates -> Flatten[Table[{j / 2, i / 3}, {i, 0, 3}, {j, 0, 2}], 1]];
Wolfram Language code: Graphics3D[{Texture[[image]], ℛ}, Lighting -> "Neutral"]

VertexColorsを頂点に割り当てる：

Wolfram Language code: ℛ = Cube[{0, 0, 0}, VertexColors -> ColorData[54, "ColorList"]];
Wolfram Language code: Graphics3D[ℛ, Lighting -> "Neutral"]

領域  (3)

埋込み次元は立方体が存在する空間の次元である：

Wolfram Language code: ℛ = Cube[];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

幾何次元は形状それ自体の次元である：

Wolfram Language code: RegionDimension[ℛ]

重心：

Wolfram Language code: ℛ = Cube[];
Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}, Boxed -> False]

立方体は有界である：

Wolfram Language code: ℛ = Cube[];
Wolfram Language code: BoundedRegionQ[ℛ]

領域を求める：

Wolfram Language code: RegionBounds[ℛ]

おもしろい例題  (2)

立方体のコピーを 軸を中心に回転させて多角柱を作成する：

Wolfram Language code: Graphics3D[Table[Cube[{k Pi / 10, 0}], {k, 5}]]

双曲面を空間対角線を中心に回転した立方体の包絡線として表示する：

Wolfram Language code: zCube = GeometricTransformation[ Cube[], RotationTransform[{{1, 1, 1}, {0, 0, 1}}] ];
Wolfram Language code: Graphics3D[Table[GeometricTransformation[zCube, RotationTransform[k Pi / 15, {0, 0, 1}]], {k, 15}], ViewPoint -> {2, 0, 0}]
Wolfram Research (2019), Cube, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cube.html.

テキスト

Wolfram Research (2019), Cube, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cube.html.

CMS

Wolfram Language. 2019. "Cube." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Cube.html.

APA

Wolfram Language. (2019). Cube. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Cube.html

BibTeX

@misc{reference.wolfram_2026_cube, author="Wolfram Research", title="{Cube}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Cube.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cube, organization={Wolfram Research}, title={Cube}, year={2019}, url={https://reference.wolfram.com/language/ref/Cube.html}, note=[Accessed: 16-September-2026]}