WOLFRAM

Wolfram 语言与系统参考资料中心

Cylinder[{{x1,y1,z1},{x2,y2,z2}},r]

表示半径为 r 围绕从 (x1,y1,z1) 到 (x2,y2,z2) 的线段的圆柱体.

Cylinder[{{x1,y1,z1},{x2,y2,z2}}]

表示半径为1的圆柱体.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式化  
坐标  
区域  
应用  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Cylinder

Cylinder[{{x1,y1,z1},{x2,y2,z2}},r]

表示半径为 r 围绕从 (x1,y1,z1) 到 (x2,y2,z2) 的线段的圆柱体.

Cylinder[{{x1,y1,z1},{x2,y2,z2}}]

表示半径为1的圆柱体.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (4)

下面的圆柱体半径为1个单位，高度为2个单位：

Wolfram Language code: Graphics3D[Cylinder[]]

从原点到 {1,1,1}、半径为 1/2的圆柱体：

Wolfram Language code: Graphics3D[Cylinder[{{0, 0, 0}, {1, 1, 1}}, 1 / 2]]

各种样式的圆柱体：

Wolfram Language code: {Graphics3D[{Yellow, Cylinder[]}], Graphics3D[{EdgeForm[Thick], Cylinder[]}], Graphics3D[{EdgeForm[Dashed], Cylinder[]}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Yellow, Cylinder[]}]}

体积和质心：

Wolfram Language code: Volume[Cylinder[{{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, r]]
Wolfram Language code: RegionCentroid[Cylinder[{{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, r]]

范围  (23)

图形  (13)

规范  (5)

如果不指定半径尺寸，则假定为1：

Wolfram Language code: Graphics3D[Cylinder[{{0, 0, 0}, {0, 0, 1}}]]

具有不同半径的圆柱体：

Wolfram Language code: Graphics3D[{Cylinder[{{0, 0, 3}, {0, 0, -3}}, 1], Cylinder[{{5, 0, 3}, {5, 0, -3}}, 3]}]

沿不同方向放置的圆柱体：

Wolfram Language code: Graphics3D[{Cylinder[{{0, 0, 0}, {1, 0, 0}}], Cylinder[{{1, 1, 1}, {2, 3, 1}}]}]

中心在原点、半径为1的圆柱体的简写形式：

Wolfram Language code: Graphics3D[Cylinder[], Axes -> True]

多个圆柱体：

Wolfram Language code: s = {{0, 0, 0}, {0, 0, 2}};
Wolfram Language code: Graphics3D[Cylinder[{s, s + 2}]]

样式化  (5)

颜色指令指定圆柱体表面的颜色：

Wolfram Language code: Table[Graphics3D[{c, Cylinder[]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定表面和边缘的样式：

Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Cylinder[]}]

使用 FaceForm 可以指定前面和背面的不同属性：

Wolfram Language code: Graphics3D[{FaceForm[Yellow, Blue], Cylinder[]}, PlotRange -> {{-1, 1}, {-.8, 1}, {-1, 1}}]

具有不同镜面指数的圆柱体：

Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], Cylinder[]}, Lighting -> {{"Point", White, Scaled[{2, -1, 1.2}]}}], {n, {5, 20, 100}}]

发红光的黑色圆柱体：

Wolfram Language code: Graphics3D[{Glow[Red], Black, Cylinder[]}]

Opacity 指定表面不透明度：

Wolfram Language code: Table[Graphics3D[{Opacity[o], Cylinder[]}], {o, {0.3, 0.5, 0.9}}]

坐标  (3)

使用 Scaled 坐标：

Wolfram Language code: Graphics3D[Cylinder[{Scaled[{.5, .5, .2}], Scaled[{.5, .5, .8}]}, 3], PlotRange -> {{0, 10}, {0, 10}, {0, 10}}, Axes -> True]

使用 Scaled 半径：

Wolfram Language code: Graphics3D[Cylinder[{{0, 0, -1}, {0, 0, 1}}, Scaled[0.25]], Axes -> True, PlotRange -> 1]

点可以是 Dynamic：

Wolfram Language code: DynamicModule[{x}, {VerticalSlider[Dynamic[x], {0, 1}], Graphics3D[Cylinder[{Dynamic[x{0, 0, 1}], {0, 0, -1}}, 1]]}]

区域  (10)

嵌入维度是圆柱体所在空间的维度：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

几何维度是形状自身的维度：

Wolfram Language code: RegionDimension[ℛ]

成员检验：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: {RegionMember[ℛ, {(1/3), (1/3), (1/3)}], RegionMember[ℛ, {5, 5, 5}]}

获取成员条件：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

体积：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

质心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

距一个点的距离：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1 / 2, 1}}, 2];
Wolfram Language code: {RegionDistance[ℛ, {1., 2, 3}], RegionDistance[ℛ, {(1/3), (1/4), (1/5)}]}

