WOLFRAM

Wolfram 语言与系统参考资料中心

DelaunayMesh[{p1,p2,…}]

给出 MeshRegion 表示来自点 p1、p2、… 的德劳内网格.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
MeshCellHighlight  
MeshCellLabel  
MeshCellMarker  
MeshCellShapeFunction  
MeshCellStyle  
PlotTheme  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

DelaunayMesh

DelaunayMesh[{p1,p2,…}]

给出 MeshRegion 表示来自点 p1、p2、… 的德劳内网格.

更多信息和选项

  • DelaunayMesh 也被称为德劳内三角和德劳内四面体.
  • 德劳内网格由区间（一维）、三角形（二维）、四面体（三维）和 维单纯形（ 维）组成.
  • 德劳内网格具有的单纯形单元由 个点定义，使得这相同的 个点的外接圆不含有原始点 pi 中的其他点.
  • 德劳内网格给出一个三角化，其中最小内角最大化.
  • DelaunayMesh 使用与 MeshRegion 相同的选项.

范例

打开所有单元 关闭所有单元

基本范例  (4)

一维德劳内网格：

Wolfram Language code: pts = RandomReal[{-1, 1}, {5, 1}];
Wolfram Language code: DelaunayMesh[pts];
Wolfram Language code: HighlightMesh[%, Style[0, Red]]

来自一列点的二维德劳内网格：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 2}];
Wolfram Language code: ℛ = DelaunayMesh[pts];
Wolfram Language code: HighlightMesh[ℛ, Style[0, Red]]

来自一列点的三维德劳内网格：

Wolfram Language code: pts = RandomReal[{-1, 1}, {25, 3}];
Wolfram Language code: ℛ = DelaunayMesh[pts];
Wolfram Language code: HighlightMesh[ℛ, {Style[0, Directive[PointSize[Medium], Red]], Style[2, Opacity[0.1]]}]

对应于六边形密排点阵的最小向量的点的 Delaunay 网格：

Wolfram Language code: LatticeData["HexagonalClosePacking", "MinimalVectors"]
Wolfram Language code: DelaunayMesh[%]

范围  (3)

从一个点集创建一维德劳内网格：

Wolfram Language code: pts = RandomReal[{-1, 1}, {20, 1}];
Wolfram Language code: ℛ = DelaunayMesh[pts]

基本属性：

Wolfram Language code: {RegionQ[ℛ], MeshRegionQ[ℛ]}

德劳内网格是全维的：

Wolfram Language code: {RegionDimension[ℛ], RegionEmbeddingDimension[ℛ]}

德劳内网格是有界的：

Wolfram Language code: {BoundedRegionQ[ℛ], RegionBounds[ℛ]}

求它的尺寸和质心：

Wolfram Language code: {RegionMeasure[ℛ], RegionCentroid[ℛ]}

求最小距离和最近的点：

Wolfram Language code: {RegionDistance[ℛ, {2}], RegionNearest[ℛ, {2}]}
Wolfram Language code: RegionMember[ℛ, {0.5}]

从一个点集创建二维德劳内网格：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 2}];
Wolfram Language code: ℛ = DelaunayMesh[pts]

基本属性：

Wolfram Language code: {RegionQ[ℛ], MeshRegionQ[ℛ]}

德劳内网格是全维的：

Wolfram Language code: {RegionDimension[ℛ], RegionEmbeddingDimension[ℛ]}

德劳内网格是有界的：

Wolfram Language code: {BoundedRegionQ[ℛ], RegionBounds[ℛ]}

求它的面积和质心：

Wolfram Language code: {RegionMeasure[ℛ], RegionCentroid[ℛ]}

检验点成员或到区域中最近点的距离：

Wolfram Language code: RegionMember[ℛ, {0.5, 0.5}]
Wolfram Language code: {RegionDistance[ℛ, {2, 2}], RegionNearest[ℛ, {2, 2}]}

从一个点集创建三维德劳内网格：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 3}];
Wolfram Language code: ℛ = DelaunayMesh[pts]

基本属性：

Wolfram Language code: {RegionQ[ℛ], MeshRegionQ[ℛ]}

