WOLFRAM

Wolfram 语言与系统参考资料中心

DEigensystem[ℒ[u[x,y,…]],u,{x,y,…}∈Ω,n]

给出线性微分算子 ℒ 在区域 Ω 上 n 个幅值最小的特征值和特征函数.

DEigensystem[eqns,u,t,{x,y,…}∈Ω,n]

给出含时微分方程 eqns 的解 u 的特征值和特征函数.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
1D  
二维  
三维  
选项  
Assumptions  
Method  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

DEigensystem

DEigensystem[ℒ[u[x,y,…]],u,{x,y,…}∈Ω,n]

给出线性微分算子 ℒ 在区域 Ω 上 n 个幅值最小的特征值和特征函数.

DEigensystem[eqns,u,t,{x,y,…}∈Ω,n]

给出含时微分方程 eqns 的解 u 的特征值和特征函数.

更多信息和选项

  • DEigensystem 可以根据边界条件，计算常微分算子和偏微分算子的特征值和特征函数.
  • DEigensystem 给出特征值 λi 和特征函数 ui 的列表 {{λ1,…,λn},{u1,…,un}}.
  • 微分算子 ℒ 的特征值和特征函数对 {λi,ui} 满足 ℒ[ui[x,y,…]]==λi ui[x,y,…].
  • 可以包含齐次 DirichletCondition 或 NeumannValue 边界条件. 非齐次边界条件将被相应的齐次边界条件代替.
  • 如果没有指定边界 ∂Ω 处的边界条件，则相当于指定诺伊曼 0 边界条件.
  • 方程 eqns 的规范与在 DSolve 中的一样.
  • 对于不能符号式计算特征系统，N[DEigensystem[…]] 会调用 NDEigensystem.
  • 可以给出下列选项：
  • Assumptions $Assumptions对参数的假设
    Method Automatic使用的方法
  • 特征函数不会自动归一化. 设置 Method->"Normalize" 可被用于给出归一化的特征函数.

范例

打开所有单元 关闭所有单元

基本范例  (2)

求拉普拉斯算子在 [0,π] 上 4 个最小的特征值和特征函数：

Wolfram Language code: DEigensystem[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, 0, π}, 4]

可视化特征函数：

Wolfram Language code: Plot[Evaluate[%[[2]]], {x, 0, π}]

计算边缘被固定好的圆形膜片的前 6 个特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[], 6];
Wolfram Language code: vals//N

可视化特征函数：

Wolfram Language code: Table[Plot3D[funs[[i]]//N//Evaluate, {x, y}∈Disk[], PlotRange -> All, PlotLabel -> vals[[i]], PlotTheme -> "Minimal"], {i, Length[vals]}]

范围  (20)

1D  (9)

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x] == 0, True];

求区间上 5 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x], {x, 0, π}, 5];
Wolfram Language code: vals

可视化特征函数：

Wolfram Language code: Plot[Evaluate[funs], {x, 0, π}]

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

指定齐次诺伊曼边界条件：

Wolfram Language code: ℬ = NeumannValue[0, True];

求区间上 5 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[ℒ + ℬ, u[x], {x, 0, π}, 5];
Wolfram Language code: vals

这是等价的：

Wolfram Language code: {vals, funs} = DEigensystem[ℒ, u[x], {x, 0, π}, 5];
Wolfram Language code: vals

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ1 = DirichletCondition[u[x] == 0, x == 0];

指定齐次诺伊曼边界条件：

Wolfram Language code: ℬ2 = NeumannValue[0, x == π];

求区间上 5 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ + ℬ2, ℬ1}, u[x], {x, 0, π}, 5];
Wolfram Language code: vals

可视化特征函数：

Wolfram Language code: Plot[Evaluate[funs], {x, 0, π}]

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ1 = DirichletCondition[u[x] == 0, x == π];

指定齐次非零诺伊曼边界条件：

Wolfram Language code: ℬ2 = NeumannValue[-u[x] / 3, x == 0];

