WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DayHemisphere[]

現在昼である地球の半分を表す，二次元のGeoGraphicsプリミティブである．

DayHemisphere[datespec]

指定された日付における地球の昼半球を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
ReferenceAltitude  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

DayHemisphere

DayHemisphere[]

現在昼である地球の半分を表す，二次元のGeoGraphicsプリミティブである．

DayHemisphere[datespec]

指定された日付における地球の昼半球を表す．

詳細とオプション

  • datespec は，DateObjectあるいは日付に還元される文字列でよい．
  • 明示的な時刻帯のない日付は$TimeZoneを使うものとみなされる．
  • DayHemisphere[…]プリミティブは，惑星や多くの衛星等，地球以外の太陽系天体の地図において使用できる．
  • オプションReferenceAltitudeは，昼半球と夜半球を分ける明暗境界線をどのように定義するかを指定する．取り得る値には次のものが含まれる．
  • Automatic太陽の上縁が高度0を横切る
    altalt という数値高度を太陽の中心が横切る
    {alt,limb}指定された太陽の縁が数値高度 alt を横切る
    "Civil"太陽の中心の高度が–6度である
    "Nautical"太陽の中心の高度が–12度である
    "Astronomical"太陽の中心の高度が–18度である
  • 基準高度角 alt は，Quantityの角度として，または角度度数法の度として解釈される数式として与えることができる．
  • 太陽の周縁に対して取り得る値には，次のものが含まれる．
  • "UpperLimb"太陽の上縁
    "Center"太陽の中心点
    "LowerLimb"太陽の下縁
    縁–1（下縁）から1（上縁）までの数値

例題

すべて開く すべて閉じる

例  (2)

現在昼である地球の部分に色を付ける：

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[]}, GeoRange -> "World"]

次の夏至のときに照らされている地球の部分を示す．赤い線は北極圏と南極圏を示す：

Wolfram Language code: solstice = FindAstroEvent["JuneSolstice"]
Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[solstice], Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"]}, GeoRange -> "World"]

異なる投影法を使う：

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[solstice], Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"]}, GeoRange -> "World", GeoProjection -> "Bonne"]

スコープ  (3)

DayHemisphere[]は，現在の日付と時刻についてのプロットを与える：

Wolfram Language code: GeoGraphics[DayHemisphere[]]

Nowを明示的に使って同じ結果を得る：

Wolfram Language code: GeoGraphics[DayHemisphere[Now]]

年および日の異なるときにおける，照らされている半球の変化を示す：

Wolfram Language code: GeoGraphics[Table[{GeoStyling[Opacity[0.2], Hue[n / 12]], DayHemisphere[DateObject[{2014, n, 1, 2n, 0, 0}]]}, {n, 1, 12}]]

日付を別の形式で指定する：

Wolfram Language code: GeoGraphics[DayHemisphere["31 December 2000"]]
Wolfram Language code: GeoGraphics[DayHemisphere[Tomorrow]]

オプション  (1)

ReferenceAltitude  (1)

デフォルトで，DayHemisphereは，太陽が地平線の上にある地球の部分に対応する：

Wolfram Language code: GeoGraphics[{StandardYellow, DayHemisphere[]}]

市民薄明，航海薄明，および天文薄明の領域を含む地球の各部分を表示する：

Wolfram Language code: dayHemispheres = { DayHemisphere[], DayHemisphere[ReferenceAltitude -> "Civil"], DayHemisphere[ReferenceAltitude -> "Nautical"], DayHemisphere[ReferenceAltitude -> "Astronomical"] };
Wolfram Language code: GeoGraphics[{StandardYellow, dayHemispheres}]

それぞれの意味は，"Orthographic"射影を用いた世界地図において，より明確である：

Wolfram Language code: Manipulate[GeoGraphics[{StandardYellow, dayHemispheres}, GeoProjection -> "Orthographic", GeoCenter -> {lat, lon}], {{lat, 0}, -90, 90}, {{lon, 0}, -180, 180}, SaveDefinitions -> True]

特性と関係  (2)

明暗境界線は昼半球と夜半球を分ける：

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[], GeoStyling[Opacity[0.5], Black], NightHemisphere[], Red, DayNightTerminator[]}]

地球の球体モデルについては，昼半球は測地円板である：

Wolfram Language code: sun = AstroSubpoint["Sun"]
Wolfram Language code: d = GeoDistance[sun, GeoAntipode[sun]] / 2
Wolfram Language code: GeoGraphics[{DayHemisphere[], GeoStyling[Opacity[0.3], Red], GeoDisk[sun, d]}, GeoRange -> "World"]

真の昼半球と近似の昼の測地円板は，地球の楕円体モデルを使うと若干異なる：

Wolfram Language code: GeoGraphics[{DayHemisphere[], GeoStyling[Opacity[0.3], Red], GeoDisk[sun, d]}, GeoCenter -> GeoDestination[sun, {d, 90}], GeoRange -> Quantity[20, "Miles"], Frame -> True]

おもしろい例題  (1)

昼半球と夜半球に別々の地図スタイルを使う：

Wolfram Language code: GeoGraphics[{GeoStyling["ReliefMap"], DayHemisphere[], GeoStyling["Satellite"], NightHemisphere[]}, GeoBackground -> None, ImageSize -> Large]
Wolfram Research (2014), DayHemisphere, Wolfram言語関数， https://reference.wolfram.com/language/ref/DayHemisphere.html （2026年に更新）.

テキスト

Wolfram Research (2014), DayHemisphere, Wolfram言語関数， https://reference.wolfram.com/language/ref/DayHemisphere.html （2026年に更新）.

CMS

Wolfram Language. 2014. "DayHemisphere." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/DayHemisphere.html.

APA

Wolfram Language. (2014). DayHemisphere. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DayHemisphere.html

BibTeX

@misc{reference.wolfram_2026_dayhemisphere, author="Wolfram Research", title="{DayHemisphere}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/DayHemisphere.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dayhemisphere, organization={Wolfram Research}, title={DayHemisphere}, year={2026}, url={https://reference.wolfram.com/language/ref/DayHemisphere.html}, note=[Accessed: 07-September-2026]}