WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DayNightTerminator[]

地球の現在昼である半球と夜である半球の間の分離線を表す一次元GeoGraphicsプリミティブである．

DayNightTerminator[datespec]

指定された日付の昼と夜を分ける分離線を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
ReferenceAltitude  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

DayNightTerminator

DayNightTerminator[]

地球の現在昼である半球と夜である半球の間の分離線を表す一次元GeoGraphicsプリミティブである．

DayNightTerminator[datespec]

指定された日付の昼と夜を分ける分離線を表す．

詳細とオプション

  • datespec は，DateObjectあるいは日付に還元される文字列で指定できる．
  • 明示的な時刻帯のない日付は$TimeZoneを使うものとみなされる．
  • DayNightTerminator[…]プリミティブは，惑星や多数の衛星等，地球以外の太陽系天体の地図においても使用できる．
  • オプション ReferenceAltitude は，明暗境界線をどのように定義するかを指定する．取り得る値には次のものが含まれる．
  • Automatic太陽の上縁が高度0を横切る
    alt太陽の中心が数値高度 alt を横切る
    {alt,limb}指定された太陽の縁が数値高度 alt を横切る
    "Civil"太陽の中心の高度が–6度である
    "Nautical"太陽の中心の高度が–12度である
    "Astronomical"太陽の中心の高度が–18度である
  • 基準高度角 alt は，Quantity角として，または角度の度数として解釈される数式として指定できる．
  • 太陽の周縁に対して取り得る値には，次のものが含まれる．
  • "UpperLimb"太陽の上縁
    "Center"太陽の中心点
    "LowerLimb"太陽の下縁
    縁数値は –1（下縁）から 1（上縁）までの間である

例題

すべて開く すべて閉じる

例  (2)

現在の明暗境界線を線として表示する：

Wolfram Language code: GeoGraphics[{Blue, DayNightTerminator[]}, GeoRange -> "World"]

夏至における明暗境界線を示す．赤い線は北極圏と南極圏を表す：

Wolfram Language code: GeoGraphics[{Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"], Blue, DayNightTerminator[DateObject[{2017, 6, 21}]]}, GeoRange -> "World"]

別の投影法を使う：

Wolfram Language code: GeoGraphics[{Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"], Blue, DayNightTerminator[DateObject[{2017, 6, 21}]]}, GeoRange -> "World", GeoProjection -> "Albers"]

スコープ  (3)

DayNightTerminator[]は現在の日付と時刻についてのプロットを与える：

Wolfram Language code: GeoGraphics[DayNightTerminator[]]

Nowを明示的に使って同じ結果を得る：

Wolfram Language code: GeoGraphics[DayNightTerminator[Now]]

明暗境界線の変化を1ヶ月間隔で示す：

Wolfram Language code: GeoGraphics[Table[{Hue[month / 12], DayNightTerminator[DateObject[{2014, month, 1}]]}, {month, 1, 12}]]

日付を他の形式で指定する：

Wolfram Language code: GeoGraphics[DayNightTerminator["23 Sept 2018"]]
Wolfram Language code: GeoGraphics[DayNightTerminator[Tomorrow]]

オプション  (1)

ReferenceAltitude  (1)

デフォルトで，DayNightTerminatorは，地平線上の太陽を観測する点に対応する：

Wolfram Language code: GeoGraphics[DayNightTerminator[]]

市民薄明，航海薄明，および天文薄明の終端線を表示する：

Wolfram Language code: terminators = { DayNightTerminator[], DayNightTerminator[ReferenceAltitude -> "Civil"], DayNightTerminator[ReferenceAltitude -> "Nautical"], DayNightTerminator[ReferenceAltitude -> "Astronomical"] };
Wolfram Language code: GeoGraphics[terminators]

それぞれの意味は，"Orthographic"射影を用いる世界地図において，より明確である：

Wolfram Language code: Manipulate[GeoGraphics[terminators, GeoProjection -> "Orthographic", GeoCenter -> {lat, lon}], {{lat, 0}, -90, 90}, {{lon, 0}, -180, 180}, SaveDefinitions -> True]

特性と関係  (2)

明暗境界線は昼半球と夜半球を分ける：

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[], GeoStyling[Opacity[0.5], Black], NightHemisphere[], Red, DayNightTerminator[]}]

地球の球体モデルについては，明暗境界線はほぼ測地円である：

Wolfram Language code: sun = GeoPosition[Reverse[SunPosition[CelestialSystem -> "Equatorial"]] - {0, SiderealTime[GeoPosition[{0, 0}]]}]
Wolfram Language code: d = GeoDistance[sun, GeoAntipode[sun]] / 2
Wolfram Language code: GeoGraphics[{DayNightTerminator[], Red, GeoCircle[sun, d]}, GeoRange -> "World"]

真の明暗境界線と近似明暗境界線の測地円は，地球の楕円体モデルを使うと若干異なる：

Wolfram Language code: GeoGraphics[{DayNightTerminator[], Red, GeoCircle[sun, d]}, GeoCenter -> GeoDestination[sun, {d, 90}], GeoRange -> Quantity[20, "Miles"], Frame -> True]
Wolfram Research (2014), DayNightTerminator, Wolfram言語関数， https://reference.wolfram.com/language/ref/DayNightTerminator.html （2026年に更新）.

テキスト

Wolfram Research (2014), DayNightTerminator, Wolfram言語関数， https://reference.wolfram.com/language/ref/DayNightTerminator.html （2026年に更新）.

CMS

Wolfram Language. 2014. "DayNightTerminator." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/DayNightTerminator.html.

APA

Wolfram Language. (2014). DayNightTerminator. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DayNightTerminator.html

BibTeX

@misc{reference.wolfram_2026_daynightterminator, author="Wolfram Research", title="{DayNightTerminator}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/DayNightTerminator.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_daynightterminator, organization={Wolfram Research}, title={DayNightTerminator}, year={2026}, url={https://reference.wolfram.com/language/ref/DayNightTerminator.html}, note=[Accessed: 16-September-2026]}