求区间上 5 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ + ℬ2, ℬ1}, u[x], {x, 0, π}, 5];

特征值为超越方程的根：

Wolfram Language code: vals[[1]]//TraditionalForm

可视化特征函数：

Wolfram Language code: Plot[Evaluate[funs], {x, 0, π}]

指定艾里算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}] + x u[x];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x] == 0, True];

求区间上 5 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x], {x, 0, 1}, 5];

特征值为超越方程的根：

Wolfram Language code: vals[[1]]//TraditionalForm

可视化特征函数：

Wolfram Language code: Plot[Evaluate[funs], {x, 0, 1}]

指定艾里算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}] + x u[x];

指定齐次诺伊曼边界条件：

Wolfram Language code: ℬ = NeumannValue[0, True];

求区间上 5 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ + ℬ}, u[x], {x, 0, 1}, 5];

特征值为超越方程的根：

Wolfram Language code: vals[[1]]//TraditionalForm

可视化特征函数：

Wolfram Language code: Plot[Evaluate[funs], {x, 0, 1}]

求拉普拉斯算子的特征值和特征函数的符号表达式：

Wolfram Language code: {vals, funs} = DEigensystem[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, a, b}, 3];

符号式特征值：

Wolfram Language code: vals

符号式特征函数：

Wolfram Language code: funs

输入量子谐振算符：

Wolfram Language code: qho = -(ℏ^2/2m)Laplacian[u[x], {x}] + (m ω^2/2)x ^ 2 u[x];

求实数轴上特征值和特征函数的符号表达式：

Wolfram Language code: DEigensystem[qho, u[x], {x, -∞, ∞}, 4, Assumptions -> ℏ > 0 && m > 0 && ω > 0]

指定带齐次狄利克雷边界条件的热方程：

Wolfram Language code: {ℒ, ℬ} = {D[u[t, x], t] == Laplacian[u[t, x], {x}], DirichletCondition[u[t, x] == 0, True]};

求 4 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[t, x], t, {x, 0, π}, 4]

可视化特征函数：

Wolfram Language code: Table[Plot3D[funs[[i]]//Evaluate, {x, -3, 3}, {t, 0, 1 / 3}, PlotRange -> All, Ticks -> False, Mesh -> False], {i, 4}]

二维  (6)

指定具有齐次狄利克雷边界条件的拉普拉斯算子：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]};

求长方形内 9 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x, y], {x, 0, π}, {y, 0, π}, 9];
Wolfram Language code: vals

可视化特征函数：

Wolfram Language code: Plot3D[#, {x, 0, π}, {y, 0, π}]& /@ funs

指定具有齐次诺伊曼边界条件的拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}] + NeumannValue[0, True];

求长方形内 4 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[ℒ, u[x, y], {x, 0, π}, {y, 0, π}, 4];
Wolfram Language code: vals
Wolfram Language code: funs

可视化特征函数：

Wolfram Language code: ContourPlot[#, {x, 0, π}, {y, 0, π}]& /@ funs

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

求算子在单位圆盘中 4 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x, y], {x, y}∈Disk[], 4];
Wolfram Language code: vals//TraditionalForm

可视化特征函数：

Wolfram Language code: ContourPlot[#, {x, y}∈Disk[], Contours -> 10]& /@ N[funs]

指定一个量子谐振算符：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}] + (x ^ 2 + y ^ 2)u[x, y];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

求算子在平面上的 6 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x, y], {x, y}∈FullRegion[2], 6];
Wolfram Language code: vals

可视化特征函数：

Wolfram Language code: Table[ContourPlot[funs[[i]], {x, y}∈Rectangle[{-3, -3}, {3, 3}]], {i, 6}]

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

求算子在三角形中 6 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x, y], {x, y}∈Triangle[], 6];
Wolfram Language code: vals

可视化特征函数：

Wolfram Language code: Table[Plot3D[funs[[i]], {x, y}∈Triangle[], Boxed -> False, Axes -> False], {i, 6}]

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

