EllipticTheta

EllipticTheta[a,u,q]

シータ(Theta)関数を与える．

EllipticTheta[a,q]

シータ定数を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
$TemplateBox[{1, u, q}, EllipticTheta]=2q^(1/4)sum_(n=0)^(infty)(-1)^nq^(n(n+1))sin((2 n+1)u)$
$TemplateBox[{2, u, q}, EllipticTheta]=2q^(1/4)sum_(n=0)^(infty)q^(n(n+1))cos((2 n+1)u)$
$TemplateBox[{3, u, q}, EllipticTheta]=1+2sum_(n=1)^(infty)q^(n^2)cos(2n u)$
$TemplateBox[{4, u, q}, EllipticTheta]=1+2sum_(n=1)^(infty)(-1)^nq^(n^2)cos(2n u)$
は単位 q の円板，，の中でしか定義されない．単位円板は解析性における自然の境界になる．
単位 q の円板内では，とはからで分枝切断線を持つ．
特別な引数の場合，EllipticThetaは，自動的に厳密値を計算する．
EllipticThetaは任意の数値精度で評価できる．
EllipticThetaは自動的にリストに縫い込まれる．
EllipticThetaはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (3)

数値的に評価する：

Wolfram Language code: EllipticTheta[1, 2., 1 / 3]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[EllipticTheta[2, x, 1 / 3], {x, -6, 6}]

原点における q についての級数展開：

Wolfram Language code: Series[EllipticTheta[4, 0, q], {q, 0, 100}]

スコープ (20)

数値評価 (5)

数値的に評価する：

Wolfram Language code: EllipticTheta[2, 5, .5]

Wolfram Language code: EllipticTheta[3, .4, .5]

高精度で評価する：

Wolfram Language code: N[EllipticTheta[3, 1 / 4, 1 / 3], 25]

出力精度は入力精度に従う：

Wolfram Language code: EllipticTheta[3, 4, .50005555555500055005]

複素数入力：

Wolfram Language code: EllipticTheta[3, .4 + I, .5I]

高精度で効率的に評価する：

Wolfram Language code: EllipticTheta[2, 5, .5`100]//Timing

Wolfram Language code: EllipticTheta[2, 5, .5`10000];//Timing

EllipticThetaはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる：

Wolfram Language code: EllipticTheta[2, 1, Interval[{0.47, 0.48}]]

Wolfram Language code: EllipticTheta[2, 1, CenteredInterval[1 / 4, 1 / 100]]

特定の値 (3)

ゼロにおける値：

Wolfram Language code: EllipticTheta[1, 0, 0]

EllipticThetaは，特定の引数については記号的に評価される：

Wolfram Language code: Table[EllipticTheta[j, z, 0], {j, 4}]

Wolfram Language code: EllipticTheta[1, Pi, 1 / 2]

EllipticTheta[3,x,1/2]の最初の正の最小値を求める：

Wolfram Language code: xmin = x /. FindRoot[D[EllipticTheta[3, x, 1 / 2]] == 0, {x, 2}]//Quiet

Wolfram Language code:

Plot[EllipticTheta[3, x, 1 / 2], {x, -1, 4}, Epilog -> Style[Point[{xmin, EllipticTheta[3, xmin, 1 / 2]}], PointSize[Large], Red]]

可視化 (2)

EllipticTheta関数をさまざまなパラメータについてプロットする：

Wolfram Language code:

Plot[{EllipticTheta[1, x, 1 / 2], EllipticTheta[2, x, 1 / 2], EllipticTheta[3, x, 1 / 2], EllipticTheta[4, x, 1 / 2]}, {x, -6, 6}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[EllipticTheta[4, z, 1 / 3]], {z, -4 - 4I, 4 + 4 I}, Contours -> 24]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[EllipticTheta[4, z, 1 / 3]], {z, -4 - 4I, 4 + 4 I}, Contours -> 24]

関数の特性 (10)

EllipticThetaの実領域と複素領域：

Wolfram Language code: Table[FunctionDomain[EllipticTheta[a, x, q], {x, q}], {a, 4}]

Wolfram Language code: Table[FunctionDomain[EllipticTheta[a, z, q], {z, q}, Complexes], {a, 4}]

EllipticThetaはについて周期関数である：

Wolfram Language code: Table[FunctionPeriod[EllipticTheta[a, z, q], z], {a, 4}]

EllipticThetaは要素単位でリストに縫い込まれる：

Wolfram Language code: EllipticTheta[{1, 2, 3, 4}, z, q]

Wolfram Language code: EllipticTheta[2, {Pi / 2, Pi}, 1 / 2]

は x の解析関数である：

Wolfram Language code: FunctionAnalytic[EllipticTheta[1, x, q], x, Assumptions -> 0 < q < 1]

例えば，は特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[EllipticTheta[1, x, 1 / 2], x]//Quiet

Wolfram Language code: FunctionDiscontinuities[EllipticTheta[1, x, 1 / 2], x]//Quiet

は非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[EllipticTheta[1, x, 1 / 2], x]

