WOLFRAM

Wolfram 语言与系统参考资料中心

DifferentialRoot[lde][x]

给出由线性微分方程 lde[h,x] 指定的完整函数 .

DifferentialRoot[lde]

表示纯完整函数 .

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
函数属性  
微分  
积分  
级数展开  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

DifferentialRoot

DifferentialRoot[lde][x]

给出由线性微分方程 lde[h,x] 指定的完整函数 .

DifferentialRoot[lde]

表示纯完整函数 .

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

定义 f 为正弦函数：

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}]]

绘制其结果：

Wolfram Language code: Plot[f[x], {x, 0, 2Pi}]

计算并保留结果到任意精度：

Wolfram Language code: f[N[1 + I, 30]]

将结果与内置正弦函数进行比较：

Wolfram Language code: Sin[N[1 + I, 30]]

求解一个微分方程：

Wolfram Language code: DSolve[y'''[x] - x^2 y'[x] - y[x] - Cos[x] == 0 && y[0] == 0 && y'[0] == 1 && y''[0] == 0, y, x]

数值值：

Wolfram Language code: Table[y[n] /. First[%], {n, 1, 2, 0.2}]

范围  (23)

数值计算  (7)

在机器精度下进行计算：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'[x] - y[x] == 0, y[0] == 1}]][0.5]

在高精度下进行计算：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'[x] - y[x] == 0, y[0] == 1}]][1 / 2`50]

输出的精度可以追溯输入的精度：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'[x] - y[x] == 0, y[0] == 1}]][0.10000000000000000001]

DifferentialRoot 使用复数的形式参数和实用参数：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + y'[x] - y[x] == 0, y[1 / 2] == 1, y'[1 / 2] == -3 / 4}]][1 / 2 + 1.I]
Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + I y'[x] - y[x] == 0, y[1 / 2] == 1 + 4I, y'[1 / 2] == -3 / 4}]][1 / 2 + 1.I]

DifferentialRoot 使用不精确的输入参数：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + y'[x] - y[x] == 0, y[1 / 2] == 1`20, y'[1 / 2] == -3 / 4}]][1 / 2 + 1I]
Wolfram Language code: Precision[%]

高效地在高精度下计算 DifferentialRoot：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + I y'[x] - y[x] == 0, y[1 / 2] == 1 + 4I, y'[1 / 2] == -3 / 4}]][2 / 10`100]//N//Timing

DifferentialRoot 以元素方式线性作用于（threads over）列表和矩阵：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + I y'[x] - y[x] == 0, y[1 / 2] == 1 + 4I, y'[1 / 2] == -3 / 4}]][{0.2, 1.4}]
Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + I y'[x] - y[x] == 0, y[1 / 2] == 1 + 4I, y'[1 / 2] == -3 / 4}]][(| | | | :------- | :------- | | 3.1 | 1 / 3`20 | | 4 / 5`20 | 0.4 |)]

函数属性  (5)

DifferentialRoot 对象具有数学函数的所有标准特点：

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {y'''[x] + 2x y''[x] - y[x] == 0, y[1 / 2] == 1, y'[1 / 2] == -3 / 4, y''[1 / 2] == 0}]]

对函数积分：

Wolfram Language code: Integrate[f[x], x]

求函数的微分：

Wolfram Language code: D[f[x], x]

求其级数展开：

Wolfram Language code: Series[f[x], {x, 1 / 2, 3}]

在实数轴上绘制：

Wolfram Language code: Plot[f[x], {x, -10, 10}]

在复数平面中绘制：

Wolfram Language code: ComplexPlot[f[z], {z, 5}, RasterSize -> 50, PlotLegends -> Automatic]

自动生成简单精确值：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}]][Pi / 2]

使用 FunctionExpand 尝试将 DifferentialRoot 对象转换为一个内置数学函数：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}]][x]
Wolfram Language code: %//FunctionExpand