求算子在圆盘的扇区中 4 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x, y], {x, y}∈Disk[{0, 0}, 1, {0, Pi / 5}], 4];
Wolfram Language code: vals//TraditionalForm

可视化特征函数：

Wolfram Language code: ContourPlot[#, {x, y}∈Disk[{0, 0}, 1, {0, Pi / 5}]]& /@ N[funs]//Quiet

三维  (5)

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

求长方体中 7 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Cuboid[{2, 1, 1}, {4, 2, 3}], 7];
Wolfram Language code: vals

可视化特征函数：

Wolfram Language code: ContourPlot3D[Evaluate[funs[[7]]], {x, 2, 4}, {y, 1, 2}, {z, 1, 3}, Boxed -> False, Axes -> False]

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

求圆柱中 7 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Cylinder[{{0, 0, 0}, {0, 0, 5}}, 2], 7];
Wolfram Language code: vals[[1 ;; 5]]//TraditionalForm

可视化特征函数：

Wolfram Language code: DensityPlot3D[funs[[7]]//N//Evaluate, {x, y, z}∈Cylinder[{{0, 0, 0}, {0, 0, 5}}, 2], Boxed -> False, Axes -> False]

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

求一个球体中 7 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Ball[{0, 0, 0}, 2], 7];

可视化特征函数：

Wolfram Language code: DensityPlot3D[funs[[7]]//N//Evaluate, {x, y, z}∈Ball[{0, 0, 0}, 2], Boxed -> False, Axes -> False, ColorFunction -> Hue]

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

求棱柱中 7 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Prism[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 2}, {1, 0, 2}, {0, 1, 2}}], 7];
Wolfram Language code: vals

可视化特征函数：

Wolfram Language code: DensityPlot3D[funs[[7]]//N//Evaluate, {x, y, z}∈Prism[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 2}, {1, 0, 2}, {0, 1, 2}}], Boxed -> False, ColorFunction -> Hue, PlotPoints -> 50, Axes -> False]

指定量子谐振算符：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}] + 2(x^2 + y^2 + z^2)u[x, y, z];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

求得空间中 8 个最小的特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈FullRegion[3], 8];
Wolfram Language code: vals

可视化特征函数：