德劳内网格是全维的：

Wolfram Language code: {RegionDimension[ℛ], RegionEmbeddingDimension[ℛ]}

德劳内网格是有界的：

Wolfram Language code: {BoundedRegionQ[ℛ], RegionBounds[ℛ]}

求它的面积和质心：

Wolfram Language code: {RegionMeasure[ℛ], RegionCentroid[ℛ]}

检验点成员或到区域中最近点的距离：

Wolfram Language code: RegionMember[ℛ, {0.5, 0.5, 0.5}]
Wolfram Language code: {RegionDistance[ℛ, {2, 2, 2}], RegionNearest[ℛ, {2, 2, 2}]}

选项  (11)

MeshCellHighlight  (2)

MeshCellHighlight 使得您可以指定 DelaunayMesh 的部分的突出显示：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellHighlight -> {{1, All} -> Red, {0, All} -> Green}]

单独的单元使用单元索引突出显示：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellHighlight -> {{1, 1} -> {Thick, Red}, {1, 2} -> {Dashed, Black}}]

或者通过单元本身：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellHighlight -> {Line[{1, 2}] -> {Thick, Red}, Line[{2, 3}] -> {Dashed, Black}}]

MeshCellLabel  (2)

MeshCellLabel 可以用于对 DelaunayMesh 的部分添加标签：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellLabel -> {0 -> "Index"}]

单个单元可以使用单元索引添加标签：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellLabel -> {{1, 1} -> "x", {1, 2} -> "y"}]

或者通过单元自身：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellLabel -> {Line[{1, 3}] -> "x", Line[{1, 2}] -> "y"}]

MeshCellMarker  (1)

MeshCellMarker 可用于对 DelaunayMesh 的部分赋值：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2, {0, 3} -> 3, {0, 4} -> 4}]

使用 MeshCellLabel 显示记号：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2, {0, 3} -> 3, {0, 4} -> 4}, MeshCellLabel -> {0 -> "Marker"}]

MeshCellShapeFunction  (2)