DifferentialRoot 作用于有有理系数的方程：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'''[x] / x + y[x] == 0, y[0] == 0, y'[0] == 1, y''[0] == 0}]]

非齐次完全方程式自动转换为更高阶的齐次方程式：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'[x] - y[x] - Cos[x] == 0, y[0] == 1}]]

微分  (4)

DifferentialRoot 的导数是一个 DifferentialRoot 函数：

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x + y[x] + y'[x] == 0, y[0] == 1}]][x]
Wolfram Language code: D[%, x]

求关于参数的 DifferentialRoot 对象的微分：

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x + a y[x] + y'[x] == 0, y[0] == 1}]]
Wolfram Language code: D[f[x], a]

计算 DifferentialRoot 对象更高阶的导数：

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x + a y[x] + y'[x] == 0, y[0] == 1}]][x]
Wolfram Language code: D[f, {x, 2}]
Wolfram Language code: D[f, x, a]
Wolfram Language code: D[f, {a, 2}]

求 DifferentialRoot 对象的微分：

Wolfram Language code: df = D[DifferentialRoot[Function[{y, x}, {4x^2 - y[x] + y'[x] == 0, y[0] == 1}]][x], x]

的特定值：

Wolfram Language code: df /. x -> RandomReal[{-5, 5}, 5]

绘制 ：

Wolfram Language code: Plot[df, {x, -5, 5}]

积分  (4)

DifferentialRoot 对象的积分是一个 DifferentialRoot 对象：

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x + y[x] + y'[x] == 0, y[0] == 1}]]
Wolfram Language code: Integrate[f[x], x]

计算 DifferentialRoot 对象的更高阶积分：

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x + a y[x] + y'[x] == 0, y[0] == 1}]][x]
Wolfram Language code: Integrate[f, x, x]

计算 DifferentialRoot 对象的定积分：

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x^2 + y[x] + y'[x] == 0, y[0] == 1}]]
Wolfram Language code: Subsuperscript[∫, -1, 1]f[x]ⅆx

求 DifferentialRoot 对象的积分：

Wolfram Language code: F = Integrate[DifferentialRoot[Function[{y, x}, {x^2 + x y[x] + y'[x] == 0, y[0] == 1}]][x], x]

的特定值：

Wolfram Language code: F /. x -> RandomReal[{-5, 5}, 5]

绘制 ：

Wolfram Language code: Plot[F, {x, -5, 5}]

级数展开  (3)

计算 DifferentialRoot 对象的级数展开：

Wolfram Language code: Series[DifferentialRoot[Function[{y, x}, {y''[x] + y[x] == 0, y[0] == 1, y'[0] == 1}]][x], {x, 0, 5}]

计算 DifferentialRoot 对象的泰勒展开式的第 个系数：

Wolfram Language code: SeriesCoefficient[DifferentialRoot[Function[{y, x}, {y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}]][x], {x, 0, n}]

计算前 9 个系数：

Wolfram Language code: Table[%, {n, 0, 9}]

与 Sin 函数展开系数进行比较：

Wolfram Language code: CoefficientList[Series[Sin[x], {x, 0, 10}]//Normal, {x}]

计算有一个参数的 DifferentialRoot 对象的级数展开：

Wolfram Language code: Series[DifferentialRoot[Function[{y, x}, {y''[x] + a y[x] == 0, y[0] == 1, y'[0] == 1}]][x], {x, 0, 5}]

推广和延伸  (1)

有完整常数项的方程自动提升为多项式系数：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'[x] - y[x] - Cos[x] == 0, y[0] == 1}]]

应用  (4)

从特殊函数中生成 DifferentialRoot 对象：

Wolfram Language code: DifferentialRootReduce[BesselJ[2, Sqrt[x ^ 2 + 1]], x]

求其积分：

Wolfram Language code: Integrate[%, x]

DifferentialRoot 对象有数学函数的所有标准特点：

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {y'''[x] + 2x y''[x] - y[x] == 0, y[1 / 2] == 1, y'[1 / 2] == -3 / 4, y''[1 / 2] == 0}]][x]

求 DifferentialRoot 对象的级数展开的系数：

Wolfram Language code: SeriesCoefficient[f, {x, 1 / 2, n}]

计算展开的前 5 个系数：

Wolfram Language code: Table[%, {n, 0, 5}]

计算 DifferentialRoot 对象的任意阶导数：

Wolfram Language code: df = D[f, x]
Wolfram Language code: D[f, {x, 4}]

求 DifferentialRoot 对象的积分：

Wolfram Language code: F = Integrate[f, x]

该函数为 f 的积分，提取该函数的微分方程和初始条件：

Wolfram Language code: %[[0, 1]][y, x]

绘制函数 f、其积分和导数函数：

Wolfram Language code: Plot[{f, F, df}, {x, -10, 10}]

使用 DifferentialRoot 齐次化微分方程：

