WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Discard[data,crit]

crit[ei]がTrueになる data のすべての要素 eiを削除する．

Discard[data,critprop]

残された要素の特性 prop を返す．

Discard[data,crit,n]

crit[ei]がTrueになる最初の n 個の要素を削除する．

Discard[crit]

式に適用可能なDiscardの演算子形を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
入力データ  
特性の形式  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

Discard

Discard[data,crit]

crit[ei]がTrueになる data のすべての要素 eiを削除する．

Discard[data,critprop]

残された要素の特性 prop を返す．

Discard[data,crit,n]

crit[ei]がTrueになる最初の n 個の要素を削除する．

Discard[crit]

式に適用可能なDiscardの演算子形を表す．

詳細

  • Discardは，指定された基準 crit がFalseとなる要素を保持する．
  • data は，次の形式と解釈を持つことができる．
  • {e1,e2,…}値のリスト »
    f[e1,e2,…]任意の頭部 f »
    Association[…]値の連想 »
    QuantityArray[…]数量配列またはその他の構造化配列
    Tabular[…]一貫した型の表形式データ »
    TabularColumn[…]一貫した型の列データ »
    Dataset[…]階層データを生成する
    TimeSeries[…]サンプルとして取られた時点と値のペアの集合
    EventSeries[…]一連の時間的事象
  • 特性 prop は，次の追加的な形式と解釈を持つことができる．
  • "Element"残りの値 »
    "Index"残りの値のインデックス »
    "BitVectorMask"選択された値にはTrueを，それ以外にはFalseを返すブールマスク »
    {prop1,prop2,…}複数の形式のリスト »
    All要素，インデックス，ビットベクトルマスクを与える連想 »
  • Discard[crit][data]はDiscard[data,crit]に等しい．

例題

すべて開く すべて閉じる

例  (6)

偶数要素を削除する：

Wolfram Language code: Discard[{1, 2, 4, 7, 6, 2}, EvenQ]

残っている要素のインデックスを返す：

