WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Darker[color]

指定の色をより暗くした色を表す．

Darker[color,f]

割合 f で指定の色をより暗くしたものを表す．

Darker[image,…]

画像をより暗くしたものを返す．

Darker[video,…]

動画のフレームがより暗いバージョンを与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
データ  
パラメータ  
アプリケーション  
特性と関係  
考えられる問題  
インタラクティブな例題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Darker

Darker[color]

指定の色をより暗くした色を表す．

Darker[color,f]

割合 f で指定の色をより暗くしたものを表す．

Darker[image,…]

画像をより暗くしたものを返す．

Darker[video,…]

動画のフレームがより暗いバージョンを与える．

詳細

  • Darkerは色または画像をより暗くしたものを作成するために使うことができる．
  • Darker[color,1]は黒を返す． »
  • Darker[color,0]は color を返す． »
  • Darker[color]はDarker[color,1/3]に等しい． »
  • Darker[color,f]で，f の値が0から1の外側の場合，その値は切り取られる．
  • Darker[image]は，2Dおよび3Dの画像に用いることができる．
  • Darker[{col1,col2,…},…] は coli のそれぞれをより暗くしたものを返す． »
  • 色に適用された場合は，Darkerは常にRGBColorを返す．
  • Darkerは，カラー画像に適用された場合は，常にRGB画像を返す．
  • Darkerは，色あるいは画像の不透明度には影響しない．

例題

すべて開く すべて閉じる

例  (3)

色を暗くする：

Wolfram Language code: Graphics[{Darker[Red], Disk[]}]
Wolfram Language code: Graphics3D[{Darker[Green], Sphere[]}]

どの程度暗くするか割合を指定する：

