WOLFRAM

Wolfram 语言与系统参考资料中心

DifferenceQuotient[f,{x,h}]

给出差商 .

DifferenceQuotient[f,{x,n,h}]

给出 h 步的多重差商.

DifferenceQuotient[f,{x1,n1,h1},{x2,n2,h2},…]

计算 x1,x2,… 的偏差商.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用途  
单变量差商  
多变量差商  
选项  
Assumptions  
应用  
第一性原理的导数  
近似导数  
微分方程  
外推法  
属性和关系  
互动范例  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

DifferenceQuotient

DifferenceQuotient[f,{x,h}]

给出差商 .

DifferenceQuotient[f,{x,n,h}]

给出 h 步的多重差商.

DifferenceQuotient[f,{x1,n1,h1},{x2,n2,h2},…]

计算 x1,x2,… 的偏差商.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

计算函数的差商：

Wolfram Language code: dq = DifferenceQuotient[x Sin[x], {x, h}]

获取当 h 趋近 0 时的极限：

Wolfram Language code: Limit[%, h -> 0]

该极限为函数的导数：

Wolfram Language code: der = D[x Sin[x], x]
Wolfram Language code: Plot[{der, dq /. {h -> 0.5}, dq /. {h -> 0.3}}, {x, 0, 2π}]

范围  (16)

基本用途  (4)

计算步长 h 向前差商：

Wolfram Language code: DifferenceQuotient[f[x], {x, h}]

向后差商：

Wolfram Language code: DifferenceQuotient[f[x], {x, -h}]

对称差商：

Wolfram Language code: DifferenceQuotient[f[x - h], {x, 2h}]

计算步长 h 的二阶差商：

Wolfram Language code: DifferenceQuotient[f[x], {x, 2, h}]

三阶差商：

Wolfram Language code: DifferenceQuotient[f[x], {x, 3, h}]

步长为 r 和 s 的偏差商：

Wolfram Language code: DifferenceQuotient[f[x, y], {x, r}, {y, s}]

DifferenceQuotient 逐项作用于列表：

Wolfram Language code: DifferenceQuotient[{f[x], g[x]}, {x, h}]

单变量差商  (8)

常数的差商 DifferenceQuotient 为 0：

Wolfram Language code: DifferenceQuotient[c, {x, h}]

多项式函数的差商 DifferenceQuotient 为多项式函数：

Wolfram Language code: DifferenceQuotient[x ^ 3, {x, h}]

后一个差商 x 的次数比前一个差商少 1：

Wolfram Language code: Table[DifferenceQuotient[x ^ 4, {x, n, h}], {n, 4}]

有理函数：

Wolfram Language code: DifferenceQuotient[(x + 1) / (x + 3), {x, h}]

有理函数的差商仍保持为有理函数：

Wolfram Language code: Table[DifferenceQuotient[(x + 1) / (x + 3), {x, n, h}], {n, 2}]

三角函数：

Wolfram Language code: DifferenceQuotient[Sin[x], {x, h}]
Wolfram Language code: DifferenceQuotient[Cos[2x], {x, h}]

指数函数：

Wolfram Language code: Table[DifferenceQuotient[a ^ x, {x, n, h}], {n, 3}]

多项式指数：

Wolfram Language code: DifferenceQuotient[(x ^ 2 + x + 1)2 ^ x, {x, h}]

带有整数步长的 PolyGamma 的差商都是有理函数：

Wolfram Language code: Block[{h = 3}, Table[DifferenceQuotient[PolyGamma[n, x], {x, h}], {n, 0, 3}]]

HarmonicNumber 和 Zeta 也类似：

Wolfram Language code: DifferenceQuotient[HarmonicNumber [x, 2], {x, 3}]
Wolfram Language code: DifferenceQuotient[Zeta [2, x], {x, 3}]

h 步长的 FactorialPower 有一个与 h 步长匹配的 a 的简单差商：

Wolfram Language code: DifferenceQuotient[FactorialPower[x, n, h], {x, h}]

多变量差商  (4)

多变量多项式函数的差商 DifferenceQuotient 是多项式函数：

Wolfram Language code: DifferenceQuotient[x ^ 3 y ^ 2 + 5 x y + 11, {x, h}, {y, k}]

多变量有理函数的差商仍为有理函数：

Wolfram Language code: DifferenceQuotient[(x + y + 1) / (((x ^ 2 + 3)(y + 5))), {x, h}, {y, k}]

高阶商的表达式往往会比较长：

