Curl
詳細
- Curlは，循環密度としても知られている．
- Curl[f,x]は ∇xf と入力することができる．記号 ∇ は
del
または\[Del]とタイプし，記号 は
cross
または\[Cross]とタイプする．変数 x のリストは下付き文字として入力される． - 空のテンプレート ∇ は
delx
と入力する．
を使ってカーソルを下付き文字から移動することができる． - 与えられた変数に明示的に依存しない数量はすべて偏導関数が0であるとみなされる．
- Curl[f,{x1,…,xn}]では，f が深さ k<n の配列の場合，その次元は{n,…,n}でなければならない．結果の回転は次元{n,…,n}で深さ n-k-1の配列である．
- f がスカラーの場合，Curl[f,{x1,…,xn},chart]は chart に関連する正規直交基底で深さ n-1の配列を返す．
- Curl[f,{x1,…,xn},chart]では，f が配列の場合，f の成分は chart に関連する正規直交基底にあると解釈される．
- ユークリッド空間の座標グラフについては，Curl[f,{x1,…,xn},chart]は，f をデカルト座標に変換し，通常の回転を計算して再び chart に変換し直すことで計算できる． »
- Curlの第3引数中の座標チャートはトリプル{coordsys,metric,dim}として，CoordinateChartDataの第1引数における場合と同様に指定することができる．dim を省略した短縮形を使うこともできる．
- CurlはSparseArrayオブジェクトおよび構造配列オブジェクトに使うことができる．
例題
すべて開く すべて閉じる例 (4)
Curl[{f[x, y, z], g[x, y, z], h[x, y, z]}, {x, y, z}]Curl[{f[r, θ, z], g[r, θ, z], h[r, θ, z]}, {r, θ, z}, "Cylindrical"]Curl[{y, -x}, {x, y}]
del
で ∇ を，
で下付き文字にした変数のリストを，
cross
で を入力する：
Subscript[∇, {x, y, z}]⨯{y, -x, z}
delx
でテンプレート ∇ を入力し，変数を記入し，
を押してして関数を入力する：
Subscript[∇, {x, y, z}]⨯{y, -x, z}スコープ (6)
Curl[{r Sin[θ], -r Cos[θ]}, {r, θ}, "Polar"]曲線座標系では，一定の要素を持つベクトルであっても回転が零であることがある：
Curl[{1, 1, 1}, {r, θ, ϕ}, "Spherical"]//ExpandCurl[{{x y, x y^2, x y^3}, {x^2y, x^2y^2, x^2y^3}, {x^3y, x^3y^2, x^3y^3}}, {x, y, z}]Curl[{ψ, 0, ϕ θ}, {ψ, θ, ϕ}, {{"EllipticCylindrical", {a}}, "Euclidean"}]//SimplifyCurlはより高階の配列を作ることができる：
Curl[u ^ 2 v ^ 2 x ^ 2 y ^ 2 z ^ 2, {u, v, x, y, z}]TensorRank[%]Curlは曲がった空間に使うことができる：
Curl[{f[u, v], g[u, v]}, {u, v}, {"Stereographic", {"Sphere", 1}}]//FullSimplifyアプリケーション (3)
ベクトル場は，回転が零である場合，無回転または保存的であると呼ばれる：
v[x_, y_] := {Cos[x] Sin[y], Cos[y] Sin[x]}
Curl[v[x, y], {x, y}]これは，視覚的には，ベクトル場の流線が小さい閉じたループを形成しない傾向にあることを意味する：
StreamPlot[v[x, y], {x, -10, 10}, {y, -10, 10}, PlotRangePadding -> None]これは，解析的には，ベクトル場がスカラー関数の勾配として表せることを意味する．この関数は，原点から任意の点{x,y}までの回転をパラメータ化することで求められる：
c[t_] := t{x, y}スカラー関数は回転に沿った v の線積分を使って求めることができる：
φ[x_, y_] = Subsuperscript[∫, 0, 1]v@@c[t].c'[t]ⅆtGrad[φ[x, y], {x, y}] == v[x, y]ベクトル場は，球対称でラジアル成分のみを持つ場合は，中心的であると呼ばれる：
v[r_, θ_, φ_] := {f[r], 0, 0}Curl[v[r, θ, φ], {r, θ, φ}, "Spherical"]これは，v が勾配場であることを意味する．v には径方向依存性しかないので，u ポテンシャルの線積分は単純な一次元積分に簡約される：
u[r_, θ_, φ_] = Subsuperscript[∫, 0, r]v[s, θ, φ] . {1, 0, 0}ⅆsGrad[u[r, θ, φ], {r, θ, φ}, "Spherical"] == v[r, θ, φ]発散のないベクトル場はベクトルポテンシャルの回転として表すことができる：
B[r_, θ_, z_] := {0, 0, 1 / r }Div[B[r, θ, z], {r, θ, z}, "Cylindrical"]ベクトルポテンシャルを求めたければ，まず劣決定系を解かなければならない：
A[r_, θ_, z_] := {f[r, θ, z], g[r, θ, z], h[r, θ, z]}Thread[B[r, θ, z] == Curl[A[r, θ, z], {r, θ, z}, "Cylindrical"]]
と 
が定数であれば最初の2つの方程式が満たされる．その場合，3番目の方程式には 
という明らかな解がある：
B[r, θ, z] == Curl[{0, 1, 0}, {r, θ, z}, "Cylindrical"]特性と関係 (7)
Curlは完全に反対称の配列を作る：
cur = Curl[x y z, {x, y, z}]Transpose[cur] == - curTensorContract[cur, {{1, 2}}]Curl[Grad[f[x, y, z], {x, y, z}], {x, y, z}]Curl[Grad[{f[x, y, z], g[x, y, z], h[x, y, z]}, {x, y, z}], {x, y, z}]この恒等式はGradのInactive形によって順守される：
Curl[Inactive[Grad][f[x, y, z], {x, y, z}], {x, y, z}]Curl[Inactive[Grad][{f[x, y, z], g[x, y, z], h[x, y, z]}, {x, y, z}], {x, y, z}]次元 
では，Curlは階数が 
より低いテンソルについてのみ定義される：
Curl[f[x, y], {x, y}]Curl[{f[x, y], g[x, y]}, {x, y}]Curl[{{a[x, y], b[x, y]}, {c[x, y], d[x, y]}}, {x, y}]
Curlは，反対称化されたGradにHodgeDualへの呼出しが続いたものに比例する：
Curl[f[x, y], {x, y}] == HodgeDual@Symmetrize[Grad[f[x, y], {x, y}], Antisymmetric[All]]
f = {x ^ 2y, z x y, z ^ 3};r = TensorRank[f]Curl[f, {x, y, z}] == (-1)^r(r + 1)HodgeDual[Symmetrize[Grad[f, {x, y, z}], Antisymmetric[All]]]デカルト座標に変換して計算し，再びデカルト座標から変換し直すことで，ユークリッド座標グラフ c でCurlを計算する：
TransformedField["Spherical" -> "Cartesian", {f[r, θ, φ], g[r, θ, φ], h[r, θ, φ]}, {r, θ, φ} -> {x, y, z}]//MatrixFormCurl[%, {x, y, z}]//Simplify//MatrixFormFullSimplify[TransformedField["Cartesian" -> "Spherical", %, {x, y, z} -> {r, θ, φ}], r > 0 && 0 < θ < π && -π < φ < π]//MatrixForm結果は直接Curl[f,{x1,…,xn},c]を計算したものと同じである：
% == Curl[{f[r, θ, φ], g[r, θ, φ], h[r, θ, φ]}, {r, θ, φ}, "Spherical"]//FullSimplify次元 
では，スカラーの回転は階数 
のテンソルである．したがって，
の結果は階数2のテンソルである：
cur = Curl[x ^ 2 + y ^ 2 + z ^ 2, {x, y, z}]Normal[cur]
Curl[cur, {x, y, z}]スカラー場の二重回転はそのスカラーのラプラシアンである．二次元では次のようになる：
Curl[Curl[f[x, y], {x, y}], {x, y}]Laplacian[f[x, y], {x, y}]Curl[Curl[f[x, y, z], {x, y, z}], {x, y, z}]//CancelLaplacian[f[x, y, z], {x, y, z}]インタラクティブな例題 (1)
systems = {{"BipolarCylindrical", {a}}, {"Bispherical", {a}}, "Cartesian", "CircularParabolic", {"Conical", {b, c}}, "Cylindrical", {"EllipticCylindrical", {a}}, {"OblateSpheroidal", {a}}, "ParabolicCylindrical", {"ProlateSpheroidal", {a}}, "Spherical", {"Toroidal", {a}}};Manipulate[Block[{f, varNames, vars, vec},
varNames = CoordinateChartData[{Coordinates, 3}, "StandardCoordinateNames"];vars = ToExpression /@ varNames;
vec = Subscript[f, HoldForm[#]]@@vars& /@ varNames;
Inactive[Curl][vec, vars] == Simplify@Curl[vec, vars, {Coordinates}]], {{Coordinates, "Cartesian"}, systems}]テキスト
Wolfram Research (2012), Curl, Wolfram言語関数， https://reference.wolfram.com/language/ref/Curl.html （2014年に更新）.
CMS
Wolfram Language. 2012. "Curl." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Curl.html.
APA
Wolfram Language. (2012). Curl. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Curl.html