WOLFRAM

Wolfram 语言与系统参考资料中心

DayNightTerminator[]

是一个一维 GeoGraphics 基元，表示地球当前处于白天和夜晚的半球之间的分界线.

DayNightTerminator[datespec]

表示指定日期昼夜之间的分界线.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
ReferenceAltitude  
属性和关系  
参见
技术笔记
相关指南
历史
按以下格式引用：

DayNightTerminator

DayNightTerminator[]

是一个一维 GeoGraphics 基元，表示地球当前处于白天和夜晚的半球之间的分界线.

DayNightTerminator[datespec]

表示指定日期昼夜之间的分界线.

更多信息和选项

  • datespec 可以指定为 DateObject 或可以解析为日期的字符串.
  • 如果没有明确给出时区，则日期使用 $TimeZone.
  • 可在地球以外的太阳系天体地图中使用 DayNightTerminator[…]，如行星及其卫星.
  • 选项 ReferenceAltitude 指定如何定义分界线. 可能的值包括：
  • Automatic太阳上缘越过零高度
    alt太阳中心越过数值高度 alt
    {alt,limb}太阳的给定部分越过数值高度 alt
    "Civil"太阳中心的高度为 –6 度
    "Nautical"太阳中心的高度为 –12 度
    "Astronomical"太阳中心的高度为 –18 度
  • 可用 Quantity 角度或（可解释为角度的）数值表达式给出参考高度角 alt.
  • 可用以下值指定太阳的部分：
  • "UpperLimb"太阳的上缘
    "Center"太阳的中心
    "LowerLimb"太阳的下缘
    limb介于 -1（下缘）和 1（上缘）之间的数值

范例

打开所有单元 关闭所有单元

基本范例  (2)

用线条显示当前的分界线：

Wolfram Language code: GeoGraphics[{Blue, DayNightTerminator[]}, GeoRange -> "World"]

显示夏至的分界线，用红色线条表示北极圈和南极圈：

Wolfram Language code: GeoGraphics[{Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"], Blue, DayNightTerminator[DateObject[{2017, 6, 21}]]}, GeoRange -> "World"]

使用不同的投影：

Wolfram Language code: GeoGraphics[{Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"], Blue, DayNightTerminator[DateObject[{2017, 6, 21}]]}, GeoRange -> "World", GeoProjection -> "Albers"]

范围  (3)

DayNightTerminator[] 给出当前日期和时间的图形：

Wolfram Language code: GeoGraphics[DayNightTerminator[]]

使用 Now 显式给出相同结果：

Wolfram Language code: GeoGraphics[DayNightTerminator[Now]]

以月为间隔，作图说明分界线的变化：

Wolfram Language code: GeoGraphics[Table[{Hue[month / 12], DayNightTerminator[DateObject[{2014, month, 1}]]}, {month, 1, 12}]]

以其他格式指定日期：

Wolfram Language code: GeoGraphics[DayNightTerminator["23 Sept 2018"]]
Wolfram Language code: GeoGraphics[DayNightTerminator[Tomorrow]]

选项  (1)

ReferenceAltitude  (1)

默认情况下，DayNightTerminator 对应于观察到太阳在地平线上的点：

Wolfram Language code: GeoGraphics[DayNightTerminator[]]

给出民用、航海和天文曙暮光区的分界线：

Wolfram Language code: terminators = { DayNightTerminator[], DayNightTerminator[ReferenceAltitude -> "Civil"], DayNightTerminator[ReferenceAltitude -> "Nautical"], DayNightTerminator[ReferenceAltitude -> "Astronomical"] };
Wolfram Language code: GeoGraphics[terminators]

通过 "Orthographic" 投影可在世界地图上更清楚地看出这些地区：

Wolfram Language code: Manipulate[GeoGraphics[terminators, GeoProjection -> "Orthographic", GeoCenter -> {lat, lon}], {{lat, 0}, -90, 90}, {{lon, 0}, -180, 180}, SaveDefinitions -> True]

属性和关系  (2)

分界线将昼半球和夜半球分离：

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[], GeoStyling[Opacity[0.5], Black], NightHemisphere[], Red, DayNightTerminator[]}]

对于地球的球形模型，分界线近似为地理圆盘：

Wolfram Language code: sun = GeoPosition[Reverse[SunPosition[CelestialSystem -> "Equatorial"]] - {0, SiderealTime[GeoPosition[{0, 0}]]}]
Wolfram Language code: d = GeoDistance[sun, GeoAntipode[sun]] / 2
Wolfram Language code: GeoGraphics[{DayNightTerminator[], Red, GeoCircle[sun, d]}, GeoRange -> "World"]

当使用地球的椭圆体模型时，真实分界线和近似分界线的地理圆盘略有不同：

Wolfram Language code: GeoGraphics[{DayNightTerminator[], Red, GeoCircle[sun, d]}, GeoCenter -> GeoDestination[sun, {d, 90}], GeoRange -> Quantity[20, "Miles"], Frame -> True]
Wolfram Research (2014)，DayNightTerminator，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DayNightTerminator.html （更新于 2026 年）.

文本

Wolfram Research (2014)，DayNightTerminator，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DayNightTerminator.html （更新于 2026 年）.

CMS

Wolfram 语言. 2014. "DayNightTerminator." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2026. https://reference.wolfram.com/language/ref/DayNightTerminator.html.

APA

Wolfram 语言. (2014). DayNightTerminator. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DayNightTerminator.html 年

BibTeX

@misc{reference.wolfram_2026_daynightterminator, author="Wolfram Research", title="{DayNightTerminator}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/DayNightTerminator.html}", note=[Accessed: 16-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_daynightterminator, organization={Wolfram Research}, title={DayNightTerminator}, year={2026}, url={https://reference.wolfram.com/language/ref/DayNightTerminator.html}, note=[Accessed: 16-October-2026]}