Wolfram Language code: DifferenceQuotient[(x + y + 1) / (((x ^ 2 + 3)(y + 5))), {x, 2, h}, {y, 2, k}]

基于变量子集的多变量函数的差商 DifferenceQuotient 为 0：

Wolfram Language code: DifferenceQuotient[f[x], {x, h}, {y, k}]
Wolfram Language code: DifferenceQuotient[ g[y], {x, h}, {y, k}]
Wolfram Language code: DifferenceQuotient[ h[x, y], {x, h}, {y, k}, {z, p}]

单变量函数的乘积的差商 DifferenceQuotient：

Wolfram Language code: DifferenceQuotient[f[x] g[y], {x, h}, {y, k}]

这等于单个差商的乘积：

Wolfram Language code: DifferenceQuotient[f[x], {x, h}]DifferenceQuotient[ g[y], {y, k}]

选项  (1)

Assumptions  (1)

若假设指定了变量 x 和步长 h，可得到更简单的结果：

Wolfram Language code: DifferenceQuotient[Abs[x], {x, h}]
Wolfram Language code: DifferenceQuotient[Abs[x], {x, h}, Assumptions -> x > 0 && h > 0]
Wolfram Language code: DifferenceQuotient[Abs[x], {x, h}, Assumptions -> x < 0 && h < 0]

应用  (10)

第一性原理的导数  (3)

计算第一性原理的多项式的导数：

Wolfram Language code: f[x_] := x ^ 2 + 5x + 7
Wolfram Language code: Limit[DifferenceQuotient[f[x], {x, h}], h -> 0]

使用 D 计算导数：

Wolfram Language code: f'[x]

指数函数：

Wolfram Language code: f[x_] := E ^ (a x)
Wolfram Language code: Limit[DifferenceQuotient[f[x], {x, h}], h -> 0]
Wolfram Language code: f'[x]

三角函数

Wolfram Language code: f[x_] := Sin[2x + 1]
Wolfram Language code: Limit[DifferenceQuotient[f[x], {x, h}], h -> 0]
Wolfram Language code: f'[x]

为幂函数计算二阶导数：

Wolfram Language code: f[x_] := x ^ n
Wolfram Language code: Limit[DifferenceQuotient[f[x], {x, 2, h}], h -> 0]
Wolfram Language code: f''[x]

超乘方 (power tower) 的三阶导数：

