WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DifferenceRootReduce[expr,n]

expr を n の関数として単一のDifferenceRootオブジェクトに簡約しようと試みる．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Assumptions  
Method  
アプリケーション  
関連項目
関連するガイド
履歴
引用書式

DifferenceRootReduce

DifferenceRootReduce[expr,n]

expr を n の関数として単一のDifferenceRootオブジェクトに簡約しようと試みる．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

フィボナッチ(Fibonacci)数列をDifferenceRootオブジェクトに簡約する：

Wolfram Language code: DifferenceRootReduce[Fibonacci[k], k]

値を比べる：

Wolfram Language code: Table[%, {k, 0, 10}]
Wolfram Language code: Table[Fibonacci[k], {k, 0, 10}]

カッシーニ(Cassini)の恒等式を証明する：

Wolfram Language code: DifferenceRootReduce[Fibonacci[k + 1]Fibonacci[k - 1] - Fibonacci[k] ^ 2 == (-1) ^ k, k]

スコープ  (9)

多項式関数：

Wolfram Language code: DifferenceRootReduce[n ^ 2 + 1, n]

有理関数：

Wolfram Language code: DifferenceRootReduce[(n + 1) / (n - 1), n]

超幾何項：

Wolfram Language code: DifferenceRootReduce[Binomial[2n, n], n]

純関数として表現された数列の簡約：

Wolfram Language code: DifferenceRootReduce[2 ^ #&]

DifferenceRootオブジェクトを検証する：

Wolfram Language code: Table[DifferentialRoot[Function[{, }, {(-[])*Log[2] + Derivative[1][][] == 0, [0] == 1}]][n], {n, 10}]

加算：

Wolfram Language code: DifferenceRootReduce[Fibonacci[n] + Exp[n], n]

項別の乗算：

Wolfram Language code: DifferenceRootReduce[Binomial[2n, n]Exp[n], n]

多分法：

Wolfram Language code: DifferenceRootReduce[Fibonacci[2n + 1], n]

一般式：

Wolfram Language code: DifferenceRootReduce[Fibonacci[n] - (-1) ^ n LucasL[2n + 1], n]

DifferenceRootReduceは自動的にリストに縫い込まれる：

Wolfram Language code: DifferenceRootReduce[{LucasL[n], n}, n]

オプション  (2)

Assumptions  (1)

DifferenceRootReduceは，変数に関する仮定に応じて，異なる漸化式構造を生成できる：

Wolfram Language code: expr = (-1)^Sqrt[n^2];

DifferenceRootReduceは，一般の場合には式を未評価のままにする：

Wolfram Language code: DifferenceRootReduce[expr, n]

という仮定の下では，DifferenceRootReduceはこの式に対する2階差分方程式を生成する：

Wolfram Language code: DifferenceRootReduce[expr, n, Assumptions -> n ≥ 0]

Method  (1)

DifferenceRootReduceは非同次方程式を与えることがある：

Wolfram Language code: DifferenceRootReduce[Fibonacci[n] + 1, n]

オプションMethod->"Homogeneous"を使って同次方程式を得る：

Wolfram Language code: DifferenceRootReduce[Fibonacci[n] + 1, n, Method -> "Homogeneous"]

アプリケーション  (3)

Fibonacciについての否定の公式を確認する：

Wolfram Language code: DifferenceRootReduce[Fibonacci[-n] == (-1) ^ (n + 1) * Fibonacci[n], n]

追加的な式：

Wolfram Language code: DifferenceRootReduce[Fibonacci[m + n] == 1 / 2(Fibonacci[m]LucasL[n] + LucasL[m]Fibonacci[n]), n]

二倍角の公式：

Wolfram Language code: DifferenceRootReduce[Fibonacci[2n] == Fibonacci[n]LucasL[n], n]

後続関係：

Wolfram Language code: DifferenceRootReduce[Fibonacci[n + 1] == 1 / 2(Fibonacci[n] + LucasL[n]), n]

共役関係：

Wolfram Language code: DifferenceRootReduce[Fibonacci[n] == 1 / 5(LucasL[n - 1] + LucasL[n + 1]), n]

有限和：

Wolfram Language code: HoldForm[Sum[Binomial[2m + 1, 2k]3 ^ k / (5 2 ^ m), {k, 0, m}]]

差分方程式は のすべての値が奇数であることを示している：

Wolfram Language code: DifferenceRootReduce[Sum[Binomial[2m + 1, 2k]3 ^ k / (5 2 ^ m), {k, 0, m}] /. m -> 3n + 1, n]
Wolfram Language code: Table[%, {n, 0, 10}]//Simplify

パドヴァン(Padovan)数を定義する：

Wolfram Language code: PadovanNumber = DifferenceRoot[Function[{y, n}, {-y[n] - y[1 + n] + y[3 + n] == 0, y[0] == 1, y[1] == 1, y[2] == 1}]]
Wolfram Language code: Table[PadovanNumber[n], {n, 0, 10}]

再帰関係を証明する：

Wolfram Language code: DifferenceRootReduce[PadovanNumber[n] == PadovanNumber[n - 2] + PadovanNumber[n - 3], n]
Wolfram Language code: DifferenceRootReduce[PadovanNumber[n] == PadovanNumber[n - 4] + PadovanNumber[n - 5] + PadovanNumber[n - 6] + PadovanNumber[n - 7] + PadovanNumber[n - 8], n]

和の恒等式を証明する：

Wolfram Language code: DifferenceRootReduce[Sum[PadovanNumber[3k + 2], {k, 0, n}] == PadovanNumber[3n + 4] - 1, n]
Wolfram Research (2008), DifferenceRootReduce, Wolfram言語関数， https://reference.wolfram.com/language/ref/DifferenceRootReduce.html （2020年に更新）.

テキスト

Wolfram Research (2008), DifferenceRootReduce, Wolfram言語関数， https://reference.wolfram.com/language/ref/DifferenceRootReduce.html （2020年に更新）.

CMS

Wolfram Language. 2008. "DifferenceRootReduce." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/DifferenceRootReduce.html.

APA

Wolfram Language. (2008). DifferenceRootReduce. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DifferenceRootReduce.html

BibTeX

@misc{reference.wolfram_2026_differencerootreduce, author="Wolfram Research", title="{DifferenceRootReduce}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/DifferenceRootReduce.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_differencerootreduce, organization={Wolfram Research}, title={DifferenceRootReduce}, year={2020}, url={https://reference.wolfram.com/language/ref/DifferenceRootReduce.html}, note=[Accessed: 06-September-2026]}