圆柱体的等距轮廓：

Wolfram Language code: ContourPlot3D[Evaluate@RegionDistance[ℛ, {x, y, z}], {x, -3, 4}, {y, -3, 4}, {z, -3, 4}, Mesh -> None, Contours -> {0.25, 0.5, 1}, ContourStyle -> ColorData[94, "ColorList"], Lighting -> "Neutral", BaseStyle -> Opacity[0.5], BoxRatios -> Automatic]

距一个点的带符号距离：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2, 3}], SignedRegionDistance[ℛ, {(1/3), (1/4), (1/5)}]}

区域中的最近点：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: {RegionNearest[ℛ, {1, 2, 3}], RegionNearest[ℛ, {(1/3), (1/4), (1/5)}]}

到一个封闭球的最近点：

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 3]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

圆柱体是有界的：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: BoundedRegionQ[ℛ]

求范围：

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

在圆柱体区域上积分：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: Integrate[x + y + z, {x, y, z}∈ℛ]

在圆柱体区域上最优化：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

求解圆柱体区域上的方程：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -1 && z^2 == x y && {x, y, z}∈ℛ, {x, y, z}]

应用  (6)

求体积为 的圆柱体的最小表面积：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {0, 0, h}}, r];
Wolfram Language code: Minimize[{Area[RegionBoundary[ℛ]], Volume[ℛ] == 2π && r > 0 && h > 0}, {r, h}]

与具有相同体积的其他圆柱体比较：