Wolfram Language code: f[x_] := x ^ x
Wolfram Language code: Limit[DifferenceQuotient[f[x], {x, 3, h}], h -> 0]
Wolfram Language code: f'''[x]//Simplify

计算双变量函数中 x 的偏导数：

Wolfram Language code: f[x_, y_] := Cos[x ^ 2 + E ^ (-y)]
Wolfram Language code: Plot3D[f[x, y], {x, -2, 2}, {y, -1, 1}]
Wolfram Language code: Limit[DifferenceQuotient[f[x, y], {x, h}], h -> 0]
Wolfram Language code: D[f[x, y], x]//Simplify

y 的偏导数：

Wolfram Language code: Limit[DifferenceQuotient[f[x, y], {y, k}], k -> 0]
Wolfram Language code: D[f[x, y], y]

混合偏导数：

Wolfram Language code: Limit[Limit[DifferenceQuotient[f[x, y], {x, h}, {y, k}], h -> 0], k -> 0]
Wolfram Language code: D[f[x, y], x, y]

近似导数  (3)

使用 DifferenceQuotient 求某点的近似导数：

Wolfram Language code: f[x_] := 2 x^3 - 15 x^2 + 33 x - 20
Wolfram Language code: Plot[f[x], {x, 0, 5}]

x=2.7 处的导数：

Wolfram Language code: f'[2.57]

DifferenceQuotient 给出的近似值：

Wolfram Language code: DifferenceQuotient[f[x], {x, 0.01}] /. {x -> 2.57}

使用不同的差商计算函数的近似导数：

Wolfram Language code: f[x_] := Sin[E ^ x]
Wolfram Language code: Plot[f[x], {x, 0, π}]

精确导数：

Wolfram Language code: f'[2]
Wolfram Language code: N[%]

使用向前差商获取近似值：

Wolfram Language code: hvals = {0.1, 0.01, 0.0001, 0.0001};
Wolfram Language code: fd = Table[DifferenceQuotient[f[x], {x, h}], {h, hvals}] /. {x -> 2}

向后差商：

Wolfram Language code: bd = Table[DifferenceQuotient[f[x], {x, -h}], {h, hvals}] /. {x -> 2}

对称差商：

Wolfram Language code: Table[DifferenceQuotient[f[x - h], {x, 2h}], {h, {0.1, 0.01, 0.0001, 0.0001}}] /. {x -> 2}

使用 DifferenceQuotient 计算某点处的偏导数近似值：

Wolfram Language code: f[x_, y_] := Sin[x + y]Cos[ 3y]
Wolfram Language code: Plot3D[f[x, y], {x, 0, 5}, {y, 0, 5}]
Wolfram Language code: {D[f[x, y], {x, 2}], D[f[x, y], x, y], D[f[x, y], {y, 2}]} /. {x -> 2.3, y -> 3.8}
Wolfram Language code: {DifferenceQuotient[f[x, y], {x, 2, h}], DifferenceQuotient[f[x, y], {x, h}, {y, k}], DifferenceQuotient[f[x, y], {y, 2, k}]} /. {x -> 2.3, y -> 3.8, h -> 0.001, k -> 0.002}

微分方程  (3)

使用向前差商离散化一个微分方程：

Wolfram Language code: deqn = {y'[x] == 2x - y[x], y[0] == 5};
Wolfram Language code: reqn = {DifferenceQuotient[y[x], {x, 1 / 10}] == 2x - y[x], y[0] == 5}//Simplify

使用 DSolveValue 求解微分方程：

Wolfram Language code: dsol = DSolveValue[deqn, y[x], x]
Wolfram Language code: Plot[dsol, {x, 0, 5}]

使用 RSolveValue 求解差分方程：

Wolfram Language code: rsol = RSolveValue[reqn, y[x], x]//Simplify

比较精确解和近似解：

Wolfram Language code: Table[dsol, {x, 0., 5}]
Wolfram Language code: Table[rsol, {x, 0., 5}]

使用向后差商离散化一个微分方程：

Wolfram Language code: deqn = {y'[x] == 4 - 3y[x], y[0] == 5};
Wolfram Language code: reqn = {DifferenceQuotient[y[x], {x, -1 / 10}] == 4 - 3y[x], y[0] == 5}//Simplify

使用 DSolveValue 求解微分方程：

Wolfram Language code: dsol = DSolveValue[deqn, y[x], x]
Wolfram Language code: Plot[dsol, {x, 0, 5}]

使用 RSolveValue 求解差分方程：

Wolfram Language code: rsol = RSolveValue[reqn, y[x], x]//Simplify

比较精确解和近似解：

Wolfram Language code: Table[dsol, {x, 0., 5}]
Wolfram Language code: Table[rsol, {x, 0., 5}]

使用对称差商离散化一个微分方程：

Wolfram Language code: deqn = {y'[x] == x - 3y[x], y[0] == 1};
Wolfram Language code: reqn = {DifferenceQuotient[y[x], {x, h}] == x - 3y[x], y[0] == 1}//Simplify

使用 DSolveValue 求解微分方程：

Wolfram Language code: dsol = DSolveValue[deqn, y[x], x]//Simplify
Wolfram Language code: Plot[dsol, {x, 0, 5}]

使用 RSolveValue 求解差分方程：

Wolfram Language code: rsol[h_] = RSolveValue[reqn, y[x], x]

使用向前和向后差商的差来比较精确解和近似解：

Wolfram Language code: Table[{dsol, rsol[0.1], rsol[-0.1]}, {x, 0., 5}]//TableForm

获取作为一个极限近似解的精确解：

Wolfram Language code: Limit[rsol[h], h -> 0]//FullSimplify

外推法  (1)

理查森外推法是一个应用于数列加速度的方法，可用于提高随参数 h 变化的数列 a[h] 收敛的速率. 使用数列 a[x,h] 和理查森外推法来加速 DifferenceQuotient 收敛于函数 f[x] 的导数，数列定义为：

Wolfram Language code: a[x_, h_] = DifferenceQuotient[f[x], {x, h}]

设置理查森外推法的方案：

Wolfram Language code: r[x_, h_, k_] = (k ^ 2 a[x, h] - a[x, k h]) / (k ^ 2 - 1)//Simplify

定义该函数：

Wolfram Language code: f[x_] := x Sin[E ^ (x)]

计算某点处的导数：

Wolfram Language code: f'[3.4]

DifferenceQuotient 给出的近似值：

Wolfram Language code: a[3.4, 0.001]

理查森外推法提高了导数近似度：

Wolfram Language code: Table[r[3.4, 0.001, k], {k, {0.5, 0.3, 0.0001}}]

属性和关系  (6)

DifferenceQuotient 给出连接一条曲线上相近两点的割线的斜率：

Wolfram Language code: f[x_] := x ^ 3 + 2x - 5
Wolfram Language code: diffquotient = DifferenceQuotient[f[x], {x, h}]
Wolfram Language code: % /. {x -> 3, h -> 2}
Wolfram Language code: secantslope = (f[5] - f[3]) / 2
Wolfram Language code: Show[Plot[f[x], {x, 1, 6}], Graphics[{Red, Line[{{2.5, 2.5}, {5.5, 155.5}}]}]]

差商 DifferenceQuotient 的极限 Limit 是导数 D：

Wolfram Language code: DifferenceQuotient[f[x], {x, h}]
Wolfram Language code: Limit[%, h -> 0, Analytic -> True]

多重差商的迭代极限 Limit 给出混合偏导数：

Wolfram Language code: DifferenceQuotient[f[x, y], {x, r}, {y, s}]
Wolfram Language code: Limit[Limit[%, r -> 0, Analytic -> True], s -> 0, Analytic -> True]

DifferenceQuotient 与 DifferenceDelta 的关系为 TemplateBox[{{f, (, x, )}, x, 1, h}, DifferenceDelta4]/h：

Wolfram Language code: DifferenceQuotient[f[x], {x, h}] == DifferenceDelta[f[x], {x, 1, h}] / h//Simplify
Wolfram Language code: Table[DifferenceQuotient[f[x], {x, n, h}] == DifferenceDelta[f[x], {x, n, h}] / h ^ n//Simplify, {n, 4}]//Simplify

DifferenceQuotient 与 DiscreteShift 的关系为 (TemplateBox[{{f, (, x, )}, x, 1, h}, DiscreteShift4]-f(x))/h：

Wolfram Language code: DifferenceQuotient[f[x], {x, h}] == (DiscreteShift[f[x], {x, 1, h}] - f[x]) / h//Simplify

DifferenceQuotient 是一个线性运算符：

Wolfram Language code: DifferenceQuotient[f[x] + g[x], {x, h}] == DifferenceQuotient[f[x], {x, h}] + DifferenceQuotient[g[x], {x, h}]//Together
Wolfram Language code: DifferenceQuotient[c f[x], {x, h}] == c DifferenceQuotient[f[x], {x, h}]//Together

互动范例  (1)

函数 可参数化 和 之间的割线：

Wolfram Language code: f[x_] = 10 Exp[-(x^2 - x/4)] Sin[2 x];
Wolfram Language code: g[h_, b_][x_] = f[b] + (DifferenceQuotient[f[x], {x, h}] /. (x -> b)) (x - b);

可视化割线在函数上的变化，但当 时在每个点处都变为切线：

Wolfram Language code: Manipulate[ Plot[{f[x], g[h, b][x]}, {x, -3, 3}, PlotRange -> 12, Epilog -> {AbsolutePointSize[7], Point[{{b, f[b]}, {b + h, f[b + h]}}]}], {{b, 0}, -2, 2, Appearance -> "Labeled"}, {{h, 1}, -1, 1, Appearance -> "Labeled"}, SaveDefinitions -> True]

巧妙范例  (1)

创建一个常见差商的表格：

Wolfram Language code: flist = {1, x, x ^ 2, x ^ 3, 1 / x, Sin[x], Cos[x], Sinh[x], Cosh[x], a ^ (x)};
Wolfram Language code: Grid[Transpose[{flist, DifferenceQuotient[flist, {x, h}]}], Dividers -> All, Spacings -> {4, 2}, Background -> StandardBlue, BaseStyle -> {FontFamily -> Times, FontSize -> 13}]//TraditionalForm
Wolfram Research (2016)，DifferenceQuotient，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DifferenceQuotient.html.

文本

Wolfram Research (2016)，DifferenceQuotient，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DifferenceQuotient.html.

CMS

Wolfram 语言. 2016. "DifferenceQuotient." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DifferenceQuotient.html.

APA

Wolfram 语言. (2016). DifferenceQuotient. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DifferenceQuotient.html 年

BibTeX

@misc{reference.wolfram_2026_differencequotient, author="Wolfram Research", title="{DifferenceQuotient}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/DifferenceQuotient.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_differencequotient, organization={Wolfram Research}, title={DifferenceQuotient}, year={2016}, url={https://reference.wolfram.com/language/ref/DifferenceQuotient.html}, note=[Accessed: 10-August-2026]}