WOLFRAM

Wolfram 语言与系统参考资料中心

Decrypt["password",enc]

尝试使用指定密码对加密对象 enc 进行解密.

Decrypt[keyspec,enc]

尝试使用加密密钥规范 keyspec 解密.

Decrypt[obj]

交互式请求对 obj 进行解密的密码.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

Decrypt

Decrypt["password",enc]

尝试使用指定密码对加密对象 enc 进行解密.

Decrypt[keyspec,enc]

尝试使用加密密钥规范 keyspec 解密.

Decrypt[obj]

交互式请求对 obj 进行解密的密码.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

使用密码加密一则消息：

Wolfram Language code: Encrypt["my password", "Now is the time..."]

使用相同的密码解密，以重新得到消息：

Wolfram Language code: Decrypt["my password", %]

生成密钥：

Wolfram Language code: key = GenerateSymmetricKey[]

使用密钥加密：

Wolfram Language code: Encrypt[key, "Now is the time..."]

使用密钥解密：

Wolfram Language code: Decrypt[key, %]

生成公共和私有密钥：

Wolfram Language code: keys = GenerateAsymmetricKeyPair[]

使用公共密钥加密：

Wolfram Language code: Encrypt[keys["PublicKey"], "Now is the time..."]

使用私有密钥解密：

Wolfram Language code: Decrypt[keys["PrivateKey"], %]

另外，也可以使用私有密钥加密：

Wolfram Language code: Encrypt[keys["PrivateKey"], "Now is the time..."]

现在使用公共密钥解密：

Wolfram Language code: Decrypt[keys["PublicKey"], %]

范围  (3)

加密任何表达式：

Wolfram Language code: Encrypt["my password", Graphics[Disk[]]]

解密，以找回精确表达式：

Wolfram Language code: Decrypt["my password", %]

如果想解密用字节数组加密的数据，Decrypt 需要知道所用加密算法的详细信息：

Wolfram Language code: data = ByteArray["HyEEIAp4iTI8Fv2BJpqjqDjwZU9jfKii3p0YqMsSJwvTzT1t+wthV7ODqjLfL6/nkUOuWVeQr7Tp1RBjZb1KO/Zc\ gg7YzoakSz/wy+jlh3bVpmem3V77AW9dcg1wHUzcnZzPR4Yl5fYbrDHdg5HnpmppN4B9eVrPa4OIV4PimdpkvN7abdDhfHDNzxR\ YET2M2MzmobaPD29NaY/trvgDJI7qK+52A4sTHiiDEtGhiyPImZgsF/pjiZDUYAMnU7lDfzsORRAn4HahEKwIPG22K5NwgdbB2o\ gGDNUTxy4ZEYildjSd5cwddWN/yh2KlHcyzv40RoppN0xKIEHWCAeI8A=="];

创建一个 EncryptedObject 来指定纯文本消息的加密、填充方式和格式：

Wolfram Language code: encrypted = EncryptedObject[<|"Cipher" -> "RSA", "Data" -> data, "OriginalForm" -> String, "Padding" -> Automatic|>]

用正确的密码或密钥来解密：

Wolfram Language code: Decrypt[PrivateKey[Association["Type" -> "RSA", "Cipher" -> "RSA", "Padding" -> "PKCS1", "PublicExponent" -> 65537, "PublicModulus" -> 222999274349291996838327545482429681975946235960406\ 29785429933350406512922509037007038753702646027203641330283959977 ... zKsiI+P2eRwpy+s0p9th7mdTuu/pD/U+UhwFu32W1YyLn6ZLb1UFQ+dCms\ f9tbGgpfD6Hx+mWv1FPzENeJCLNwMGHvK3iJuMuASAiaR7UDz1X6qrp+T5j1LxDcGsJVANKVRxcGAgNt3QGKIvPyjE7Jxhxu98g\ Sm7aze3mDZGZCf1ofYAUuG2imZZPFsA/aIE/buyANKuJ+zleh/OvoyRLG0y+QVrL6EjeX3fcoLRywxgQ=="]]], encrypted]

对称密码通常需要一个初始化向量来解密：

Wolfram Language code: data = ByteArray["Jw71WcKfKyJ5STiCH1a+Qd3sworv5j7IINTEJXKfEWQ="]; iv = ByteArray["r922W/6m/KASJatnG9tnpg=="];

创建一个 EncryptedObject 来指定纯文本消息的加密、分组模式、初始化向量和格式：

Wolfram Language code: encrypted = EncryptedObject[<|"Cipher" -> "AES256", "BlockMode" -> "CBC", "Data" -> data, "InitializationVector" -> iv, "OriginalForm" -> String|>]

用正确的密码或密钥来解密：

Wolfram Language code: Decrypt["my password", encrypted]

应用  (1)

编写简单的加密签名和验证函数：

Wolfram Language code: sign[key_PrivateKey, expr_] := Encrypt[key, Hash[expr, "SHA256"]]
Wolfram Language code: verify[key_PublicKey, expr_, signature_EncryptedObject] := Decrypt[key, signature] === Hash[expr, "SHA256"]

生成一对公共和私有密钥：

Wolfram Language code: keys = GenerateAsymmetricKeyPair[]

定义表达式签名：

Wolfram Language code: expr = Graphics[Disk[]]

生成一个签名：

Wolfram Language code: sig = sign[keys["PrivateKey"], expr]

验证签名是真实的：

Wolfram Language code: verify[keys["PublicKey"], expr, sig]

用另一种表达式验证将失败：

Wolfram Language code: verify[keys["PublicKey"], "another expression", sig]

可能存在的问题  (1)

使用错误密钥解密将产生一则消息：

Wolfram Language code: Encrypt["my password", "Now is the time..."]
Wolfram Language code: Decrypt["another password", %]
Wolfram Research (2015)，Decrypt，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Decrypt.html （更新于 2019 年）.

文本

Wolfram Research (2015)，Decrypt，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Decrypt.html （更新于 2019 年）.

CMS

Wolfram 语言. 2015. "Decrypt." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2019. https://reference.wolfram.com/language/ref/Decrypt.html.

APA

Wolfram 语言. (2015). Decrypt. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Decrypt.html 年

BibTeX

@misc{reference.wolfram_2026_decrypt, author="Wolfram Research", title="{Decrypt}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Decrypt.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_decrypt, organization={Wolfram Research}, title={Decrypt}, year={2019}, url={https://reference.wolfram.com/language/ref/Decrypt.html}, note=[Accessed: 11-September-2026]}