は単射ではない：

Wolfram Language code: FunctionInjective[EllipticTheta[1, x, 1 / 2], x]

Wolfram Language code: Plot[{EllipticTheta[1, x, 1 / 2], 1}, {x, -6, 6}]

は全射ではない：

Wolfram Language code: FunctionSurjective[EllipticTheta[1, x, 1 / 2], x]

Wolfram Language code: Plot[{EllipticTheta[1, x, 1 / 2], -5}, {x, -6, 6}]

は非負でも非正でもない：

Wolfram Language code: FunctionSign[EllipticTheta[1, x, 1 / 2], x]

は凸でも凹でもない：

Wolfram Language code: FunctionConvexity[EllipticTheta[1, x, 1 / 2], x]

TraditionalFormによる表示：

Wolfram Language code: EllipticTheta[a, z, q] // TraditionalForm

Wolfram Language code: EllipticTheta[a, q] // TraditionalForm

一般化と拡張 (1)

EllipticThetaはベキ級数に適用できる：

Wolfram Language code: EllipticTheta[2, z, q - (q^2/2) + (q^3/9) + O[q]^4]

アプリケーション (11)

複素 q 平面上の単位円近くでシータ関数をプロットする：

Wolfram Language code: Plot[Re[EllipticTheta[1, 0.5, 0.9 Exp[I ϕ]]], {ϕ, -π, π}]

Wolfram Language code: Plot[Re[EllipticTheta[1, 0.5, 0.97 Exp[I ϕ]]], {ϕ, -π, π}]

4つの正方形の総和としてのの表示回数：

Wolfram Language code:

Table[
	SeriesCoefficient[Series[EllipticTheta[3, 0, q] ^ 4, {q, 0, n}], n], {n, 10}]

Wolfram Language code: Table[SquaresR[4, n], {n, 10}]

級数展開を介したヤコビの三重積の恒等式を検証する：

Wolfram Language code: Series[EllipticThetaPrime[1, q] - EllipticTheta[2, q]EllipticTheta[3, q]EllipticTheta[4, q], {q, 0, 9}]

楕円から単位円板への等角写像：

Wolfram Language code:

w[z_, {a_, b_}] := With[{q = ((a - b/a + b))^2, aze = ArcSin[(z/Sqrt[a^2 - b^2])]}, (EllipticTheta[1, aze, q]/EllipticTheta[4, aze, q])]

写像を可視化する：

Wolfram Language code: ParametricPlot[ReIm[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]], {ρ, 0, 1}, {φ, 0, 2π}, Mesh -> 15]

ディリクレ(Dirichlet)境界条件と初期条件を持つ一次元の熱伝導方程式のためのグリーン(Green)の関数：

Wolfram Language code:

T[{x_, t_}, x0_, L_] := (1/2L) (EllipticTheta[3, (π/2L) (x - x0), E^-((π/L))^2t] - EllipticTheta[3, (π/2L)(x + x0), E^-((π/L))^2t])

時間に依存する温度分布をプロットする：

Wolfram Language code: Plot3D[T[{x, t}, 0.6, 1], {x, 0, 1}, {t, 0.01, 1 / 2}]

ガウス(Gauss)の軌道で一次元結晶のブロッホ(Bloch)関数を形成する：

Wolfram Language code:

ψ[𝓀_, x_, ϕ_] := (E^-(π ϕ x^2/2) EllipticTheta[3, π 𝓀 - (π I ϕ x/2), E^-π / 2 ϕ]/Sqrt[(2/ϕ) E^-(4 𝓀^2 π/ϕ)EllipticTheta[3, -(4 I 𝓀 π/ϕ), E^-(4 π/ϕ)]])

ブロッホ関数を擬似波動ベクトルの関数としてプロットする：

Wolfram Language code: Plot3D[Re[ψ[𝓀, x, 1]], {x, -12, 12}, {𝓀, 0, 1 / 2}]

点状のイオンを持つNaCl様の結晶内の静電気力：

Wolfram Language code: q[x_, t_] := EllipticTheta[2, 2 π x, E^-t^2]

Wolfram Language code: φ[{x_, y_, z_}] := (16/π) NIntegrate[t q[x, t]q[y, t]q[z, t], {t, 0, ∞}]

結晶を通る平面上の力の強さをプロットする：

Wolfram Language code: ListContourPlot[Table[φ[{x, y, 0.3}], {x, -1, 1, 1 / 25}, {y, -1, 1, 1 / 25}]]

ポアソン(Poisson)の総和公式の簡潔な形：

Wolfram Language code: x^1 / 4 EllipticTheta[3, 0, E^π x] == (2UnitStep[Im[x]] - 1) I x^-1 / 4 EllipticTheta[3, 0, E^π / x]

Wolfram Language code: % /. x -> -2.

有限ガウス和についての漸近近似：

Wolfram Language code: AsymptoticSum[E^-k^2, {k, 1, n}, {n, ∞, 2}]//FullSimplify

について，近似値と厳密値を比較する：

Wolfram Language code: % /. {n -> 10.}