Wolfram Language code: dr = DifferentialRoot[Function[{y, x}, {y''[x] - x y[x] == Cos[x^2], y[0] == 1, y'[0] == -3 / 4 I}]]

提取齐次方程：

Wolfram Language code: dr[[1]][y, x]

生成一个作为两个数学函数的组合的 DifferentialRoot 对象：

Wolfram Language code: DifferentialRootReduce[Sin[x] + 4 x Cos[x], x]

提取这个函数遵循的微分方程和初始条件：

Wolfram Language code: %[[0, 1]][y, x]

属性和关系  (5)

DifferentialRootReduce 生成 DifferentialRoot 对象：

Wolfram Language code: DifferentialRootReduce[Cos[x], x]

若无法从已知函数中获取解，则 DSolve 生成一个 DifferentialRoot 对象：

Wolfram Language code: DSolve[y'''[x] + y'[x] + x^3y[x] == 0, y[x], x]

GeneratingFunction 可能生成一个 DifferentialRoot 对象：

Wolfram Language code: GeneratingFunction[DifferenceRoot[Function[{y, n}, {y[n] + (1 + n) (2 + n) y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n, x]

Integrate 为一般完全函数返回 DifferentialRoot 对象：

Wolfram Language code: Integrate[DifferentialRoot[Function[{y, x}, {x + y[x] + y'[x] == 0, y[0] == 1}]][x], x]

D 为一般完全函数返回 DifferentialRoot 对象：

Wolfram Language code: D[DifferentialRoot[Function[{y, x}, {x + y[x] + y'[x] == 0, y[0] == 1}]][x], x]

可能存在的问题  (3)

DifferentialRoot 只接受有多项式系数的线性微分方程：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {Sqrt[x]y''[x] - x y^2[x] == 0, y[0] == 1, y'[0] == -3 / 4 I}]][x]

若给定的初始值为奇点，则 DifferentialRoot 不会计算：

Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + y'[x] - y[x] == 0, y[0] == 1, y'[0] == -3 / 4 I}]][x]

内置函数的分支剪界结构可能与自动计算的分支剪界结构不同：

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x (x - 1)y''[x] + ((1 + 1 / 2 + 1 / 3)x - 1 / 4)y'[x] + 1 / 2 * 1 / 3y[x] == 0, y[1 + I] == Hypergeometric2F1[1 / 2, 1 / 3, 1 / 4, 1 + I], y'[1 + I] == (D[Hypergeometric2F1[1 / 2, 1 / 3, 1 / 4, z], z] /. z -> 1 + I)}]]

对于复平面的一些区域而言，f 的值与其对应的内置函数值不同：

Wolfram Language code: f[2. - I]
Wolfram Language code: Hypergeometric2F1[1 / 2, 1 / 3, 1 / 4, 2. - I]

对于其他区域而言， DifferentialRoot 会给出同样的结果：

Wolfram Language code: f[3. + 4I]
Wolfram Language code: Hypergeometric2F1[1 / 2, 1 / 3, 1 / 4, 3. + 4I]

巧妙范例  (1)

求解一个使用已知数学函数无法解决的微分方程：

Wolfram Language code: sol = DSolveValue[{y''[x] + (x^10 - 1)y[x] == 0, y[0] == 1 / 2, y'[0] == -3 / 4}, y[x], x]

计算该解的数值：

Wolfram Language code: Table[sol, {x, 0., 1, 0.2}]

绘制该解：

Wolfram Language code: Plot[sol, {x, -3, 3}]

对该解求微分：

Wolfram Language code: dsol = D[sol, x]
Wolfram Research (2008)，DifferentialRoot，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DifferentialRoot.html （更新于 2020 年）.

文本

Wolfram Research (2008)，DifferentialRoot，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DifferentialRoot.html （更新于 2020 年）.

CMS

Wolfram 语言. 2008. "DifferentialRoot." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/DifferentialRoot.html.

APA

Wolfram 语言. (2008). DifferentialRoot. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DifferentialRoot.html 年

BibTeX

@misc{reference.wolfram_2026_differentialroot, author="Wolfram Research", title="{DifferentialRoot}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/DifferentialRoot.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_differentialroot, organization={Wolfram Research}, title={DifferentialRoot}, year={2020}, url={https://reference.wolfram.com/language/ref/DifferentialRoot.html}, note=[Accessed: 14-September-2026]}