WOLFRAM

Wolfram 语言与系统参考资料中心

DayHemisphere[]

是一个二维 GeoGraphics 基元，表示当前是白天的半球.

DayHemisphere[datespec]

表示地球在指定日期的昼半球.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
ReferenceAltitude  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

DayHemisphere

DayHemisphere[]

是一个二维 GeoGraphics 基元，表示当前是白天的半球.

DayHemisphere[datespec]

表示地球在指定日期的昼半球.

更多信息和选项

  • datespec 可以是 DateObject 或是可以解析为日期的字符串.
  • 如果没有明确给出时区，则日期使用 $TimeZone.
  • 可在地球以外的太阳系天体地图中使用 DayHemisphere[…]，如行星及其卫星.
  • 选项 ReferenceAltitude 指定如何定义分界线，分隔昼夜半球. 可能的值包括：
  • Automatic太阳上缘越过零高度
    alt太阳中心越过数值高度 alt
    {alt,limb}太阳的给定部分越过数值高度 alt
    "Civil"太阳中心的高度为 –6 度
    "Nautical"太阳中心的高度为 –12 度
    "Astronomical"太阳中心的高度为 –18 度
  • 可用 Quantity 角度或（可解释为角度的）数值表达式给出参考高度角 alt.
  • 可用以下值指定太阳的部分：
  • "UpperLimb"太阳的上缘
    "Center"太阳的中心
    "LowerLimb"太阳的下缘
    limb介于 -1（下缘）和 1（上缘）之间的数值

范例

打开所有单元 关闭所有单元

基本范例  (2)

对当前为白天的那部分地球着色：

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[]}, GeoRange -> "World"]

显示下一个夏至日地球上被照亮的部分，用红色线条表示北极圈和南极圈：

Wolfram Language code: solstice = FindAstroEvent["JuneSolstice"]
Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[solstice], Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"]}, GeoRange -> "World"]

使用不同投影：

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[solstice], Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"]}, GeoRange -> "World", GeoProjection -> "Bonne"]

范围  (3)

DayHemisphere[] 给出当前日期和时间的图形：

Wolfram Language code: GeoGraphics[DayHemisphere[]]

使用 Now 显式给出相同结果：

Wolfram Language code: GeoGraphics[DayHemisphere[Now]]

作图说明一天和一年的不同时间被照亮的半球的变化：

Wolfram Language code: GeoGraphics[Table[{GeoStyling[Opacity[0.2], Hue[n / 12]], DayHemisphere[DateObject[{2014, n, 1, 2n, 0, 0}]]}, {n, 1, 12}]]

以其他格式指定日期：

Wolfram Language code: GeoGraphics[DayHemisphere["31 December 2000"]]
Wolfram Language code: GeoGraphics[DayHemisphere[Tomorrow]]

选项  (1)

ReferenceAltitude  (1)

默认情况下，DayHemisphere 对应于太阳在地平线以上的部分地球：

Wolfram Language code: GeoGraphics[{StandardYellow, DayHemisphere[]}]

给出地球的民用、航海和天文曙暮光区：

Wolfram Language code: dayHemispheres = { DayHemisphere[], DayHemisphere[ReferenceAltitude -> "Civil"], DayHemisphere[ReferenceAltitude -> "Nautical"], DayHemisphere[ReferenceAltitude -> "Astronomical"] };
Wolfram Language code: GeoGraphics[{StandardYellow, dayHemispheres}]

通过 "Orthographic" 投影可在世界地图上更清楚地看出这些地区：

Wolfram Language code: Manipulate[GeoGraphics[{StandardYellow, dayHemispheres}, GeoProjection -> "Orthographic", GeoCenter -> {lat, lon}], {{lat, 0}, -90, 90}, {{lon, 0}, -180, 180}, SaveDefinitions -> True]

属性和关系  (2)

终止线将昼半球和夜半球分开：

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[], GeoStyling[Opacity[0.5], Black], NightHemisphere[], Red, DayNightTerminator[]}]

对于地球的球形模型，昼半球部分是地理圆盘：

Wolfram Language code: sun = AstroSubpoint["Sun"]
Wolfram Language code: d = GeoDistance[sun, GeoAntipode[sun]] / 2
Wolfram Language code: GeoGraphics[{DayHemisphere[], GeoStyling[Opacity[0.3], Red], GeoDisk[sun, d]}, GeoRange -> "World"]

当使用地球的椭圆体模型时，真实昼半球和近似日光地理圆盘略有不同：

Wolfram Language code: GeoGraphics[{DayHemisphere[], GeoStyling[Opacity[0.3], Red], GeoDisk[sun, d]}, GeoCenter -> GeoDestination[sun, {d, 90}], GeoRange -> Quantity[20, "Miles"], Frame -> True]

巧妙范例  (1)

用日半球和夜半球使用不同的地图样式：

Wolfram Language code: GeoGraphics[{GeoStyling["ReliefMap"], DayHemisphere[], GeoStyling["Satellite"], NightHemisphere[]}, GeoBackground -> None, ImageSize -> Large]
Wolfram Research (2014)，DayHemisphere，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DayHemisphere.html （更新于 2026 年）.

文本

Wolfram Research (2014)，DayHemisphere，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DayHemisphere.html （更新于 2026 年）.

CMS

Wolfram 语言. 2014. "DayHemisphere." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2026. https://reference.wolfram.com/language/ref/DayHemisphere.html.

APA

Wolfram 语言. (2014). DayHemisphere. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DayHemisphere.html 年

BibTeX

@misc{reference.wolfram_2026_dayhemisphere, author="Wolfram Research", title="{DayHemisphere}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/DayHemisphere.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dayhemisphere, organization={Wolfram Research}, title={DayHemisphere}, year={2026}, url={https://reference.wolfram.com/language/ref/DayHemisphere.html}, note=[Accessed: 13-September-2026]}