WOLFRAM

Wolfram 语言与系统参考资料中心

DocumentNotebook[{cell1,cell2,…}]

表示 Wolfram 系统前端的一个完整的文件笔记本.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Background  
CellDingbat  
CellGrouping  
TextAlignment  
Visible  
应用  
属性和关系  
参见
相关指南
相关的工作流程
历史
按以下格式引用：

DocumentNotebook

DocumentNotebook[{cell1,cell2,…}]

表示 Wolfram 系统前端的一个完整的文件笔记本.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

创建一个含有两个单元的文档笔记本的表示：

Wolfram Language code: DocumentNotebook[{x + y, 1 / x + 1 / y}]

指明单元的样式：

Wolfram Language code: DocumentNotebook[{TextCell["The head", "Section"], TextCell["first cell"]}]

范围  (3)

带有二维排版表达式的笔记本：

Wolfram Language code: DocumentNotebook[{TextCell["S1", "Section"], ExpressionCell[x ^ 2, "Input"]}]

带有图形的笔记本：

Wolfram Language code: DocumentNotebook[{Plot[x ^ 2, {x, -1, 1}]}]

带有网格的笔记本：

Wolfram Language code: DocumentNotebook[{Grid[Array[a, {2, 3}]]}]

选项  (5)

Background  (1)

设置背景颜色：

Wolfram Language code: CreateWindow[DocumentNotebook[{a, b}, Background -> RGBColor[1, .9, .7]]];

CellDingbat  (1)

设置单元标志：

Wolfram Language code: CreateWindow[DocumentNotebook[{a, b}, CellDingbat -> ""]];

CellGrouping  (1)

生成一个带有手动分组单元的文件：

Wolfram Language code: CreateWindow[DocumentNotebook[{CellGroup[{a, b}], c}, CellGrouping -> Manual]];

TextAlignment  (1)

内容向右对齐：

Wolfram Language code: CreateWindow[DocumentNotebook[{a, b}, TextAlignment -> Right]];

Visible  (1)

生成一个不可视的笔记本：

Wolfram Language code: nb = CreateWindow[DocumentNotebook[{a, b}, Visible -> False]];

显示笔记本：

Wolfram Language code: SetOptions[nb, Visible -> True]

应用  (2)

为标准文件定义一个模板：

Wolfram Language code: mammalPage[common_, picture_, order_, family_, species_] := DocumentNotebook[Style[Grid[{{Style[common, FontSize -> 18], SpanFromLeft}, {picture, Column[Row[{#1, ": ", Style[#2, FontWeight -> Bold]}]&@@@{{"Order", order}, {"Family", family}, {"Species", species}}]}}, Frame -> True], FontFamily -> "Arial", ShowStringCharacters -> False]]
Wolfram Language code: CreateWindow[mammalPage["Ocelot", Import["ExampleData/ocelot.jpg"], "Carnivora", "Felidae", "Leopardus pardalis"]];

把列表结构转化成文件结构：

Wolfram Language code: outline[l_List] := l //. {s_String, r___} :> f[s, r] /. s_String :> TextCell[s] //. f[c__] :> CellGroup[{c}]
Wolfram Language code: outline[{"Chap. 1", {"Sec. 1", "a"}, {"Sec. 2", "b", "c"}}]//InputForm
Wolfram Language code: CreateWindow[DocumentNotebook[%, CellGrouping -> Manual]];

属性和关系  (2)

用 CreateWindow 得到 NotebookObject：

Wolfram Language code: nb = CreateWindow[DocumentNotebook[{a, b, c}]];

在笔记本的行为中用 NotebookObject：

Wolfram Language code: SelectionMove[nb, Next, Cell]
Wolfram Language code: NotebookRead[nb]
Wolfram Language code: NotebookDelete[nb]

PaletteNotebook 和 DialogNotebook 对象主要用于用户接口工具：

Wolfram Language code: PaletteNotebook[{"Square root", Button[Sqrt[π], p = N[Sqrt[π]]]}]
Wolfram Language code: DialogNotebook[{TextCell[Row[{"Your name:", InputField[]}]]}]
Wolfram Research (2007)，DocumentNotebook，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DocumentNotebook.html.

文本

Wolfram Research (2007)，DocumentNotebook，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DocumentNotebook.html.

CMS

Wolfram 语言. 2007. "DocumentNotebook." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DocumentNotebook.html.

APA

Wolfram 语言. (2007). DocumentNotebook. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DocumentNotebook.html 年

BibTeX

@misc{reference.wolfram_2026_documentnotebook, author="Wolfram Research", title="{DocumentNotebook}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/DocumentNotebook.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_documentnotebook, organization={Wolfram Research}, title={DocumentNotebook}, year={2007}, url={https://reference.wolfram.com/language/ref/DocumentNotebook.html}, note=[Accessed: 11-September-2026]}