WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Decrypt["password",enc]

暗号化されたオブジェクト enc を，指定されたパスワードを使って復号化しようと試みる．

Decrypt[keyspec,enc]

暗号鍵指定 keyspec を使って復号化しようと試みる．

Decrypt[obj]

obj を復号するためのパスワードをインタラクティブにリクエストする．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

Decrypt

Decrypt["password",enc]

暗号化されたオブジェクト enc を，指定されたパスワードを使って復号化しようと試みる．

Decrypt[keyspec,enc]

暗号鍵指定 keyspec を使って復号化しようと試みる．

Decrypt[obj]

obj を復号するためのパスワードをインタラクティブにリクエストする．

詳細

  • Decrypt[…,enc]は，Encryptによって生成されるEncryptedObject[…]を取る．
  • Decrypt[expr]は，ノートブックインターフェースではダイアログボックスを，テキスト型のインターフェースではテキストプロンプトを生成する．
  • 対称暗号化メソッドでは，Decrypt[key,Encrypt[key,expr]]は expr を与える．
  • Decryptは，EncryptedObject[…]["OriginalForm"]で指定された形で式を返す．

例題

すべて開く すべて閉じる

例  (3)

パスワードでメッセージを暗号化する：

Wolfram Language code: Encrypt["my password", "Now is the time..."]

同じパスワードで復号化し，メッセージを取り出す：

Wolfram Language code: Decrypt["my password", %]

秘密鍵を生成する：

Wolfram Language code: key = GenerateSymmetricKey[]

鍵を使って暗号化する：

Wolfram Language code: Encrypt[key, "Now is the time..."]

鍵を使って復号化する：

Wolfram Language code: Decrypt[key, %]

公開鍵と秘密鍵を生成する：

Wolfram Language code: keys = GenerateAsymmetricKeyPair[]

公開鍵を使って暗号化する：

Wolfram Language code: Encrypt[keys["PublicKey"], "Now is the time..."]

秘密鍵を使って復号化する：

Wolfram Language code: Decrypt[keys["PrivateKey"], %]

秘密鍵を使って暗号化することもできる：

Wolfram Language code: Encrypt[keys["PrivateKey"], "Now is the time..."]

公開鍵を使って復号化する：

Wolfram Language code: Decrypt[keys["PublicKey"], %]

スコープ  (3)

任意の式を暗号化する：

Wolfram Language code: Encrypt["my password", Graphics[Disk[]]]

復号化して厳密な式を得る：

Wolfram Language code: Decrypt["my password", %]

バイト配列で暗号化されたデータを解く際は，使用された暗号化アルゴリズムの詳細をDecryptが知らなければならない：

Wolfram Language code: data = ByteArray["HyEEIAp4iTI8Fv2BJpqjqDjwZU9jfKii3p0YqMsSJwvTzT1t+wthV7ODqjLfL6/nkUOuWVeQr7Tp1RBjZb1KO/Zc\ gg7YzoakSz/wy+jlh3bVpmem3V77AW9dcg1wHUzcnZzPR4Yl5fYbrDHdg5HnpmppN4B9eVrPa4OIV4PimdpkvN7abdDhfHDNzxR\ YET2M2MzmobaPD29NaY/trvgDJI7qK+52A4sTHiiDEtGhiyPImZgsF/pjiZDUYAMnU7lDfzsORRAn4HahEKwIPG22K5NwgdbB2o\ gGDNUTxy4ZEYildjSd5cwddWN/yh2KlHcyzv40RoppN0xKIEHWCAeI8A=="];

EncryptedObjectを作って暗号，充填モード，テキストメッセージの形式を指定する：

Wolfram Language code: encrypted = EncryptedObject[<|"Cipher" -> "RSA", "Data" -> data, "OriginalForm" -> String, "Padding" -> Automatic|>]

正しいパスワードまたは鍵を使って暗号を解く：

Wolfram Language code: Decrypt[PrivateKey[Association["Type" -> "RSA", "Cipher" -> "RSA", "Padding" -> "PKCS1", "PublicExponent" -> 65537, "PublicModulus" -> 222999274349291996838327545482429681975946235960406\ 29785429933350406512922509037007038753702646027203641330283959977 ... zKsiI+P2eRwpy+s0p9th7mdTuu/pD/U+UhwFu32W1YyLn6ZLb1UFQ+dCms\ f9tbGgpfD6Hx+mWv1FPzENeJCLNwMGHvK3iJuMuASAiaR7UDz1X6qrp+T5j1LxDcGsJVANKVRxcGAgNt3QGKIvPyjE7Jxhxu98g\ Sm7aze3mDZGZCf1ofYAUuG2imZZPFsA/aIE/buyANKuJ+zleh/OvoyRLG0y+QVrL6EjeX3fcoLRywxgQ=="]]], encrypted]

対称暗号は，大抵の場合，暗号解読のための初期化ベクトルを必要とする：

Wolfram Language code: data = ByteArray["Jw71WcKfKyJ5STiCH1a+Qd3sworv5j7IINTEJXKfEWQ="]; iv = ByteArray["r922W/6m/KASJatnG9tnpg=="];

EncryptedObjectを使って暗号，ブロックモード，初期化ベクトル，テキストメッセージの形式を指定する：

Wolfram Language code: encrypted = EncryptedObject[<|"Cipher" -> "AES256", "BlockMode" -> "CBC", "Data" -> data, "InitializationVector" -> iv, "OriginalForm" -> String|>]

正しいパスワードまたは鍵を使って暗号を解く：

Wolfram Language code: Decrypt["my password", encrypted]

アプリケーション  (1)

簡単な暗号署名と検証の関数を書く：

Wolfram Language code: sign[key_PrivateKey, expr_] := Encrypt[key, Hash[expr, "SHA256"]]
Wolfram Language code: verify[key_PublicKey, expr_, signature_EncryptedObject] := Decrypt[key, signature] === Hash[expr, "SHA256"]

公開鍵と秘密鍵のペアを生成する：

Wolfram Language code: keys = GenerateAsymmetricKeyPair[]

署名する式を定義する：

Wolfram Language code: expr = Graphics[Disk[]]

署名を生成する：

Wolfram Language code: sig = sign[keys["PrivateKey"], expr]

署名が本物であるかどうかを検証する：

Wolfram Language code: verify[keys["PublicKey"], expr, sig]

他の式での検証は失敗する：

Wolfram Language code: verify[keys["PublicKey"], "another expression", sig]

考えられる問題  (1)

不正な鍵を使って復号化しようとするとメッセージが出る：

Wolfram Language code: Encrypt["my password", "Now is the time..."]
Wolfram Language code: Decrypt["another password", %]
Wolfram Research (2015), Decrypt, Wolfram言語関数， https://reference.wolfram.com/language/ref/Decrypt.html （2019年に更新）.

テキスト

Wolfram Research (2015), Decrypt, Wolfram言語関数， https://reference.wolfram.com/language/ref/Decrypt.html （2019年に更新）.

CMS

Wolfram Language. 2015. "Decrypt." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Decrypt.html.

APA

Wolfram Language. (2015). Decrypt. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Decrypt.html

BibTeX

@misc{reference.wolfram_2026_decrypt, author="Wolfram Research", title="{Decrypt}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Decrypt.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_decrypt, organization={Wolfram Research}, title={Decrypt}, year={2019}, url={https://reference.wolfram.com/language/ref/Decrypt.html}, note=[Accessed: 04-September-2026]}