WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CurryApplied[f,n]

CurryApplied[f,n][x1]…[xn]が f[x1,…,xn]と等しくなるような，n 引数の関数 f の演算子形を表す．

CurryApplied[n]

関数に適用して n 引数の演算子形を表すことができるCurryAppliedの演算子形を表す．

CurryApplied[f,{i1,…,in}]

CurryApplied[f,{i1,…,in}][x1]…[xn]が f[xi1,…,xin]と等しくなるような，n 引数の関数 f の演算子形を表す．

CurryApplied[f,k{i1,…,in}]

k 個の引数を取る演算子形を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CurryApplied

CurryApplied[f,n]

CurryApplied[f,n][x1]…[xn]が f[x1,…,xn]と等しくなるような，n 引数の関数 f の演算子形を表す．

CurryApplied[n]

関数に適用して n 引数の演算子形を表すことができるCurryAppliedの演算子形を表す．

CurryApplied[f,{i1,…,in}]

CurryApplied[f,{i1,…,in}][x1]…[xn]が f[xi1,…,xin]と等しくなるような，n 引数の関数 f の演算子形を表す．

CurryApplied[f,k{i1,…,in}]

k 個の引数を取る演算子形を表す．

詳細

  • CurryApplied[f,arity][x1,…][y1,…]…[z1,…]はCurryApplied[f,arity][x1,…,y1,…,z1,…]に等しいので，ブラケット構造は関係なく，引数の数のみが関係する．
  • CurryApplied[f,n]はCurryApplied[f,{1,2,…,n}]に等しい．
  • CurryApplied[f,{i1,…,in}]はCurryApplied[f,Max[{i1,…,in}]{i1,…,in}]に等しい．
  • CurryApplied[f,{i1,…,in,opts}][x1]…[xk]は，連続するオプション opts について f[xi1,…,xin,opts]に等しい．
  • CurryApplied[f,{i1,…,in}]のカリー化された ip番目の引数は f の p 番目の引数である．
  • CurryApplied[arity][f]はCurryApplied[f,arity]に等しい．

例題

すべて開く すべて閉じる

例  (3)

2引数の関数をカリー化する：

Wolfram Language code: CurryApplied[f, 2][x][y]

CurryAppliedの演算子形を使って同じことを行う：

Wolfram Language code: CurryApplied[2][f][x][y]

3引数の関数を，引数の順序を保ってカリー化する：

Wolfram Language code: CurryApplied[f, 3][x][y][z]

これは，2つの積分変数をカリー化する，カリー化した形のIntegrateである：

Wolfram Language code: CurryApplied[Integrate, {3, 1, 2}][x][y]

これを変数 と を持つ関数に適用する：

Wolfram Language code: %[x Sin[y]]

上記は以下と等価である：

Wolfram Language code: Integrate[x Sin[y], x, y]

スコープ  (7)

2引数の関数の最初の引数をカリー化する：

Wolfram Language code: truncatedJD = CurryApplied[2][JulianDate]["Truncated"];

この関数を任意の日付オブジェクトに適用する：

Wolfram Language code: truncatedJD[Now]
Wolfram Language code: truncatedJD[DateObject[{2000, 1, 1, 12, 0, 0}, TimeZone -> 0]]

関数の第2引数をカリー化する：

Wolfram Language code: Dx = CurryApplied[{2, 1}][D][x]

この演算子を適用する：

Wolfram Language code: Dx[f[x]]

3引数の関数を，引数の順序を保ってカリー化する：

Wolfram Language code: CurryApplied[Nest, 3][f][x][4]

3引数の関数を，引数が関数に渡される前に置換を適用してカリー化する：

Wolfram Language code: CurryApplied[Nest, {3, 1, 2}][x][4][f]

以下は4つの引数を取るカリー化された演算子であるが，その内の2つしか関数 f には渡されない：

Wolfram Language code: CurryApplied[f, {2, 4}][a][b][c][d]
Wolfram Language code: CurryApplied[f, 4 -> {2, 3}][a][b][c][d]

カリー化された関数の引数を任意のブラケット構造で使う：

Wolfram Language code: op = CurryApplied[f, 3]
Wolfram Language code: op[a][b][c]
Wolfram Language code: op[a, b, c]
Wolfram Language code: op[a, b][c]
Wolfram Language code: op[][a][][][b, c]

Levelをデフォルトのオプション値でカリー化する：

Wolfram Language code: Sin[x[0] + 3]//CurryApplied[Level, {2, 1}][2]

オプションをLevelに渡す：

Wolfram Language code: Sin[x[0] + 3]//CurryApplied[Level, {2, 1, Heads -> True}][2]
Wolfram Language code: Sin[x[0] + 3]//CurryApplied[Level[##, Heads -> True]&, {2, 1}][2]