Wolfram Language code: Table[DensityPlot3D[funs[[i]]//N//Evaluate, {x, y, z}∈Ball[{0, 0, 0}, 3], Boxed -> False, ColorFunction -> Hue, PlotPoints -> 50, Axes -> False], {i, 8}]

选项  (2)

Assumptions  (1)

用 Assumptions 化简结果：

Wolfram Language code: DEigensystem[-Laplacian[u[x, y, z], {x, y, z}] + 2ω^2(x^2 + y^2 + z^2)u[x, y, z], u[x, y, z], {x, y, z}∈FullRegion[3], 4, Assumptions -> ω > 0]

不使用选项，会返回等价但更加复杂的答案：

Wolfram Language code: DEigensystem[-Laplacian[u[x, y, z], {x, y, z}] + 2ω^2(x^2 + y^2 + z^2)u[x, y, z], u[x, y, z], {x, y, z}∈FullRegion[3], 4]

Method  (1)

归一化微分算子的特征函数：

Wolfram Language code: DEigensystem[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, 0, Pi}, 3, Method -> "Normalize"]

检验特征函数是否被归一化：

Wolfram Language code: Integrate[%[[2]] ^ 2, {x, 0, Pi}]

应用  (3)

给定在区间 上的狄利克雷条件，计算函数 关于由一维拉普拉斯算子提供的基的特征函数展开式的前三项：

Wolfram Language code: basis = DEigensystem[{-Laplacian[u[x], {x}] + u[x], DirichletCondition[u[x] == 0, True]}, u[x], {x, 0, π}, 3, Method -> "Normalize"][[2]]

计算傅立叶系数：

Wolfram Language code: f[x_] := x ^ 2(π - x) ^ 3
Wolfram Language code: coeffs = Table[Integrate[f[x] basis[[i]], {x, 0, Pi}], {i, 3}]

所求的特征函数展开式为：

Wolfram Language code: eigexp[x_] = Sum[coeffs[[i]]basis[[i]], {i, 3}]

比较函数和它的特征函数展开式：

Wolfram Language code: Plot[{f[x], eigexp[x]}//Evaluate, {x, 0, Pi}]

给定狄利克雷条件，通过使用热方程特征函数的线性组合建立热方程的解：

Wolfram Language code: eqns = {D[u[t, x], t] == Laplacian[u[t, x], {x}], DirichletCondition[u[t, x] == 0, True]};
Wolfram Language code: eigfuns = DEigensystem[eqns, u[t, x], t, {x, 0, Pi}, 5][[2]]

形成特征函数的线性组合：

Wolfram Language code: sol[t_, x_] = Sum[RandomInteger[{1, 10}] eigfuns[[i]], {i, 5}]

验证它确实是热方程的解：

Wolfram Language code: eqns[[1]] /. {u -> sol}

此解满足齐次狄利克雷条件：

Wolfram Language code: {sol[t, 0], sol[t, π]}

可视化解：

Wolfram Language code: Plot3D[sol[t, x], {x, 0, Pi}, {t, 0, 0.7}, PlotRange -> All]

实验中，一个 CO 分子根据其平衡长度震荡，震荡的有效弹性系数为 k=TemplateBox[{1.86`, {"kN", , "/", , "m"}, kilonewtons per meter, {{(, "Kilonewtons", )}, /, {(, "Meters", )}}}, QuantityTF]. 震荡由量子谐振方程决定. 在下式中， 是分子的缩减质量， 是自然频率， 是距离平衡位置的位移，而 是缩减的普朗克常数：

Wolfram Language code: qho = -(ℏ^2/2m)Laplacian[u[x], {x}] + (m ω^2/2)x ^ 2 u[x];

计算特征值——各自状态的能量——和归一化的特征函数：

Wolfram Language code: {ℰs, efuns} = DEigensystem[qho, u[x], {x, -∞, ∞}, 4, Assumptions -> ℏ > 0 && m > 0 && ω > 0, Method -> "Normalize"]

如果粒子在四种状态的相等叠加态，则波动函数具有如下形式：

Wolfram Language code: ψ[x_, t_] = Total[MapThread[(1/2)Exp[I t #1 / ℏ]#2&, {ℰs, efuns}]]

使用原子质量单位的基本单位、飞秒和皮米计算 、 和 ，这样能给出接近正常的数量级的值：

Wolfram Language code: m = QuantityMagnitude[(Entity["Element", "Carbon"][EntityProperty["Element", "AtomicMass"]]Entity["Element", "Oxygen"][EntityProperty["Element", "AtomicMass"]]/Entity["Element", "Carbon"][EntityProperty["Element", "AtomicMass"]] + Entity["Element", "Oxygen"][EntityProperty["Element", "AtomicMass"]]), "AtomicMassUnits"]
Wolfram Language code: ω = Sqrt[QuantityMagnitude[Quantity[1.86, "Kilonewtons" / "Meters"], "AtomicMassUnit" / "Femtoseconds" ^ 2] / m]
Wolfram Language code: ℏ = QuantityMagnitude[Quantity[1., "ReducedPlanckConstant"], "AtomicMassUnit" * "Picometers" ^ 2 / "Femtoseconds"]

特征函数对应的势能 可以可视化，通过改变比例尺来放到带状区域 中：

Wolfram Language code: Show[Plot[Evaluate[ℏ ω efuns + ℰs], {x, -18, 18}], Plot[Evaluate[Append[ℰs, (1/2)m ω^2x^2]], {x, -18, 18}, PlotStyle -> Dashed]]

距离平衡态位移的概率密度函数由 给出：

Wolfram Language code: ρ[x_, t_] = FullSimplify[ComplexExpand[Conjugate[ψ[x, t]] ψ[x, t]]]

作为概率分布， 在全部 上的实数积分为 1:

Wolfram Language code: Chop[Integrate[ρ[x, t], {x, -∞, ∞}]]

可视化随着时间的概率密度：

Wolfram Language code: Animate[Plot[ρ[x, t], {x, -25, 25}, PlotRange -> {0, .16}, PlotTheme -> "Detailed", FrameLabel -> Style[x, FontSize -> Larger], PlotLegends -> Placed[{HoldForm[ρ][x, NumberForm[t, {3, 2}]]}, Above]], {t, 0., 5.7}, AnimationRate -> 1, SaveDefinitions -> True, Alignment -> Center]

属性和关系  (6)

用 NDEigensystem 求特征值和特征向量的数值：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]};

求特征值和特征向量的精确值：

Wolfram Language code: exacteigsys = DEigensystem[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3, Method -> "Normalize"]
Wolfram Language code: exacteigsys /. {x -> 0.3}

求特征值和特征向量的数值：

Wolfram Language code: neigsys = NDEigensystem[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3] /. {x -> 0.3}

用 DEigenvalues 求微分算子的特征值：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]};

求特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]
Wolfram Language code: vals

只求出特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

用 DSolve 求解特征值问题：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]};

求特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

求完整的特征系统：

Wolfram Language code: DSolve[{u''[x] + λ u[x] == 0, u[0] == 0, u[π] == 0}, u[x], x]

由 DEigensystem 给出的特征函数是正交的：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]};

求特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x], {x, 0, Pi}, 4]

验证特征函数是正交的：

Wolfram Language code: Table[Integrate[funs[[i]] * funs[[j]], {x, 0, Pi}], {i, 1, 4}, {j, 1, i - 1}]//Flatten

默认情况下，由 DEigensystem 给出的特征函数系统不是正交归一的：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]};

求特征值和特征函数：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

默认情况下，特征函数系统不是正交归一的：

Wolfram Language code: Table[Integrate[funs[[i]] funs[[j]], {x, 0, Pi}], {i, 1, 3}, {j, 1, 3}]//MatrixForm

用 Method->"Normalize" 得到正交归一的系统：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3, Method -> "Normalize"]
Wolfram Language code: Table[Integrate[funs[[i]] * funs[[j]], {x, 0, Pi}], {i, 1, 3}, {j, 1, 3}]//MatrixForm

如果无法进行符号运算， 应用 N[DEigensystem[...]] 会调用 NDEigensystem：

Wolfram Language code: DEigensystem[{-Laplacian[u[x, y], {x, y}] + E ^ (-x ^ 3 + x) u[x, y], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Rectangle[], 2]
Wolfram Language code: N[%]

可能存在的问题  (2)

非齐次狄利克雷条件被齐次条件代替：

Wolfram Language code: First[DEigensystem[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 1, True]}, u[x], {x, 0, 1}, 2]]

结果是一样的：

Wolfram Language code: First[DEigensystem[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, 0, 1}, 2]]

非齐次诺伊曼值被齐次值代替：

Wolfram Language code: First[DEigensystem[{-Laplacian[u[x], {x}] + NeumannValue[1, True]}, u[x], {x, 0, 1}, 2]]

结果是一样的：

Wolfram Language code: First[DEigensystem[-Laplacian[u[x], {x}], u[x], {x, 0, 1}, 2]]
Wolfram Research (2015)，DEigensystem，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DEigensystem.html.

文本

Wolfram Research (2015)，DEigensystem，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DEigensystem.html.

CMS

Wolfram 语言. 2015. "DEigensystem." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DEigensystem.html.

APA

Wolfram 语言. (2015). DEigensystem. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DEigensystem.html 年

BibTeX

@misc{reference.wolfram_2026_deigensystem, author="Wolfram Research", title="{DEigensystem}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/DEigensystem.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_deigensystem, organization={Wolfram Research}, title={DEigensystem}, year={2015}, url={https://reference.wolfram.com/language/ref/DEigensystem.html}, note=[Accessed: 13-September-2026]}