Wolfram Language code: Graphics[{Darker[Blue, #], Disk[]}]& /@ {.1, .5, .8}

画像をより暗くしたバージョン：

Wolfram Language code: Darker[[image], .5]

スコープ  (9)

データ  (6)

色のDarkerバージョン：

Wolfram Language code: Darker[RGBColor[1, 0, 0]]

2Dグレースケール画像をより暗くしたバージョン：

Wolfram Language code: Darker[[image]]

より暗い画像：

Wolfram Language code: Darker[[image]]

より暗い動画：

Wolfram Language code: Darker[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-83a60)"]\)]

3D画像をより暗くしたバージョン：

Wolfram Language code: Darker[[image]]

Darkerは自動的に色に縫い込まれる：

Wolfram Language code: Darker[{Red, Green, Blue}, 1 / 2]

パラメータ  (3)

デフォルトの暗色化の割合はである：

Wolfram Language code: Darker[Red] == Darker[Red, 1 / 3]
Wolfram Language code: {Graphics[{Darker[Red], Disk[]}], Graphics[{Darker[Red, 1 / 3], Disk[]}]}

別の暗色化の割合を指定する：

Wolfram Language code: Table[Graphics[{Darker[Red, i], Disk[]}], {i, {0.2, 0.4, 0.6, 0.8}}]

暗くする割合が零のとき，色は変わらない：

Wolfram Language code: Darker[Blue, 0] == Blue
Wolfram Language code: {Graphics[{Darker[Blue, 0], Disk[]}], Graphics[{Blue, Disk[]}]}

暗くする割合が1のとき，色は黒になる：

Wolfram Language code: Darker[Blue, 1] == RGBColor[0, 0, 0]
Wolfram Language code: {Graphics[{Darker[Blue, 1], Disk[]}], Graphics[{Black, Disk[]}]}

アプリケーション  (3)

Darkerを使ってプロットのためのColorFunctionを構築する：

Wolfram Language code: Plot3D[y Sin[x ^ 2 + y ^ 2], {x, -3, 3}, {y, -3, 3}, ColorFunction -> (Darker[Cyan, #3]&), Mesh -> None, PlotPoints -> 40]
Wolfram Language code: DensityPlot[Sin[x]Sin[y], {x, -4, 4}, {y, -4, 4}, ColorFunction -> (Darker[Cyan, #]&)]

特定の色相のDarkerとLighterの値を色関数として使う：

Wolfram Language code: ContourPlot[Sin[x]Sin[y], {x, 0, 2Pi}, {y, 0, 2Pi}, ColorFunction -> (If[# < 0, Darker[Blue, Abs[#]], Lighter[Red, #]]&), ColorFunctionScaling -> False]

画像中の顔を検出し，背景を暗くすることでハイライトする：

Wolfram Language code: i = [image]; {w, h} = ImageDimensions[i];
Wolfram Language code: mask = Graphics[FindFaces[i], PlotRange -> {{0, w}, {0, h}}];

暗くした背景をもとの画像を組み合せる：

Wolfram Language code: bg = SetAlphaChannel[Darker[i, .55], mask]; ImageCompose[i, bg]

特性と関係  (5)

色のDarkerは，常にRGBColorとして返される：

Wolfram Language code: Darker[CMYKColor[0, 1, 1, 0]]//InputForm

不透明度の値はDarkerの影響を受けない：

Wolfram Language code: Darker[RGBColor[1, 0, 0, .4]]//InputForm

DarkerはBlendの特殊ケースである：

Wolfram Language code: {Darker[Blue, 1 / 2], Blend[{Blue, Black}, 1 / 2]}//InputForm
Wolfram Language code: {Graphics[{Darker[Blue, 1 / 2], Disk[]}], Graphics[{Blend[{Blue, Black}, 1 / 2], Disk[]}]}

DarkerとLighterは可換ではない：

Wolfram Language code: Lighter[Darker[Red, .5], .5]
Wolfram Language code: Darker[Lighter[Red, .5], .5]

画像についてのDarkerは，ImageAdjustあるいはBlendの特殊ケースである：

Wolfram Language code: {Darker[[image], 0.5], ImageAdjust[[image], {0, -0.5}], Blend[{[image], Black}, 0.5]}

考えられる問題  (2)

0, 1範囲の外側の値は切り取られる：

Wolfram Language code: Graphics[Table[{Darker[Red, i], EdgeForm[Opacity[.1]], Disk[{5i, 0}]}, {i, 0 - 1 / 4, 1 + 1 / 4, 1 / 4}]]

ある色では暗くなるにつれて，色が緑がかって見えることがある：

Wolfram Language code: Graphics[Table[{Darker[Yellow, i], EdgeForm[Opacity[.1]], Disk[{7i, 0}]}, {i, 0, 1, 1 / 6}]]

インタラクティブな例題  (1)

カラー画像を暗くするにつれて画像の色度が変化する様子を観察する：

Wolfram Language code: Manipulate[ChromaticityPlot3D[Darker[[image], f]], {f, 0, 1}]

おもしろい例題  (1)

傾いて凸凹した質感：

Wolfram Language code: ArrayPlot[Table[Evaluate[Sum[Sin[RandomReal[7, 2].{x, y}], {10}]], {x, 0, 10, .05}, {y, 0, 10, .05}], ColorFunction -> (Darker[Orange, #]&)]
Wolfram Research (2007), Darker, Wolfram言語関数， https://reference.wolfram.com/language/ref/Darker.html （2021年に更新）.

テキスト

Wolfram Research (2007), Darker, Wolfram言語関数， https://reference.wolfram.com/language/ref/Darker.html （2021年に更新）.

CMS

Wolfram Language. 2007. "Darker." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/Darker.html.

APA

Wolfram Language. (2007). Darker. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Darker.html

BibTeX

@misc{reference.wolfram_2026_darker, author="Wolfram Research", title="{Darker}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Darker.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_darker, organization={Wolfram Research}, title={Darker}, year={2021}, url={https://reference.wolfram.com/language/ref/Darker.html}, note=[Accessed: 07-September-2026]}