WOLFRAM

Wolfram 语言与系统参考资料中心

EllipticTheta[a,u,q]

给出 theta 函数 TemplateBox[{a, u, q}, EllipticTheta] .

EllipticTheta[a,q]

给出 theta 常数 TemplateBox[{a, q}, EllipticThetaConstant]=TemplateBox[{a, 0, q}, EllipticTheta].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
函数的属性  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

EllipticTheta

EllipticTheta[a,u,q]

给出 theta 函数 TemplateBox[{a, u, q}, EllipticTheta] .

EllipticTheta[a,q]

给出 theta 常数 TemplateBox[{a, q}, EllipticThetaConstant]=TemplateBox[{a, 0, q}, EllipticTheta].

更多信息

  • 数学函数，适宜于符号和数值运算.
  • TemplateBox[{1, u, q}, EllipticTheta]=2q^(1/4)sum_(n=0)^(infty)(-1)^nq^(n(n+1))sin((2 n+1)u).
  • TemplateBox[{2, u, q}, EllipticTheta]=2q^(1/4)sum_(n=0)^(infty)q^(n(n+1))cos((2 n+1)u).
  • TemplateBox[{3, u, q}, EllipticTheta]=1+2sum_(n=1)^(infty)q^(n^2)cos(2n u).
  • TemplateBox[{4, u, q}, EllipticTheta]=1+2sum_(n=1)^(infty)(-1)^nq^(n^2)cos(2n u).
  • 仅在单位 q 圆盘内定义，其中 TemplateBox[{q}, Abs]<1；单位圆盘形成一个自然分析性边界.
  • 在单位 q 圆盘内，, 和 有从 到 的分支切割.
  • 对于某些特定参数，EllipticTheta 自动运算出精确值.
  • EllipticTheta 可求任意数值精度的值.
  • EllipticTheta 自动逐项作用于列表的各个元素.
  • EllipticTheta 可与 Interval 和 CenteredInterval 对象一起使用. »

范例

打开所有单元 关闭所有单元

基本范例  (3)

数值计算：

Wolfram Language code: EllipticTheta[1, 2., 1 / 3]

在实数的子集上绘图：

Wolfram Language code: Plot[EllipticTheta[2, x, 1 / 3], {x, -6, 6}]

在原点处关于 q 的级数展开式：

Wolfram Language code: Series[EllipticTheta[4, 0, q], {q, 0, 100}]

范围  (20)

数值计算  (5)

数值计算：

Wolfram Language code: EllipticTheta[2, 5, .5]
Wolfram Language code: EllipticTheta[3, .4, .5]

高精度计算：

Wolfram Language code: N[EllipticTheta[3, 1 / 4, 1 / 3], 25]

输出的精度与输入的精度一致：

Wolfram Language code: EllipticTheta[3, 4, .50005555555500055005]

复数输入：

Wolfram Language code: EllipticTheta[3, .4 + I, .5I]

在高精度条件下进行高效计算：

Wolfram Language code: EllipticTheta[2, 5, .5`100]//Timing
Wolfram Language code: EllipticTheta[2, 5, .5`10000];//Timing

EllipticTheta 可与 Interval 和 CenteredInterval 对象一起使用：

Wolfram Language code: EllipticTheta[2, 1, Interval[{0.47, 0.48}]]
Wolfram Language code: EllipticTheta[2, 1, CenteredInterval[1 / 4, 1 / 100]]

特殊值  (3)

零处的值：

Wolfram Language code: EllipticTheta[1, 0, 0]

EllipticTheta 符号式计算特殊参数：

Wolfram Language code: Table[EllipticTheta[j, z, 0], {j, 4}]
Wolfram Language code: EllipticTheta[1, Pi, 1 / 2]

求 EllipticTheta[3,x,1/2] 的第一个正极小值：

Wolfram Language code: xmin = x /. FindRoot[D[EllipticTheta[3, x, 1 / 2]] == 0, {x, 2}]//Quiet
Wolfram Language code: Plot[EllipticTheta[3, x, 1 / 2], {x, -1, 4}, Epilog -> Style[Point[{xmin, EllipticTheta[3, xmin, 1 / 2]}], PointSize[Large], Red]]

