WOLFRAM

Wolfram 语言与系统参考资料中心

DEigenvalues[ℒ[u[x,y,…]],u,{x,y,…}∈Ω,n]

给出线性微分算子 ℒ 在区域 Ω 上 n 个幅值最小的特征值.

DEigenvalues[eqns,u,t,{x,y,…}∈Ω,n]

给出含时微分方程 eqns 的解 u 的特征值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
一维  
二维  
三维  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

DEigenvalues

DEigenvalues[ℒ[u[x,y,…]],u,{x,y,…}∈Ω,n]

给出线性微分算子 ℒ 在区域 Ω 上 n 个幅值最小的特征值.

DEigenvalues[eqns,u,t,{x,y,…}∈Ω,n]

给出含时微分方程 eqns 的解 u 的特征值.

更多信息和选项

  • DEigenvalues 可以根据所给边界条件，计算常微分算子和偏微分算子的特征值.
  • DEigenvalues 给出 n 个幅值最小的特征值 λi 的列表 {λ1,…,λn}.
  • 微分算子 ℒ 的特征值和特征函数对 {λi,ui} 满足 ℒ[ui[x,y,…]]==λi ui[x,y,…].
  • 可以包含齐次 DirichletCondition 或 NeumannValue 边界条件. 非齐次边界条件将被相应的齐次边界条件代替.
  • 如果没有指定边界 ∂Ω 处的边界条件，则相当于指定 Neumann 0 边界条件.
  • 方程 eqns 的规范与在 DSolve 中的一样.
  • 对于不能做符号式计算的特征值，N[DEigenvalues[…]] 会调用 NDEigenvalues.
  • Assumptions 选项可用来指定参数的假设值.

范例

打开所有单元 关闭所有单元

基本范例  (2)

求拉普拉斯算子在 [0,π] 上4个最小的特征值：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, 0, π}, 4]

计算边缘被固定好的圆形膜片的前6个特征值：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[], 6]//TraditionalForm
Wolfram Language code: N[%]

范围  (17)

一维  (8)

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x] == 0, True];

求区间上5个最小的特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, π}, 5]

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

指定齐次诺伊曼边界条件：

Wolfram Language code: ℬ = NeumannValue[0, True];

求区间上5个最小的特征值：

Wolfram Language code: DEigenvalues[ℒ + ℬ, u[x], {x, 0, π}, 5]

等价于：

Wolfram Language code: DEigenvalues[ℒ, u[x], {x, 0, π}, 5]

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ1 = DirichletCondition[u[x] == 0, x == 0];

指定齐次诺伊曼边界条件：

Wolfram Language code: ℬ2 = NeumannValue[0, x == π];

求区间上5个最小的特征值：

Wolfram Language code: DEigenvalues[{ℒ + ℬ2, ℬ1}, u[x], {x, 0, π}, 5]

求第 个特征值：

Wolfram Language code: FindSequenceFunction[%, n]//Factor

求拉普拉斯算子的特征值的符号表达式：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, a, b}, 3]

指定拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ1 = DirichletCondition[u[x] == 0, x == π];

指定齐次非零诺伊曼边界条件：

Wolfram Language code: ℬ2 = NeumannValue[-u[x] / 3, x == 0];

求区间上5个最小的特征值：

Wolfram Language code: vals = DEigenvalues[{ℒ + ℬ2, ℬ1}, u[x], {x, 0, π}, 5];
Wolfram Language code: vals[[1]]//TraditionalForm

指定一个艾里算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}] + x u[x];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x] == 0, True];

求区间上3个最小的特征值：

Wolfram Language code: vals = DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, 1}, 3];

特征值为超越方程的根：

Wolfram Language code: vals//TraditionalForm

特征值的数值近似：

Wolfram Language code: N[vals, 20]

指定一个艾里算子：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}] + x u[x];

指定齐次诺伊曼边界条件：

Wolfram Language code: ℬ = NeumannValue[0, True];