Wolfram Language code: Discard[{1, 2, 4, 7, 6, 2}, # > 2& -> "Index"]

選択された最初の式だけを削除する：

Wolfram Language code: Discard[{1, 2, 4, 7, 6, 2}, OddQ, 1]

Discardの演算子形を使う：

Wolfram Language code: Discard[EvenQ][{1, 2, 4, 7, 6, 2}]

DiscardはAssociationの中の値を操作する：

Wolfram Language code: Discard[<|a -> 1, b -> 2, c -> 3, d -> 4|>, # > 2&]

Tabularオブジェクトの行を削除する：

Wolfram Language code: Tabular[{{"cat", 2}, {"fox", 3}, {"dog", 5}}, {"a", "b"}]
Wolfram Language code: Discard[%, OddQ[#b]&]

スコープ  (15)

基本的な用法  (5)

x を含むペアを削除する：

Wolfram Language code: Discard[{{1, y}, {2, x}, {3, x}, {4, z}, {5, x}, {6, y}}, MemberQ[#, x]&]

x を含むペアを2つまで削除する：

Wolfram Language code: Discard[{{1, y}, {2, x}, {3, x}, {4, z}, {5, x}, {6, y}}, MemberQ[#, x]&, 2]

純関数を使って各要素をテストする：

Wolfram Language code: Discard[{1, 2, 4, 7, 6, 2}, # > 2&]

選択基準として演算子形を使う：

Wolfram Language code: Discard[Range[10], GreaterThan[3]]

Discardを演算子形で使う：

Wolfram Language code: Range[10]//Select[GreaterThan[3]]

入力データ  (5)

Discardは，Listだけでなく任意の頭部に使える：

Wolfram Language code: Discard[f[1, a, 2, b, 3], IntegerQ]

DiscardはAssociation内の値に使うことができる：

Wolfram Language code: Discard[<|"a" -> {.1, .3, .2}, "b" -> {"dog", "cat", "fox"}|>, AllTrue[#, StringQ]&]

Discardは，ベクトルSparseArrayオブジェクトに使うことができる：

Wolfram Language code: s = SparseArray[Table[2 ^ i -> i, {i, 0, 4}]]
Wolfram Language code: Discard[s, OddQ]

結果は，疎でなければリストかもしれない：

Wolfram Language code: Discard[s, EvenQ]

DiscardはTabularオブジェクトに使うことができる：

Wolfram Language code: TabularColumn[RandomDate[10 ^ 5]]

偶数の日付をすべて削除する：

Wolfram Language code: Discard[EvenQ[DateValue[#, "Day"]]&][%]

日付の分布は一様である：

Wolfram Language code: DateHistogram[Normal[%]]

名前付きの列があるTabularオブジェクトにDiscardを使う：

Wolfram Language code: tab = ToTabular[{"a" -> {1, 2, 3}, "b" -> {.1, .3, .2}, "c" -> {"dog", "cat", "fox"}, "d" -> {DateObject[{2024, 8, 1}], DateObject[{2024, 8, 2}], DateObject[{2024, 8, 3}]}}, "Columns"]

最後の列の日付が営業日である行を削除する：

Wolfram Language code: Discard[tab, Function[BusinessDayQ[#d]]]
Wolfram Language code: Normal[%]

特性の形式  (5)

残った要素を返す：

Wolfram Language code: Discard[Range[10], OddQ -> "Element"]

残った要素のインデックスを返す：

Wolfram Language code: Discard[Range[10], OddQ -> "Index"]

データのブールマスクを返す：

Wolfram Language code: Discard[Range[10], OddQ -> "BitVectorMask"]
Wolfram Language code: Normal[%]

2つの形式を返す：

Wolfram Language code: Discard[Range[10], OddQ -> {"Element", "Index"}]

すべての特性を持つ連想を返す：

Wolfram Language code: Discard[Range[10], OddQ -> All]

アプリケーション  (8)

100までの数のうち4で割り切れるものを削除する：

Wolfram Language code: Discard[Range[100], Mod[#, 4] == 0&]

逆に読んでも同じになる4個一組の最初の3つを削除する：

Wolfram Language code: Discard[Tuples[{a, b}, 4], # == Reverse[#]&, 3]

行列式が2未満の0と1からなる3×3行列を削除する：

Wolfram Language code: Discard[Tuples[{0, 1}, {3, 3}], Det[#] < 2&]

単位円内にある固有値を削除する：

Wolfram Language code: Discard[Eigenvalues[RandomReal[1, {5, 5}]], Abs[#] < 1&]

名前が36文字以上の組込みのWolfram言語オブジェクトを求める：

Wolfram Language code: Discard[Names["*"], StringLength[#] < 36&]

積から数量を取り除く：

Wolfram Language code: Discard[7 π^2 x^2 y^2, NumericQ]

円板内にある点の比を求めることで の近似を求める：

Wolfram Language code: app[n_] := 4N[Length[Discard[RandomReal[{-1, 1}, {n, 2}], Dot[#, #] > 1&]] / n]
Wolfram Language code: TableForm[Table[n = 10 ^ k;p = app[n];{n, p, π - p}, {k, 1, 6}], TableHeadings -> {{}, {"n", "approximation", "error"}}]

JFK空港からの気象データ：

Wolfram Language code: data = Tabular[{...}]

TabularStructureを使って欠落データの数を調べる：

Wolfram Language code: TabularStructure[data]

少なくとも2つの欠落値がある行を削除する：

Wolfram Language code: Discard[data, Count[#, _Missing] >= 2&]
Wolfram Language code: TabularStructure[%]

特性と関係  (3)

DiscardはSelectを補完する：

Wolfram Language code: data = RandomInteger[100, 10]
Wolfram Language code: Discard[data, PrimeQ]
Wolfram Language code: Select[data, PrimeQ]
Wolfram Language code: Union[%%, %] == Union@data

DiscardはCasesに似ているが，パターンの代りに関数を使う点が違う：

Wolfram Language code: list = RandomInteger[9, {10, 2}]

要素の和が10より大きいリストを削除する：

Wolfram Language code: f = Total[#] > 10&;
Wolfram Language code: Discard[list, f]

Casesを使って同じ結果を得る：

Wolfram Language code: Cases[list, x_ /; !f[x]]

偶数要素を削除する：

Wolfram Language code: Discard[Range[10], EvenQ]

GatherByを使って奇数要素と偶数要素を分離する：

Wolfram Language code: GatherBy[Range[10], EvenQ]

GroupByを使って基準関数の結果を明示的にキーとして持つ連想を構築する：

Wolfram Language code: GroupBy[Range[10], EvenQ]

考えられる問題  (2)

Discardは基準を適用すると明示的にTrueが返される要素を削除する：

Wolfram Language code: Discard[{1, 2, 4, 7, x}, # > 2&]
Wolfram Language code: Discard[{1, 2, 4, 7, x}, # <= 2&]

どちらの不等式もTrueにならないため，記号オブジェクトxは両方の場合に含まれる：

Wolfram Language code: {x > 2, x <= 2}

入力式の頭部はデフォルトの"Element"特性についてのみ保持される：

Wolfram Language code: Discard[f@@{1, 2, 4, 7, 8}, # > 2& -> All]
Wolfram Research (2025), Discard, Wolfram言語関数， https://reference.wolfram.com/language/ref/Discard.html （2026年に更新）.

テキスト

Wolfram Research (2025), Discard, Wolfram言語関数， https://reference.wolfram.com/language/ref/Discard.html （2026年に更新）.

CMS

Wolfram Language. 2025. "Discard." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/Discard.html.

APA

Wolfram Language. (2025). Discard. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Discard.html

BibTeX

@misc{reference.wolfram_2026_discard, author="Wolfram Research", title="{Discard}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/Discard.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_discard, organization={Wolfram Research}, title={Discard}, year={2026}, url={https://reference.wolfram.com/language/ref/Discard.html}, note=[Accessed: 14-September-2026]}