可视化  (2)

绘制各种参数值的 EllipticTheta 函数：

Wolfram Language code: Plot[{EllipticTheta[1, x, 1 / 2], EllipticTheta[2, x, 1 / 2], EllipticTheta[3, x, 1 / 2], EllipticTheta[4, x, 1 / 2]}, {x, -6, 6}]

绘制 TemplateBox[{4, z, {1, /, 3}}, EllipticTheta] 的实部：

Wolfram Language code: ComplexContourPlot[Re[EllipticTheta[4, z, 1 / 3]], {z, -4 - 4I, 4 + 4 I}, Contours -> 24]

绘制 TemplateBox[{4, z, {1, /, 3}}, EllipticTheta] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[EllipticTheta[4, z, 1 / 3]], {z, -4 - 4I, 4 + 4 I}, Contours -> 24]

函数的属性  (10)

EllipticTheta 的实数和复数定义域：

Wolfram Language code: Table[FunctionDomain[EllipticTheta[a, x, q], {x, q}], {a, 4}]
Wolfram Language code: Table[FunctionDomain[EllipticTheta[a, z, q], {z, q}, Complexes], {a, 4}]

EllipticTheta 是关于 的周期函数：

Wolfram Language code: Table[FunctionPeriod[EllipticTheta[a, z, q], z], {a, 4}]

EllipticTheta 逐项作用于列表的各个元素：

Wolfram Language code: EllipticTheta[{1, 2, 3, 4}, z, q]
Wolfram Language code: EllipticTheta[2, {Pi / 2, Pi}, 1 / 2]

TemplateBox[{1, x, q}, EllipticTheta] 是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[EllipticTheta[1, x, q], x, Assumptions -> 0 < q < 1]

例如，TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] 没有奇点或断点：

Wolfram Language code: FunctionSingularities[EllipticTheta[1, x, 1 / 2], x]//Quiet
Wolfram Language code: FunctionSingularities[EllipticTheta[1, x, 1 / 2], x]//Quiet
Wolfram Language code: FunctionDiscontinuities[EllipticTheta[1, x, 1 / 2], x]//Quiet

TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[EllipticTheta[1, x, 1 / 2], x]

TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] 不是单射函数：

Wolfram Language code: FunctionInjective[EllipticTheta[1, x, 1 / 2], x]
Wolfram Language code: Plot[{EllipticTheta[1, x, 1 / 2], 1}, {x, -6, 6}]

TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] 不是满射函数：

Wolfram Language code: FunctionSurjective[EllipticTheta[1, x, 1 / 2], x]
Wolfram Language code: Plot[{EllipticTheta[1, x, 1 / 2], -5}, {x, -6, 6}]

TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[EllipticTheta[1, x, 1 / 2], x]

TemplateBox[{1, x, {1, /, 2}}, EllipticTheta] 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[EllipticTheta[1, x, 1 / 2], x]

TraditionalForm 格式：

Wolfram Language code: EllipticTheta[a, z, q] // TraditionalForm
Wolfram Language code: EllipticTheta[a, q] // TraditionalForm

推广和延伸  (1)

EllipticTheta 可用于幂级数：

Wolfram Language code: EllipticTheta[2, z, q - (q^2/2) + (q^3/9) + O[q]^4]

应用  (11)

在复数 q 平面内单位圆附近绘制 theta 函数：

Wolfram Language code: Plot[Re[EllipticTheta[1, 0.5, 0.9 Exp[I ϕ]]], {ϕ, -π, π}]
Wolfram Language code: Plot[Re[EllipticTheta[1, 0.5, 0.97 Exp[I ϕ]]], {ϕ, -π, π}]

作为四次方的和表示的数：

Wolfram Language code: Table[ SeriesCoefficient[Series[EllipticTheta[3, 0, q] ^ 4, {q, 0, n}], n], {n, 10}]
Wolfram Language code: Table[SquaresR[4, n], {n, 10}]

