WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EllipticPi[n,m]

第3種完全楕円積分 TemplateBox[{n, m}, EllipticPi]を与える．

EllipticPi[n,ϕ,m]

不完全楕円積分 TemplateBox[{n, phi, m}, EllipticPi3]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数表現  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

EllipticPi

EllipticPi[n,m]

第3種完全楕円積分 TemplateBox[{n, m}, EllipticPi]を与える．

EllipticPi[n,ϕ,m]

不完全楕円積分 TemplateBox[{n, phi, m}, EllipticPi3]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 実数 および について，，のときTemplateBox[{n, phi, m}, EllipticPi3]=int_0^phi(1-n sin^2(theta))^(-1)[1-m sin^2(theta)]^(-1/2)dtheta．ただし，主値積分は について既知である．
  • TemplateBox[{n, m}, EllipticPi]=TemplateBox[{n, {pi, /, 2}, m}, EllipticPi3]
  • EllipticPi[n,m]は，およびに不連続な分枝切断線を持つ．
  • EllipticPi[n,ϕ,m]は，，，に不連続な分枝切断線を持つ．
  • 特別な引数の場合，EllipticPiは，自動的に厳密値を計算する．
  • EllipticPiは任意の数値精度で評価できる．
  • EllipticPi自動的にリストに縫い込まれる．
  • EllipticPiはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (6)

数値的に評価する：