アプリケーション  (4)

3つの関数のCompositionをカリー化する：

Wolfram Language code: CurryApplied[Composition, 3]

3つの関数を連続的にフィードする：

Wolfram Language code: %[f]
Wolfram Language code: %[g]
Wolfram Language code: %[h]

この組合せを式に適用する：

Wolfram Language code: Construct[%, x]

構築する関数の引数の数を指定する：

Wolfram Language code: CurryApplied[Composition, 3][f, g, h, x, y]

下付き文字が付いた変数の配列を構築する：

Wolfram Language code: Array[CurryApplied[Subscript, 4][x], {2, 3, 2}]

CurryAppliedを使ってKとSの結合子を構築する：

Wolfram Language code: k = CurryApplied[Identity, 2 -> {1}]; s = CurryApplied[Function[#1[#3][#2[#3]]], 3];

SKKとSKSの組合せは恒等式に等しい：

Wolfram Language code: s[k][k][x]
Wolfram Language code: s[k][s][x]

SとKを使ってBとCの結合子を構築する：

Wolfram Language code: b = s[k[s]][k]; c = s[s[k[s[k[s][k]]][s]][k[k]]];
Wolfram Language code: b[f][g][x]
Wolfram Language code: c[f][x][y]

特性と関係  (7)

CurryApplied[f,arity]はOperatorApplied[f,arity]と同じ演算子を表す：

Wolfram Language code: CurryApplied[f, 3][a][b][c]
Wolfram Language code: OperatorApplied[f, 3][a][b][c]

CurryApplied[n][f]はCurryApplied[f,n]に等しい：

Wolfram Language code: CurryApplied[2][f][x][y]
Wolfram Language code: CurryApplied[f, 2][x, y]

OperatorApplied[f]はOperatorApplied[f,{2,1}]に等しい：

Wolfram Language code: OperatorApplied[f][x][y]
Wolfram Language code: OperatorApplied[f, {2, 1}][x][y]

CurryApplied[f,0]は，引数がない関数については f[]を返す：

Wolfram Language code: CurryApplied[f, 0]

追加の引数が与えられた場合でも，空のブラケットペアが挿入される：

Wolfram Language code: CurryApplied[f, 0][a, b]

CurryApplied自体をカリー化する：

Wolfram Language code: CurryApplied[2][CurryApplied][f][3][a][b][c]

Constructと比較する：

Wolfram Language code: Construct[f, a, b, c]

CurryApplied[Construct,n][f]は，正の n についてはCurryApplied[f,n-1]と等価である：

Wolfram Language code: CurryApplied[Construct, 3][f][a][b][c]
Wolfram Language code: CurryApplied[f, 2][a][b][c]

この関係は n=1のときも成り立つ：

Wolfram Language code: CurryApplied[Construct, 1][f]
Wolfram Language code: CurryApplied[f, 0]

2つのCurryApplied演算子を置換とその逆の操作で構築する：

Wolfram Language code: perm = {2, 4, 1, 3} invperm = InversePermutation[perm]

結果は引数の並べ替えをしないでCurryAppliedを使った場合と同じである：

Wolfram Language code: CurryApplied[CurryApplied[f, perm], invperm][a][b][c][d]
Wolfram Language code: CurryApplied[f, 4][a][b][c][d]

同じ長さの2つの置換リストを取る：

Wolfram Language code: perm1 = {2, 4, 1, 3}; perm2 = {3, 2, 4, 1};

対応するCurryApplied演算子を構築する：

Wolfram Language code: CurryApplied[CurryApplied[f, perm1], perm2][a][b][c][d]

あるいは，CurryAppliedを同じ順序でそれらの置換の積と共に使う：

Wolfram Language code: CurryApplied[f, PermutationProduct[perm1, perm2]][a, b, c, d]
Wolfram Research (2020), CurryApplied, Wolfram言語関数， https://reference.wolfram.com/language/ref/CurryApplied.html.

テキスト

Wolfram Research (2020), CurryApplied, Wolfram言語関数， https://reference.wolfram.com/language/ref/CurryApplied.html.

CMS

Wolfram Language. 2020. "CurryApplied." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CurryApplied.html.

APA

Wolfram Language. (2020). CurryApplied. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CurryApplied.html

BibTeX

@misc{reference.wolfram_2026_curryapplied, author="Wolfram Research", title="{CurryApplied}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CurryApplied.html}", note=[Accessed: 07-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_curryapplied, organization={Wolfram Research}, title={CurryApplied}, year={2020}, url={https://reference.wolfram.com/language/ref/CurryApplied.html}, note=[Accessed: 07-October-2026]}