通过数列展开验证 Jacobi 三重乘积恒等式（Jacobi's triple product identity）：

Wolfram Language code: Series[EllipticThetaPrime[1, q] - EllipticTheta[2, q]EllipticTheta[3, q]EllipticTheta[4, q], {q, 0, 9}]

从椭圆到单位圆盘的保角变换图：

Wolfram Language code: w[z_, {a_, b_}] := With[{q = ((a - b/a + b))^2, aze = ArcSin[(z/Sqrt[a^2 - b^2])]}, (EllipticTheta[1, aze, q]/EllipticTheta[4, aze, q])]

可视化图形：

Wolfram Language code: ParametricPlot[ReIm[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]], {ρ, 0, 1}, {φ, 0, 2π}, Mesh -> 15]

具有 Dirichlet 边界条件和初始条件 的一维热方程的格林函数（Green function）：

Wolfram Language code: T[{x_, t_}, x0_, L_] := (1/2L) (EllipticTheta[3, (π/2L) (x - x0), E^-((π/L))^2t] - EllipticTheta[3, (π/2L)(x + x0), E^-((π/L))^2t])

绘制时间相关的温度分布：

Wolfram Language code: Plot3D[T[{x, t}, 0.6, 1], {x, 0, 1}, {t, 0.01, 1 / 2}]

高斯轨道的一维晶体的 Bloch 函数：

Wolfram Language code: ψ[𝓀_, x_, ϕ_] := (E^-(π ϕ x^2/2) EllipticTheta[3, π 𝓀 - (π I ϕ x/2), E^-π / 2 ϕ]/Sqrt[(2/ϕ) E^-(4 𝓀^2 π/ϕ)EllipticTheta[3, -(4 I 𝓀 π/ϕ), E^-(4 π/ϕ)]])

绘制类波向量函数的 Bloch 函数：

Wolfram Language code: Plot3D[Re[ψ[𝓀, x, 1]], {x, -12, 12}, {𝓀, 0, 1 / 2}]

氯化钠晶体离子点间的静电势：

Wolfram Language code: q[x_, t_] := EllipticTheta[2, 2 π x, E^-t^2]
Wolfram Language code: φ[{x_, y_, z_}] := (16/π) NIntegrate[t q[x, t]q[y, t]q[z, t], {t, 0, ∞}]

绘制平面中穿过晶体的电势：

Wolfram Language code: ListContourPlot[Table[φ[{x, y, 0.3}], {x, -1, 1, 1 / 25}, {y, -1, 1, 1 / 25}]]

泊松求和公式的简化形式：

Wolfram Language code: x^1 / 4 EllipticTheta[3, 0, E^π x] == (2UnitStep[Im[x]] - 1) I x^-1 / 4 EllipticTheta[3, 0, E^π / x]
Wolfram Language code: % /. x -> -2.

有限高斯和的渐进逼近：

Wolfram Language code: AsymptoticSum[E^-k^2, {k, 1, n}, {n, ∞, 2}]//FullSimplify

比较 时的近似值和精确值：

Wolfram Language code: % /. {n -> 10.}
Wolfram Language code: Underoverscript[∑, k = 1, 10]E^-k^2//N

算术-几何平均数迭代的封闭形式：

Wolfram Language code: ArithmeticGeometricMeanIteration[n_, a_, b_] := With[{z = EllipticNomeQ[1 - ((b/a))^2]}, ArithmeticGeometricMean[a, b]{EllipticTheta[3, 0, z^2^n]^2, EllipticTheta[4, 0, z^2^n]^2}]

比较封闭形式与显式迭代：