Wolfram Language code: EllipticPi[0.4, 0.6]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[EllipticPi[n, 0.6], {n, 0, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[EllipticPi[z, 0.5], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

不完全楕円積分を複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[EllipticPi[z, Pi / 3, -2], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[EllipticPi[n, ϕ, m], {m, 0, 1}]
Wolfram Language code: Series[EllipticPi[n, ϕ, m], {ϕ, 0, 5}]

Infinityにおける級数展開：

Wolfram Language code: Series[EllipticPi[n, m], {m, ∞, 2}]//Normal//FullSimplify

スコープ  (36)

数値評価  (6)

不完全楕円積分を数値的に評価する：

Wolfram Language code: EllipticPi[1 / 3, Pi / 5, 0.3]

高精度で評価する：

Wolfram Language code: N[EllipticPi[3 / 10, 4 / 10], 50]
Wolfram Language code: N[EllipticPi[3 / 10, 2, 4 / 10], 50]

出力精度は入力精度に従う：

Wolfram Language code: EllipticPi[1 / 2, 2, 0.111111111111111111110000000000]

複素引数について評価する：

Wolfram Language code: EllipticPi[-2, 1 - 2.I]
Wolfram Language code: EllipticPi[-1, 2.5 + I, 1 / 3 - I]

EllipticPiを高精度で効率よく評価する：

Wolfram Language code: EllipticPi[1 / 2, 0.6`500]//Timing
Wolfram Language code: EllipticPi[1 / 2, 0.6`50000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: EllipticPi[1, 0.2, Interval[{0.3, 0.4}]]
Wolfram Language code: EllipticPi[1 / 2, CenteredInterval[-4, 1 / 10]]
Wolfram Language code: EllipticPi[1 / 2, 1 / 3, CenteredInterval[1 / 4, 1 / 5]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: EllipticPi[1 / 2, Around[1 / 3, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: EllipticPi[{{-1, 0}, {0, 1 / 2}}, 0]//FunctionExpand

MatrixFunctionを使って行列のEllipticPi関数を計算することもできる：

Wolfram Language code: MatrixFunction[EllipticPi[#, 0]&, {{-1, 0}, {0, 1 / 2}}]//FunctionExpand

特定の値  (3)

簡単な厳密値は自動的に生成される：

Wolfram Language code: {EllipticPi[0, m], EllipticPi[n, 0]}
Wolfram Language code: {EllipticPi[n, 0, m], EllipticPi[n, ϕ, 0]}

無限大における値：

Wolfram Language code: EllipticPi[Infinity, m]
Wolfram Language code: EllipticPi[n, Infinity]

方程式TemplateBox[{x, {6, /, {(, 10, )}}}, EllipticPi]=3の実根を求める：

Wolfram Language code: f[x_] := EllipticPi[x, 6 / 10] - 3; xzero = Solve[f[x] == 0 && 0 < x < 1.0, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[f[x], {x, 0, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化  (4)

EllipticPiを，第2パラメータ のさまざまな値についてプロットする：

Wolfram Language code: Plot[{EllipticPi[n, -2], EllipticPi[n, 1 / 7], EllipticPi[n, 6 / 7]}, {n, -1, 2}]

EllipticPiを，第1パラメータ のさまざまな値についてプロットする：

Wolfram Language code: Plot[{EllipticPi[-2, m], EllipticPi[1 / 6, m], EllipticPi[5 / 6, m]}, {m, -2, 1.5}, IconizedObject[«PlotOptions»]]

不完全楕円積 TemplateBox[{n, {pi, /, 3}, m}, EllipticPi3]を，パラメータ のさまざまな値についてプロットする：

Wolfram Language code: Plot[{EllipticPi[n, Pi / 3, -2], EllipticPi[n, Pi / 3, 1 / 7], EllipticPi[n, Pi / 3, 6 / 7]}, {n, -1, 1.5}, IconizedObject[«PlotOptions»]]

TemplateBox[{{-, 2}, z}, EllipticPi]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[EllipticPi[-2, z]], {z, -5 - 5I, 5 + 5I}, IconizedObject[«PlotOptions»]]

TemplateBox[{{-, 2}, z}, EllipticPi]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[EllipticPi[-2, z]], {z, -5 - 5I, 5 + 5I}, IconizedObject[«PlotOptions»]]

関数の特性  (9)

EllipticPiは解析関数ではない：

Wolfram Language code: FunctionAnalytic[EllipticPi[n, m], {n, m}]

特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[EllipticPi[n, m], {n, m}]
Wolfram Language code: FunctionDiscontinuities[EllipticPi[n, m], {n, m}]

EllipticPiは有理型関数ではない：

Wolfram Language code: FunctionMeromorphic[EllipticPi[n, m], {n, m}]

TemplateBox[{n, {1, /, 5}}, EllipticPi]の実領域：

Wolfram Language code: FunctionDomain[EllipticPi[n, 1 / 5], n]

TemplateBox[{n, {1, /, 5}}, EllipticPi]の実数範囲：

Wolfram Language code: FunctionRange[EllipticPi[n, 1 / 5], n, y]

数値近似に変換する：

Wolfram Language code: %//N

TemplateBox[{n, {1, /, 5}}, EllipticPi]は非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[{EllipticPi[n, 1 / 5], n != 0}, n]

TemplateBox[{n, {1, /, 5}}, EllipticPi]は単射である：

Wolfram Language code: FunctionInjective[EllipticPi[n, 1 / 5], n]
Wolfram Language code: Plot[{EllipticPi[n, 1 / 5], 5}, {n, -2, 2}]

TemplateBox[{n, {1, /, 5}}, EllipticPi]は全射ではない：

Wolfram Language code: FunctionSurjective[EllipticPi[n, .2], n]
Wolfram Language code: Plot[{EllipticPi[n, .2], -2}, {n, -2, 2}]

TemplateBox[{n, {1, /, 5}}, EllipticPi]は非負でも非正でもない：

Wolfram Language code: FunctionSign[{EllipticPi[n, 1 / 5], n != 1}, n]

TemplateBox[{n, {1, /, 5}}, EllipticPi]は凸でも凹でもない：

Wolfram Language code: FunctionConvexity[{EllipticPi[n, 2], n != 1}, n]

微分  (4)

第1パラメータについての一次導関数：

Wolfram Language code: D[EllipticPi[n, m], n]//Simplify

高次導関数：

Wolfram Language code: derivs = Table[D[EllipticPi[n, m], {n, k}], {k, 1, 3}]//Simplify

についての高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[derivs /. m -> -2], {n, -4, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

第2引数について微分する：

Wolfram Language code: D[EllipticPi[n, m], m]

高次導関数：

Wolfram Language code: derivs = Table[D[EllipticPi[n, m], {m, k}], {k, 1, 3}]//Simplify

についての高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[derivs /. n -> -2], {m, -4, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

積分  (3)

についての不定積分：

Wolfram Language code: Integrate[EllipticPi[n, m], m]//Simplify

定積分：

Wolfram Language code: Integrate[EllipticPi[n, m], {m, -1, 0}, Assumptions -> 0 < n < 1]

不完全楕円積分を含む積分：

Wolfram Language code: Integrate[Cos[ϕ] EllipticPi[n, ϕ, m], ϕ]

級数展開  (3)

の周りのEllipticPiのテイラー(Taylor)展開：

Wolfram Language code: Series[EllipticPi[n, m], {m, 0, 3}]//Simplify

の周りのTemplateBox[{{-, 2}, m}, EllipticPi]の最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[EllipticPi[-2, m], {m, 0, k}], {k, 1, 3}]; Plot[{EllipticPi[-2, m], terms}, {m, -2, 2}]

分岐点 の周りのEllipticPiの級数展開：

Wolfram Language code: Series[EllipticPi[n, m], {n, 1, 1}]//Simplify

の周りのTemplateBox[{n, {-, 2}}, EllipticPi]の最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[EllipticPi[n, -2], {n, 1, k}], {k, 1, 3}]; Plot[{EllipticPi[n, -2], terms}, {n, -1.3, 1}]

EllipticPiはベキ級数に適用できる：

Wolfram Language code: EllipticPi[n, Exp[ϕ] - 1 + O[ϕ] ^ 5, m]

関数表現  (4)

積分表現：

Wolfram Language code: Integrate[1 / ((1 - n Sin[t] ^ 2) Sqrt[1 - m Sin[t] ^ 2]), {t, 0, ϕ}, Assumptions -> 0 < n < 1 && 0 < m < 1 && ϕ > 0]

第3種完全楕円積分は不完全楕円積分の部分的なケースである：

Wolfram Language code: EllipticPi[n, (π/2), m]

EllipticPiはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[EllipticPi[n, m], m]

TraditionalFormによる表示：

Wolfram Language code: EllipticPi[n, m]//TraditionalForm
Wolfram Language code: EllipticPi[n, ϕ, m]//TraditionalForm

アプリケーション  (6)

楕円積分を評価する：

Wolfram Language code: Integrate[(1/xSqrt[x ^ 3 + 2 x - 3]), x]

点から , 平面上の原点の円板（例えば探知機や道路標識等）によって範囲を定められた立体角の定義：

Wolfram Language code: ΩInt[R_, ρ_, h_] := With[{ray = {ρ, 0, h} - {r Cos[φ], r Sin[φ], 0}}, NIntegrate[Evaluate[(((ray/Norm[ray])).{0, 0, 1}/ray.ray)r ], {r, 0, R}, {φ, 0, 2Pi}]]

立体角の閉形による結果：

Wolfram Language code: Ω[R_, ρ_, h_] = Piecewise[{{2 π (1 - (h/Sqrt[h^2 + R^2])), ρ == 0}, {2 Sqrt[(h^2/h^2 + (R + ρ)^2)] (-EllipticK[(4 R ρ/h^2 + (R + ρ)^2)] + Sqrt[1 - (4 R ρ/(R + ρ)^2)] EllipticPi[(4 R ρ/(R + ρ)^2), (4 R ρ/h^2 + (R + ρ)^2)]), R < ρ}, {π - 2 Sqrt[(h^2/h^2 + 4 R^2)] EllipticK[(4 R^2/h^2 + 4 R^2)], R == ρ}, {2 π (1 - (1/π)Sqrt[(h^2/h^2 + (R + ρ)^2)] (EllipticK[(4 R ρ/h^2 + (R + ρ)^2)] + Sqrt[1 - (4 R ρ/(R + ρ)^2)] EllipticPi[(4 R ρ/(R + ρ)^2), (4 R ρ/h^2 + (R + ρ)^2)])), R > ρ}}];

数値による比較：

Wolfram Language code: With[{R = 1}, Module[{ρ = 2.3, h = 3.4}, {ΩInt[R, ρ, h], Ω[R, ρ, h]}]]

立体角を水平距離と高さの関数としてプロットする：

Wolfram Language code: Plot3D[Ω[1, ρ, h], {ρ, 0, 3}, {h, 0, 3}]

次は，相対論的な3D振動子の古典的な動作を計算する：

Wolfram Language code: HamiltonS = -ℰ t + ℒ φ + ∫Sqrt[(1/c^2)(ℰ - (1/2) m ω ρ^2)^2 - (ℒ^2/ρ^2) - m^2 c^2]ⅆρ;

この動作は EllipticPiを使って表すことができる（簡潔を期するため，出現する根は省略されている）：

Wolfram Language code: HamiltonS /. MapIndexed[#1 -> Subscript[ℛ, #2[[1]]]&, Union[Cases[HamiltonS, _Root, ∞]]] // Simplify

等角図：

Wolfram Language code: f[w_] = Integrate[Sqrt[(Cos[w] + 1 / 2/Cos[w] - 1 / 3)], w]//PowerExpand

一定の実部と虚部の線の画像を可視化する：

Wolfram Language code: ParametricPlot[{Re[f[u + I v]], Im[f[u + I v]]}, {u, -Pi / 2, Pi / 2}, {v, 1 / 100, 2}, Mesh -> 15]

種数1の定数平均曲率ウェンテ（Wente）トーラスのパラメーター化：

Wolfram Language code: WenteEmbedding[params : {H_, 𝓂_, m_, γ_, ℽ_, Γ_, α_, 𝒶_, b_, p_}, {u_, v_}] := Module[{𝓏, ω, 𝒿}, 𝓏 = Sqrt[(2/H)](1/𝒶^2)((((𝒶^2 - b)(γ Cos[u])^2 + p)ℽ JacobiCN[v, 𝓂] - (p(γ Cos[u])^2 + 𝒶^2 + b)γ Cos[u]) / ((1 - Γ Cos[u]JacobiCN[v, 𝓂])Sqrt[p - 2b(γ Cos[u])^2 - p(γ Cos[u])^4])); ω = (2 Sqrt[H]/α)((2/1 - Γ^2)EllipticPi[(Γ^2/Γ^2 - 1), u, m] - EllipticF[u, m]); 𝒿 = u - ArcTan[((2 Sqrt[H] - α Sqrt[1 - m Sin[u]^2]) Sin[2 u]/2 (2 Sqrt[H] Cos[u]^2 + α Sin[u]^2 Sqrt[1 - m Sin[u]^2]))]; {𝓏 Cos[ω - 𝒿] + (Cos[ω]/2 H), 𝓏 Sin[ω - 𝒿] + (Sin[ω]/2 H), ((1/𝒶 Sqrt[H])) ((2Γ Cos[u] JacobiSN[v, 𝓂] JacobiDN[v, 𝓂]/1 - Γ Cos[u] JacobiCN[v, 𝓂]) + (2/ℽ)JacobiZN[v, 𝓂])}]
Wolfram Language code: WenteSineSquaredValues[r_Rational /; 1 < r < 2, m_Real /; 0 < m < 1] := N[ /. FindRoot[With[{g = Sqrt[(/1 - )]Sqrt[(m/1 - m)]}, (2/1 - g)EllipticPi[(g/g - 1), ] - EllipticK[]] == r (Pi/2)(1/Sqrt[1 - 2 - (2m - 1)Sqrt[(1 - ) / (m(1 - m))]]), {, 1 / 10, 0, 4 / 23}, WorkingPrecision -> Precision[m] - 2], Precision[m] - 5]
Wolfram Language code: WenteTorusFunction[lobes_Integer /; lobes ≥ 2, u_, v_] := Module[{𝓂, m, g = lobes, H = 1 / 2, b, f, p, α, 𝒶, γ, ℽ, Γ}, (* elliptic parameter related to Halphen's constant *) 𝓂 =  /. FindRoot[EllipticK[] == 2EllipticE[], {, 4 / 5}, WorkingPrecision -> 50]; m = WenteSineSquaredValues[1 + 1 / g, 𝓂]; γ = (m/1 - m)^(1/(4));ℽ = (𝓂/1 - 𝓂)^(1/(4));Γ = γ ℽ; f = H / ((1 - 2m)Sqrt[𝓂(1 - 𝓂)] + (1 - 2𝓂)Sqrt[m(1 - m)]); α = 2Sqrt[fSqrt[𝓂(1 - 𝓂)]];𝒶 = 2Sqrt[fSqrt[m(1 - m)]]; b = 4f Sqrt[m(1 - m)] (2 𝓂 - 1);p = 8f Sqrt[m(1 - m)] Sqrt[𝓂(1 - 𝓂)]; Sequence @@ {WenteEmbedding[{H, 𝓂, m, γ, ℽ, Γ, α, 𝒶, b, p}, {u, v}], {u, -π / 2, (2 g - 1)π / 2}, {v, 0, 4EllipticK[𝓂]}} ]

3葉，5葉，7葉，11葉のトーラスを可視化する：

Wolfram Language code: Table[ParametricPlot3D@@{WenteTorusFunction[l, u, v], Lighting -> "Neutral", Mesh -> False, PlotPoints -> 55, PlotStyle -> Opacity[1 / 2, Gray], Ticks -> None}, {l, {3, 5, 7, 11}}]//Multicolumn

EllipticPiについてのパラメータのさまざまな変化を数値的に確認する：

Wolfram Language code: EllipticPi[n, ϕ, m] + EllipticPi[m / n, ϕ, m] == EllipticF[ϕ, m] + Csc[ϕ]CarlsonRC[(Csc[ϕ]^2 - 1)(Csc[ϕ]^2 - m), (Csc[ϕ]^2 - n)(Csc[ϕ]^2 - m / n)] /. {{n -> 1 / 3, ϕ -> Pi / 3, m -> 1 / 4.}, {n -> 2, ϕ -> Pi / 3, m -> 1 / 4.}, {n -> -1, ϕ -> Pi / 3, m -> 1 / 4.}}
Wolfram Language code: (m - n)EllipticPi[n, ϕ, m] + (m - (m - n/1 - n))EllipticPi[(m - n/1 - n), ϕ, m] == m EllipticF[ϕ, m] - n (m - n/1 - n)Cot[ϕ]CarlsonRC[Csc[ϕ]^2(Csc[ϕ]^2 - m), (Csc[ϕ]^2 - n)(Csc[ϕ]^2 - (m - n/1 - n))] /. {{n -> 1 / 3, ϕ -> Pi / 3, m -> 1 / 4.}, {n -> 2, ϕ -> Pi / 3, m -> 1 / 4.}, {n -> -1, ϕ -> Pi / 3, m -> 1 / 4.}}
Wolfram Language code: (1 - n)EllipticPi[n, ϕ, m] + (1 - (m (1 - n)/m - n))EllipticPi[(m (1 - n)/m - n), ϕ, m] == EllipticF[ϕ, m] + (1 - n - (m (1 - n)/m - n))Sqrt[Csc[ϕ]^2 - m]CarlsonRC[Cot[ϕ]^2 Csc[ϕ]^2, (Csc[ϕ]^2 - n)(Csc[ϕ]^2 - (m (1 - n)/m - n))] /. {{n -> 1 / 3, ϕ -> Pi / 3, m -> 1 / 4.}, {n -> 2, ϕ -> Pi / 3, m -> 1 / 4.}, {n -> -1, ϕ -> Pi / 3, m -> 1 / 4.}}

特性と関係  (4)

EllipticPi[n,m]は，と のときは実数値である：

Wolfram Language code: FunctionDomain[EllipticPi[n, m], {n, m}, Reals]

仮定を使って特殊形を展開する：

Wolfram Language code: EllipticPi[n, z, 1]//FunctionExpand
Wolfram Language code: FunctionExpand[%, 0 < z < Pi / 2]

次は，EllipticPi関数の分枝切断線を示している：

Wolfram Language code: Plot3D[Im[EllipticPi[1 / 2, x + I y]], {x, -2, 2}, {y, -2, 2}, Exclusions -> {y == 0}]
Wolfram Language code: Plot3D[Re[EllipticPi[0.2, x + I y, 1 / 4]], {x, -Pi, Pi}, {y, -2, 2}, ViewPoint -> {-2.5, -1.4, 1.8}, BoxRatios -> Automatic, Mesh -> None, Boxed -> False]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[EllipticPi[z, 2]^3 + EllipticPi[z, 2] + z == 2, {z, I}]

考えられる問題  (3)

分枝切断線における極限は間違っていることがある：

Wolfram Language code: Limit[EllipticPi[2, (π/2) + ε I], ε -> 0, Direction -> -1]
Wolfram Language code: Limit[EllipticPi[2, (π/2) + ε I], ε -> 0, Direction -> +1]
Wolfram Language code: EllipticPi[2, Pi / 2 + 10^-6{-1, 1}I]//N

定義積分は追加的な条件のもとでしか収束しない：

Wolfram Language code: Subsuperscript[∫, 0, (π/2)](1/(1 - n Sin[t]^2) Sqrt[1 - m Sin[t]^2])ⅆt

結果が変わるような異なる引数の慣習が存在する：

Wolfram Language code: Integrate[(1/(1 - n Sin[t]^2) Sqrt[1 - k^2 Sin[t]^2]), {t, 0, z}, GenerateConditions -> False]
Wolfram Language code: Integrate[(1/(1 - n t^2) Sqrt[(1 - m t^2) (1 - t^2)]), {t, 0, z}, GenerateConditions -> False]//Simplify[#, 0 < m < 1 && 0 < z < 1]&
Wolfram Research (1988), EllipticPi, Wolfram言語関数， https://reference.wolfram.com/language/ref/EllipticPi.html （2022年に更新）.

テキスト

Wolfram Research (1988), EllipticPi, Wolfram言語関数， https://reference.wolfram.com/language/ref/EllipticPi.html （2022年に更新）.

CMS

Wolfram Language. 1988. "EllipticPi." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/EllipticPi.html.

APA

Wolfram Language. (1988). EllipticPi. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EllipticPi.html

BibTeX

@misc{reference.wolfram_2026_ellipticpi, author="Wolfram Research", title="{EllipticPi}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticPi.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipticpi, organization={Wolfram Research}, title={EllipticPi}, year={2022}, url={https://reference.wolfram.com/language/ref/EllipticPi.html}, note=[Accessed: 16-September-2026]}