Wolfram Language code: Graphics3D[#, PlotLabel -> Area[RegionBoundary[#]]]& /@ Diagonal@Table[ℛ, {r, {1 / 2, 1, 2}}, {h, {8, 2, 1 / 2}}]

柏拉图多面体：

Wolfram Language code: {v, e} = Transpose[PolyhedronData["Platonic", {"Vertices", "Edges"}]];
Wolfram Language code: Row@MapThread[Graphics3D[{Specularity[White, 30], EdgeForm[], Orange, GraphicsComplex[#1, {Table[Sphere[i, .2], {i, Length[#1]}], (Cylinder[#, .1]& /@ #2)}]}, Boxed -> False, Method -> {"ShrinkWrap" -> True}]&, {v, e}]

一个简单的三维条形图：

Wolfram Language code: data = RandomReal[{1, 10}, {12, 4}];
Wolfram Language code: Graphics3D[MapIndexed[{Hue[(Last[#2] - 1) / 4], Cylinder[{Append[{1, 2}#2, 0], Append[{1, 2}#2, #1]}, .4]}&, data, {2}], Axes -> {False, False, True}, Lighting -> "Neutral"]

使用 Cylinder 渲染 GraphPlot3D 中的边：

Wolfram Language code: GraphPlot3D[Table[i -> Mod[i ^ 2, 50], {i, 0, 50}], EdgeShapeFunction -> ({Cylinder[#1[[{1, -1}]], 0.1]}&), VertexShapeFunction -> ({Sphere[#, 0.3]}&)]

根据 Cylinder 定义 ChartElementFunction：

Wolfram Language code: CylinderBar[{{xmin_, xmax_}, {ymin_, ymax_}, {zmin_, zmax_}}, ___] := Cylinder[{{(xmin + xmax) / 2, (ymin + ymax) / 2, zmin}, {(xmin + xmax) / 2, (ymin + ymax) / 2, zmax}}, Min[(xmax - xmin) / 2, (ymax - ymin) / 2]]
Wolfram Language code: data = RandomReal[1, {2, 5}];
Wolfram Language code: BarChart3D[data, ChartElementFunction -> CylinderBar]

BarChart3D 使用 Cylinder 生成三维条形图：

Wolfram Language code: BarChart3D[data, ChartElementFunction -> "Cylinder"]

Histogram3D 可以相似地使用 Cylinder：

Wolfram Language code: Histogram3D[RandomReal[NormalDistribution[0, 1], {500, 2}], 10, ChartElementFunction -> "Cylinder"]

使用 Cylinder 显示 BubbleChart3D 中的气泡：

Wolfram Language code: BubbleChart3D[RandomReal[1, {3, 10, 4}], ChartElements -> Graphics3D[Cylinder[]]]

属性和关系  (5)

使用 Scale 得到椭圆形圆柱体：

Wolfram Language code: Graphics3D[Scale[Cylinder[], {2, 4, 3}, {0, 0, 0}], Axes -> True]

使用 ParametricPlot3D 生成的圆柱壳的参数规范：

Wolfram Language code: ParametricPlot3D[{Cos[θ], Sin[θ], z}, {θ, 0, 2π}, {z, -1, 1}, Mesh -> None]

由 ContourPlot3D 生成的圆柱壳的隐式规范：

Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 == 1, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Mesh -> None]

ChemicalData 使用球和圆柱体绘制分子：

Wolfram Language code: ChemicalData["Acridone", "MoleculePlot"]

ImplicitRegion 可以表示任意 Cylinder 区域：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[0 ≤ Subscript[t, 1] + Subscript[t, 2] + Subscript[t, 3] ≤ 3 && Subsuperscript[t, 1, 2] + Subsuperscript[t, 2, 2] + Subsuperscript[t, 3, 2] ≤ 6 + Subscript[t, 2]Subscript[t, 3] + Subscript[t, 1](Subscript[t, 2] + Subscript[t, 3]), {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3]}]; Subscript[ℛ, 2] = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

巧妙范例  (3)

随机的单位圆柱体：

Wolfram Language code: Graphics3D[Table[{EdgeForm[Opacity[.3]], Hue[RandomReal[]], Cylinder[RandomReal[10, {2, 3}]]}, {20}]]

绕轴扫过一个圆柱体：

Wolfram Language code: Graphics3D[{Opacity[0.3], EdgeForm[], Table[{ColorData["Rainbow"][Rescale[c, {0, 2Pi}]], GeometricTransformation[Cylinder[], RotationTransform[c, {-3, 2, -1}, {2, -1, 1}]]}, {c, 0, 2Pi, 2Pi / 18}]}]

嵌套透明圆柱体：

Wolfram Language code: Graphics3D[{Opacity[.3], EdgeForm[Opacity[.3]], Table[Cylinder[{{0, 0, 0}, {0, 0, 2r}}, r], {r, 1, 5}]}, Boxed -> False]
Wolfram Research (2007)，Cylinder，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Cylinder.html （更新于 2014 年）.

文本

Wolfram Research (2007)，Cylinder，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Cylinder.html （更新于 2014 年）.

CMS

Wolfram 语言. 2007. "Cylinder." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/Cylinder.html.

APA

Wolfram 语言. (2007). Cylinder. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Cylinder.html 年

BibTeX

@misc{reference.wolfram_2026_cylinder, author="Wolfram Research", title="{Cylinder}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Cylinder.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cylinder, organization={Wolfram Research}, title={Cylinder}, year={2014}, url={https://reference.wolfram.com/language/ref/Cylinder.html}, note=[Accessed: 11-September-2026]}