Wolfram Language code: Table[ArithmeticGeometricMeanIteration[n, 3., 5.], {n, 0, 4}]
Wolfram Language code: NestList[{Mean[#], GeometricMean[#]}&, {3., 5.}, 4]

将具有给定周期、极点和零点的任何椭圆函数组成 EllipticTheta 的有理函数：

Wolfram Language code: makeEllipticFunction[z_, {ω1_, ω3_}, zeros_List, poles_List] := Module[{c = π / (2 ω1), q = Exp[I π ω3 / ω1]}, (Product[EllipticTheta[1, c (z - r), q], {r, zeros}] / Product[EllipticTheta[1, c (z - s), q], {s, poles}]) (EllipticTheta[1, c (z - Last[poles]), q] / EllipticTheta[1, c (z - Last[poles] - (Total[zeros] - Total[poles])), q])] /; Length[zeros] == Length[poles] && Resolve[Exists[{μ, ν}, Element[{μ, ν}, Integers], Total[zeros] - Total[poles] == μ ω1 + ν ω3]]

形成一个具有单和双零点及三极的椭圆函数：

Wolfram Language code: f[z_] = makeEllipticFunction[z, {1, I}, {1 / 3 + 1 / 3 I, 1 / 3 + 1 / 3 I, -2 / 3 - 2 / 3 I}, {0, 0, 0}]

绘制得到的椭圆函数：

Wolfram Language code: ComplexPlot[f[z], {z, -1.5 - 1.5I, 1.5 + 1.5I}, ColorFunction -> "CyclicReImLogAbs"]

属性和关系  (2)

计算超越方程的数值根：

Wolfram Language code: FindRoot[EllipticTheta[1, z, 1 / 3]^3 + EllipticTheta[3, z, 1 / 3] + z == 2, {z, 2}]

Sum 可以产生椭圆塞塔函数：

Wolfram Language code: Sum[(-1) ^ n q ^ (n ^ 2), {n, Infinity}]

可能存在的问题  (4)

机器精度输入不足以给出正确结果：

Wolfram Language code: EllipticTheta[1, 10. ^ 30, 1 / 2]

用任意精度算法获得正确结果：

Wolfram Language code: N[EllipticTheta[1, 10 ^ 30, 1 / 2], 20]

第一个参数必须是 1 到 4 之间的明确整数：

Wolfram Language code: EllipticTheta[1 + (E + 1) ^ 2 - E ^ 2 - 2E - 1, 3., 1 / 2]
Wolfram Language code: Simplify[%]

EllipticTheta 具有属性 NHoldFirst：

Wolfram Language code: Attributes[EllipticTheta]

对于 theta 函数存在不同的参数约定：

Wolfram Language code: {Plot[EllipticTheta[1, z, (1/2)], {z, 0, 2π}], Plot[EllipticTheta[1, (z/2π), (1/2)], {z, 0, 2π}]}
Wolfram Language code: {Plot[EllipticTheta[1, 2, q], {q, 0.1, 0.8}], Plot[EllipticTheta[1, 2, Exp[I π (I τ)]], {τ, 0.1, 0.8}]}

巧妙范例  (1)

可视化显示函数的解析性边界：

Wolfram Language code: Module[{f, r = 0.995}, f[z_ ? NumberQ] := If[Abs[z] > r, 0, Sin[Arg[EllipticTheta[3, 1, z]] / 2] ^ 2]; DensityPlot[f[qx + I qy], {qx, qy}∈Disk[{0, 0}, r], PlotPoints -> 90, PlotRange -> All, Frame -> False, ColorFunction -> (Hue[2.72 #]&)]]
Wolfram Language code: ParametricPlot3D[{qr Cos[qϕ], qr Sin[qϕ], Abs[EllipticTheta[2, 2, qr E^I qϕ]]}, {qϕ, -π, π}, {qr, 0, 0.99}, BoxRatios -> {1, 1, 0.66}]
Wolfram Research (1988)，EllipticTheta，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticTheta.html （更新于 2022 年）.

文本

Wolfram Research (1988)，EllipticTheta，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticTheta.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "EllipticTheta." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/EllipticTheta.html.

APA

Wolfram 语言. (1988). EllipticTheta. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EllipticTheta.html 年

BibTeX

@misc{reference.wolfram_2026_elliptictheta, author="Wolfram Research", title="{EllipticTheta}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticTheta.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_elliptictheta, organization={Wolfram Research}, title={EllipticTheta}, year={2022}, url={https://reference.wolfram.com/language/ref/EllipticTheta.html}, note=[Accessed: 10-September-2026]}