MeshCellShapeFunction 允许您指定 DelaunayMesh 的部分·的函数：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}}, MeshCellShapeFunction -> {0 -> (Disk[#, .1]&)}]

单个单元可以使用单元索引绘制：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}}, MeshCellShapeFunction -> {{0, 1} -> (Disk[#, .1]&), {0, 2} -> (Disk[#, {.1, .2}]&)}]

或者通过单元自身：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}}, MeshCellShapeFunction -> {Point[1] -> (Disk[#, .1]&), Point[2] -> (Disk[#, {.1, .2}]&)}]

MeshCellStyle  (2)

MeshCellStyle 允许您指定 DelaunayMesh 的部分的样式：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellStyle -> {{1, All} -> Red, {0, All} -> Green}]

单个单元可以使用单元索引突出显示：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellStyle -> {{1, 1} -> {Thick, Red}, {1, 2} -> {Dashed, Black}}]

或者通过单元自身：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}, MeshCellStyle -> {Line[{1, 3}] -> {Thick, Red}, Line[{1, 2}] -> {Dashed, Green}}]

PlotTheme  (2)

使用具有网格线和图例的主题：

Wolfram Language code: DelaunayMesh[RandomReal[{-1, 1}, {50, 2}], PlotTheme -> "Detailed"]

使用主题绘制线框图：

Wolfram Language code: DelaunayMesh[RandomReal[{-1, 1}, {50, 2}], PlotTheme -> "Lines"]

应用  (5)

生成 3D 点阵基元的晶格点：

Wolfram Language code: b = LatticeData["FaceCenteredCubic", "Basis"]
Wolfram Language code: p = Tuples[Range[0, 3], 3].b;

构建并可视化网格区域：

Wolfram Language code: m = DelaunayMesh[p]

从点集构建三维区域：

Wolfram Language code: pts = ExampleData[{"Geometry3D", "UtahTeapot"}, "VertexData"];
Wolfram Language code: dm = DelaunayMesh[pts];

比较原始区域与德劳内网格：

Wolfram Language code: teapot = ExampleData[{"Geometry3D", "UtahTeapot"}, "Graphics3D"];
Wolfram Language code: {teapot, dm}

可视化科罗拉多州城市海拔的分段常数插值：

Wolfram Language code: data = Table[QuantityMagnitude@CityData[c, p], {c, CityData[{Large, "Germany"}]}, {p, {"Longitude", "Latitude", "Elevation"}}]//Select[FreeQ[#, _Missing]&];

城市坐标的沃罗诺伊网格：

Wolfram Language code: dm = DelaunayMesh[QuantityMagnitude[data[[All, {1, 2}]]]];

创建一个函数，把给定的坐标对映射到最近的已知海拔：

Wolfram Language code: nearest = Nearest[Function[{x, y, z}, {x, y} -> z]@@@data];

将海拔值重新调整至 的函数，以适于颜色函数：

Wolfram Language code: rescale = With[{min = Min[data[[All, 3]]], max = Max[data[[All, 3]]]}, Function[v, Rescale[v, {min, max}]]];

城市海拔的分段恒定等高线图：

Wolfram Language code: Graphics[Table[{ColorData["M10DefaultDensityGradient"]@@Composition[rescale, nearest, Mean]@@p, EdgeForm[Gray], p}, {p, MeshPrimitives[dm, 2]}], Frame -> True, AspectRatio -> 1]

使用 ListContourPlot 也可以得到相似的图形：

Wolfram Language code: ListContourPlot[data, Mesh -> All, MeshStyle -> Gray, ColorFunction -> ColorData["M10DefaultDensityGradient"]]

在由点集定义的区域上求解偏微分方程：

Wolfram Language code: pts = RandomReal[1, {100, 2}];
Wolfram Language code: ℛ = DelaunayMesh[pts];
Wolfram Language code: Show[ℛ, Graphics[Point[pts]]]
Wolfram Language code: uifWave = NDSolveValue[{D[u[t, x, y], {t, 2}] - D[u[t, x, y], {x, 2}] - D[u[t, x, y], {y, 2}] == 0, u[0, x, y] == Exp[-5((x - 1.5) ^ 2 + (y - 1.5) ^ 2)], u^(1, 0, 0)[0, x, y] == 0, DirichletCondition[u[t, x, y] == 0, True]}, u, {t, 0, 2π}, {x, y}∈ℛ, Method -> {"EquationSimplification" -> "MassMatrix"}]
Wolfram Language code: Plot3D[uifWave[5, x, y], {x, y}∈ℛ, PlotRange -> RegionBounds[ℛ], Boxed -> False, Axes -> False]

创建一个在栅格上选定点的网格：

Wolfram Language code: img = ImageResize[ExampleData[{"TestImage", "Mandrill"}], 216]

初始定位点：

Wolfram Language code: pts = {{108, 174}, {136, 61}, {49, 142}, {71, 61}, {83, 124}, {165, 145}, {127, 124}, {0, 216}, {0, 4}, {64, 38}, {216, 0}, {216, 216}, {59, 204}, {160, 204}, {59, 182}, {159, 180}, {138, 39}, {100, 23}, {66, 163}, {151, 169}};

将栅格和网格区域转换为多边形的函数：

Wolfram Language code: toPolygons = Function[{img, reg}, Graphics[Table[{RGBColor@ImageValue[img, Mean@@p], p}, {p, MeshPrimitives[reg, "Polygons"]}], ImageSize -> 260]];

用于创建叠加网格的函数：

Wolfram Language code: overlay = Function[reg, Graphics[{Thickness@0.015, MeshPrimitives[reg, "Lines"]}, Background -> White]];

在图像上应用 Click 操作，以添加和删除可拖动的顶点：

Wolfram Language code: DynamicModule[{p = pts}, {LocatorPane[Dynamic@p, Pane[Dynamic@ImageCompose[img, {overlay[DelaunayMesh[p]], 0.25}]], LocatorAutoCreate -> True], Pane[Dynamic@toPolygons[img, DelaunayMesh[p]], ImageSize -> 232, ImageSizeAction -> "ShrinkToFit"]}, SaveDefinitions -> True]

属性和关系  (7)

DelaunayMesh 的输出总是全维的 MeshRegion：

Wolfram Language code: DelaunayMesh[RandomReal[1, {10, 2}]]
Wolfram Language code: {MeshRegionQ[%], RegionDimension[%]}

DelaunayMesh 由一维区间组成：

Wolfram Language code: DelaunayMesh[{{1}, {2}, {3}}]
Wolfram Language code: MeshCells[%, RegionDimension[%]]

二维中的三角：

Wolfram Language code: DelaunayMesh[{{0, 0}, {1, 0}, {0, 1}, {1, 1}}]
Wolfram Language code: MeshCells[%, RegionDimension[%]]

三维中的四面体：

Wolfram Language code: DelaunayMesh[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {1, 1, 0}}]
Wolfram Language code: MeshCells[%, RegionDimension[%]]