求区间上5个最小的特征值和特征函数：

Wolfram Language code: vals = DEigenvalues[{ℒ + ℬ}, u[x], {x, 0, 1}, 5];

特征值是超越方程的根：

Wolfram Language code: vals[[1]]//TraditionalForm

指定一个齐次狄利克雷边界条件下的热方程：

Wolfram Language code: {ℒ, ℬ} = {D[u[t, x], t] == Laplacian[u[t, x], {x}], DirichletCondition[u[t, x] == 0, True]};

求4个最小的特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[t, x], t, {x, 0, π}, 4]

二维  (5)

指定具有齐次狄利克雷边界条件的拉普拉斯算子：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]};

求一个长方形内9个最小的特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, 0, π}, {y, 0, π}, 9]

指定具有齐次诺伊曼边界条件的拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}] + NeumannValue[0, True];

求一个长方形内4个最小的特征值：

Wolfram Language code: DEigenvalues[ℒ, u[x, y], {x, 0, π}, {y, 0, π}, 4]

指定一个拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

求算子在单位圆盘中4个最小的特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, y}∈Disk[], 4]//TraditionalForm

指定一个拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

求算子在三角形中6个最小的特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, y}∈Triangle[], 6]

指定一个拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

求算子在圆盘的一个扇区中4个最小的特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, y}∈Disk[{0, 0}, 1, {0, Pi / 5}], 4]//TraditionalForm

三维  (4)

指定一个拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

求长方体中7个最小的特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Cuboid[{2, 1, 1}, {4, 2, 3}], 7]

指定一个拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

求圆柱中5个最小的特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Cylinder[{{0, 0, 0}, {0, 0, 5}}, 2], 5]//TraditionalForm

指定一个拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

求一个球体中7个最小的特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Ball[{0, 0, 0}, 2], 7]//TraditionalForm

指定一个拉普拉斯算子：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

指定齐次狄利克雷边界条件：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

求棱柱中7个最小的特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Prism[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 2}, {1, 0, 2}, {0, 1, 2}}], 7]

属性和关系  (3)

用 NDEigensystem 求特征值和特征向量的数值：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]};

精确特征值：

Wolfram Language code: exacteigvals = DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

特征值的数值：

Wolfram Language code: numeigvals = NDEigenvalues[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

用 DEigensystem 求微分算子的特征系统：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]};

求特征值：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

求特征系统：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]
Wolfram Language code: vals

如果无法进行符号运算，用 N[DEigenvalues[…]] 调用 NDEigenvalues：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x, y], {x, y}] + E ^ (-x ^ 3 + x) u[x, y], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Rectangle[], 4]
Wolfram Language code: N[%]

可能存在的问题  (2)

非齐次狄利克雷条件被齐次条件代替：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 1, True]}, u[x], {x, 0, 1}, 2]

结果是一样的：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, 0, 1}, 2]

非齐次诺伊曼值被齐次值代替：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}] + NeumannValue[1, True]}, u[x], {x, 0, 1}, 2]

结果是一样的：

Wolfram Language code: DEigenvalues[-Laplacian[u[x], {x}], u[x], {x, 0, 1}, 2]
Wolfram Research (2015)，DEigenvalues，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DEigenvalues.html.

文本

Wolfram Research (2015)，DEigenvalues，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DEigenvalues.html.

CMS

Wolfram 语言. 2015. "DEigenvalues." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DEigenvalues.html.

APA

Wolfram 语言. (2015). DEigenvalues. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DEigenvalues.html 年

BibTeX

@misc{reference.wolfram_2026_deigenvalues, author="Wolfram Research", title="{DEigenvalues}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/DEigenvalues.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_deigenvalues, organization={Wolfram Research}, title={DEigenvalues}, year={2015}, url={https://reference.wolfram.com/language/ref/DEigenvalues.html}, note=[Accessed: 08-September-2026]}