Wolfram Language code: Underoverscript[∑, k = 1, 10]E^-k^2//N

算術幾何平均の反復の閉じた形：

Wolfram Language code:

ArithmeticGeometricMeanIteration[n_, a_, b_] := With[{z = EllipticNomeQ[1 - ((b/a))^2]}, ArithmeticGeometricMean[a, b]{EllipticTheta[3, 0, z^2^n]^2, EllipticTheta[4, 0, z^2^n]^2}]

明示的な反復からの閉じた形と比較する：

Wolfram Language code: Table[ArithmeticGeometricMeanIteration[n, 3., 5.], {n, 0, 4}]

Wolfram Language code: NestList[{Mean[#], GeometricMean[#]}&, {3., 5.}, 4]

指定の周期，極，零点を持った任意の楕円関数をEllipticThetaの有理関数として形成する：

Wolfram Language code:

makeEllipticFunction[z_, {ω1_, ω3_}, zeros_List, poles_List] := Module[{c = π / (2 ω1), q = Exp[I π ω3 / ω1]}, 
	(Product[EllipticTheta[1, c (z - r), q], {r, zeros}] / Product[EllipticTheta[1, c (z - s), q], {s, poles}]) (EllipticTheta[1, c (z - Last[poles]), q] / EllipticTheta[1, c (z - Last[poles] - (Total[zeros] - Total[poles])), q])] /; Length[zeros] == Length[poles] && Resolve[Exists[{μ, ν}, Element[{μ, ν}, Integers], Total[zeros] - Total[poles] == μ ω1 + ν ω3]]

単一および二重の零点と三重極を持つ任意の楕円関数を形成する：

Wolfram Language code: f[z_] = makeEllipticFunction[z, {1, I}, {1 / 3 + 1 / 3 I, 1 / 3 + 1 / 3 I, -2 / 3 - 2 / 3 I}, {0, 0, 0}]

結果の楕円関数をプロットする：

Wolfram Language code: ComplexPlot[f[z], {z, -1.5 - 1.5I, 1.5 + 1.5I}, ColorFunction -> "CyclicReImLogAbs"]

特性と関係 (2)

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[EllipticTheta[1, z, 1 / 3]^3 + EllipticTheta[3, z, 1 / 3] + z == 2, {z, 2}]

Sumは楕円シータ関数が生成できる：

Wolfram Language code: Sum[(-1) ^ n q ^ (n ^ 2), {n, Infinity}]

考えられる問題 (4)

機械精度の入力では正しい答を得るのには不十分である：

Wolfram Language code: EllipticTheta[1, 10. ^ 30, 1 / 2]

任意精度で計算して正しい答を得る：

Wolfram Language code: N[EllipticTheta[1, 10 ^ 30, 1 / 2], 20]

第1引数は1から4までの明示的な整数でなければならない：

Wolfram Language code: EllipticTheta[1 + (E + 1) ^ 2 - E ^ 2 - 2E - 1, 3., 1 / 2]

Wolfram Language code: Simplify[%]

EllipticThetaは属性NHoldFirstを持つ：

Wolfram Language code: Attributes[EllipticTheta]

シータ関数について，さまざまな引数の慣習がある：

Wolfram Language code:

{Plot[EllipticTheta[1, z, (1/2)], {z, 0, 2π}], 
	Plot[EllipticTheta[1, (z/2π), (1/2)], {z, 0, 2π}]}

Wolfram Language code:

{Plot[EllipticTheta[1, 2, q], {q, 0.1, 0.8}], 
	Plot[EllipticTheta[1, 2, Exp[I π (I τ)]], {τ, 0.1, 0.8}]}

おもしろい例題 (1)

分析性の境界で関数を可視化する：

Wolfram Language code:

Module[{f, r = 0.995}, 
	f[z_ ? NumberQ] := If[Abs[z] > r, 0, Sin[Arg[EllipticTheta[3, 1, z]] / 2] ^ 2];
	DensityPlot[f[qx + I qy], {qx, qy}∈Disk[{0, 0}, r], PlotPoints -> 90, PlotRange -> All, Frame -> False, ColorFunction -> (Hue[2.72 #]&)]]

Wolfram Language code:

ParametricPlot3D[{qr Cos[qϕ], qr Sin[qϕ], Abs[EllipticTheta[2, 2, qr E^I qϕ]]}, {qϕ, -π, π}, {qr, 0, 0.99}, BoxRatios -> {1, 1, 0.66}]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

EllipticTheta

詳細

例題

例 (3)

スコープ (20)

数値評価 (5)

特定の値 (3)

可視化 (2)

関数の特性 (10)

一般化と拡張 (1)

アプリケーション (11)

特性と関係 (2)

考えられる問題 (4)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

EllipticTheta

詳細

例題

例 (3)

スコープ (20)

数値評価 (5)

特定の値 (3)

可視化 (2)

関数の特性 (10)

一般化と拡張 (1)

アプリケーション (11)

特性と関係 (2)

考えられる問題 (4)

おもしろい例題 (1)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX