WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DocumentNotebook[{cell1,cell2,…}]

Wolframシステムのフロントエンドの完全なドキュメントノートブックを表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Background  
CellDingbat  
CellGrouping  
TextAlignment  
Visible  
アプリケーション  
特性と関係  
関連項目
関連するガイド
関連するワークフロー
履歴
引用書式

DocumentNotebook

DocumentNotebook[{cell1,cell2,…}]

Wolframシステムのフロントエンドの完全なドキュメントノートブックを表す．

詳細とオプション

  • CreateWindowはDocumentNotebook式を取り，別のウィンドウにこれを表示する．
  • ノートブック内の出力として生成された場合，DocumentNotebookはノートブックのセル内の表現として表示される．
  • DocumentNotebookは任意のノートブックオプションを取ることができる．

例題

すべて開く すべて閉じる

例  (2)

2つのセルがあるドキュメントノートブック表現を作成する：

Wolfram Language code: DocumentNotebook[{x + y, 1 / x + 1 / y}]

セルのスタイルを指定する：

Wolfram Language code: DocumentNotebook[{TextCell["見出し", "Section"], TextCell["最初のセル"]}]

スコープ  (3)

二次元タイプセット式の入ったノートブック：

Wolfram Language code: DocumentNotebook[{TextCell["S1", "Section"], ExpressionCell[x ^ 2, "Input"]}]

グラフィックスの入ったノートブック：

Wolfram Language code: DocumentNotebook[{Plot[x ^ 2, {x, -1, 1}]}]

格子の入ったノートブック：

Wolfram Language code: DocumentNotebook[{Grid[Array[a, {2, 3}]]}]

オプション  (5)

Background  (1)

背景色を設定する：

Wolfram Language code: CreateWindow[DocumentNotebook[{a, b}, Background -> RGBColor[1, .9, .7]]];

CellDingbat  (1)

セルの見出し記号を設定する：

Wolfram Language code: CreateWindow[DocumentNotebook[{a, b}, CellDingbat -> ""]];

CellGrouping  (1)

手動グループ化セルでドキュメントを作る：

Wolfram Language code: CreateWindow[DocumentNotebook[{CellGroup[{a, b}], c}, CellGrouping -> Manual]];

TextAlignment  (1)

コンテンツを右揃えにする：

Wolfram Language code: CreateWindow[DocumentNotebook[{a, b}, TextAlignment -> Right]];

Visible  (1)

不可視のノートブックを作成する：

Wolfram Language code: nb = CreateWindow[DocumentNotebook[{a, b}, Visible -> False]];

ノートブックが見えるようにする：

Wolfram Language code: SetOptions[nb, Visible -> True]

アプリケーション  (2)

標準的なドキュメントのためのテンプレートを定義する：

Wolfram Language code: mammalPage[common_, picture_, order_, family_, species_] := DocumentNotebook[Style[Grid[{{Style[common, FontSize -> 18], SpanFromLeft}, {picture, Column[Row[{#1, "：", Style[#2, FontWeight -> Bold]}]&@@@{{"目", order}, {"科", family}, {"種", species}}]}}, Frame -> True], FontFamily -> "Arial", ShowStringCharacters -> False]]
Wolfram Language code: CreateWindow[mammalPage["オセロット", Import["ExampleData/ocelot.jpg"], "食肉目", "猫科", "Leopardus pardalis"]];

リスト構造をドキュメント構造に変換する：

Wolfram Language code: outline[l_List] := l //. {s_String, r___} :> f[s, r] /. s_String :> TextCell[s] //. f[c__] :> CellGroup[{c}]
Wolfram Language code: outline[{"第1章", {"第1節", "a"}, {"第2節", "b", "c"}}]//InputForm
Wolfram Language code: CreateWindow[DocumentNotebook[%, CellGrouping -> Manual]];

特性と関係  (2)

CreateWindowを使ってNotebookObjectを得る：

Wolfram Language code: nb = CreateWindow[DocumentNotebook[{a, b, c}]];

NotebookObjectをノートブックに作用するコマンド内で使用する：

Wolfram Language code: SelectionMove[nb, Next, Cell]
Wolfram Language code: NotebookRead[nb]
Wolfram Language code: NotebookDelete[nb]

PaletteNotebookオブジェクトとDialogNotebookオブジェクトは主にユーザインターフェースのツールとして使われる：

Wolfram Language code: PaletteNotebook[{"平方根", Button[Sqrt[π], p = N[Sqrt[π]]]}]
Wolfram Language code: DialogNotebook[{TextCell[Row[{"お名前：", InputField[]}]]}]
Wolfram Research (2007), DocumentNotebook, Wolfram言語関数， https://reference.wolfram.com/language/ref/DocumentNotebook.html.

テキスト

Wolfram Research (2007), DocumentNotebook, Wolfram言語関数， https://reference.wolfram.com/language/ref/DocumentNotebook.html.

CMS

Wolfram Language. 2007. "DocumentNotebook." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DocumentNotebook.html.

APA

Wolfram Language. (2007). DocumentNotebook. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DocumentNotebook.html

BibTeX

@misc{reference.wolfram_2026_documentnotebook, author="Wolfram Research", title="{DocumentNotebook}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/DocumentNotebook.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_documentnotebook, organization={Wolfram Research}, title={DocumentNotebook}, year={2007}, url={https://reference.wolfram.com/language/ref/DocumentNotebook.html}, note=[Accessed: 10-September-2026]}