DelaunayMesh 中每个三角形的外接圆都不含其他点：

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {5, 2}]]

求所有三角形的外接圆：

Wolfram Language code: circles = Circumsphere@@@Normal@GraphicsComplex[MeshCoordinates[ℛ], MeshCells[ℛ, 2]];

将外接圆绘制为圆盘：

Wolfram Language code: Show[HighlightMesh[ℛ, Style[0, PointSize[Large]]], Graphics[{Orange, circles}], PlotRange -> {{0, 1}, {0, 1}}]

DelaunayMesh 中每个四面体的外接圆都不含其他点：

Wolfram Language code: ℛ = DelaunayMesh[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {0, 0, -1}}]

求所有四面体的外接圆：

Wolfram Language code: spheres = Circumsphere@@@Normal@GraphicsComplex[MeshCoordinates[ℛ], MeshCells[ℛ, 3]];

绘制外接圆：

Wolfram Language code: Show[HighlightMesh[ℛ, {Style[0, PointSize[Medium]], Style[2, Opacity[0.5]]}], Graphics3D[{Opacity[0.2], Orange, spheres}], PlotRange -> RegionBounds[ℛ], PlotRangePadding -> 0.5]

ConvexHullMesh 实际上是 DelaunayMesh 的 BoundaryMesh：

Wolfram Language code: pts = RandomReal[1, {5, 2}];
Wolfram Language code: {BoundaryMesh[DelaunayMesh[pts]], ConvexHullMesh[pts]}

使用 TriangulateMesh 对一个区域重新三角化：

Wolfram Language code: pts = RandomReal[1, {5, 2}];
Wolfram Language code: DelaunayMesh[pts]
Wolfram Language code: TriangulateMesh[%]

VoronoiMesh 是 DelaunayMesh 的对偶：

Wolfram Language code: pts = RandomReal[1, {10, 2}];
Wolfram Language code: delaunay = HighlightMesh[DelaunayMesh[pts], {Style[0, Black], Style[1, Orange], Style[2, Opacity[0.5]]}];
Wolfram Language code: voronoi = HighlightMesh[VoronoiMesh[pts], {Style[1, Green], Style[2, Opacity[0.2]]}];

每个沃罗诺伊单元都有一个来自原始点集的单点：

Wolfram Language code: Show[delaunay, voronoi]
Wolfram Research (2014)，DelaunayMesh，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DelaunayMesh.html （更新于 2015 年）.

文本

Wolfram Research (2014)，DelaunayMesh，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DelaunayMesh.html （更新于 2015 年）.

CMS

Wolfram 语言. 2014. "DelaunayMesh." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2015. https://reference.wolfram.com/language/ref/DelaunayMesh.html.

APA

Wolfram 语言. (2014). DelaunayMesh. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DelaunayMesh.html 年

BibTeX

@misc{reference.wolfram_2026_delaunaymesh, author="Wolfram Research", title="{DelaunayMesh}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/DelaunayMesh.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_delaunaymesh, organization={Wolfram Research}, title={DelaunayMesh}, year={2015}, url={https://reference.wolfram.com/language/ref/DelaunayMesh.html}, note=[Accessed: 16-September-2026]}