WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EstimatedPointProcess[pdata,pproc]

点データ pdata からパラメトリック点過程 pproc を推定する．

EstimatedPointProcess[pdata,pproc,{{p,p0},{q,q0},…}]

パラメータ p, q, … を初期値 p0, q0, …で推定する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
クラスタ点過程  
Gibbs点過程  
オプション  
PointProcessEstimator  
WorkingPrecision  
関連項目
関連するガイド
履歴
引用書式

EstimatedPointProcess

EstimatedPointProcess[pdata,pproc]

点データ pdata からパラメトリック点過程 pproc を推定する．

EstimatedPointProcess[pdata,pproc,{{p,p0},{q,q0},…}]

パラメータ p, q, … を初期値 p0, q0, …で推定する．

詳細とオプション

  • EstimatedPointProcessは，点データ pdata を取って記号的な点過程 pproc を返す．非数値的な値についてはパラメータの推定値が挿入される．
  • 一般に，過程 pproc は点データの集合からの方がうまく推定できる．
  • 点 pdata は次の形式でよい．
  • {p1,p2,…}点 pi
    GeoPosition[…],GeoPositionXYZ[…],…地理的な点
    SpatialPointData[…]空間点集合
    {pts,reg}点集合 pts と観測領域 reg
  • 点はSpatialPointDataオブジェクトに変換される．観測領域は，pdata で与えられていない場合はRipley–Rasson推定器を使って生成される．
  • 次は，使用可能なオプションである．
  • AccuracyGoalAutomatic目標確度
    PointProcessEstimator Automatic使用する過程パラメータ推定器
    PrecisionGoalAutomatic目標精度
    WorkingPrecision Automatic内部計算精度
  • PointProcessEstimatorの設定は，個々の点過程のドキュメントページに記載されている．

例題

すべて開く すべて閉じる

例  (1)

PoissonPointProcessのパラメータを推定する：

Wolfram Language code: data = RandomPointConfiguration[PoissonPointProcess[20, 2], Disk[]];
Wolfram Language code: eproc = EstimatedPointProcess[data, PoissonPointProcess[mu, 2]]

推定された過程の最近傍関数をもとのデータと比較する：

Wolfram Language code: gdata = NearestNeighborG[data]; gproc = NearestNeighborG[eproc];
Wolfram Language code: Plot[{gdata[r], gproc[r]}, {r, 0, 0.3}]

スコープ  (3)

クラスタ点過程  (1)

Matern点過程からの点配置のシミュレーションを行う：

Wolfram Language code: proc = MaternPointProcess[20, 30, 1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];
Wolfram Language code: ListPlot[points]

"FindClusters"法を使って点過程モデルを推定する：

Wolfram Language code: est = EstimatedPointProcess[points, MaternPointProcess[a, b, c, d], PointProcessEstimator -> "FindClusters"]

もとの過程と推定モデルの間でRipley 測度を比較する：

Wolfram Language code: DiscretePlot[{RipleyK[est, r], RipleyK[proc, r]}, {r, 0.1, .5, .005}, PlotLegends -> {"original process", "estimated model"}]

Gibbs点過程  (2)

ハードコア点過程を推定する：

Wolfram Language code: proc = HardcorePointProcess[30, .1, 2]; points = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: ListPlot[points]

自動メソッドを使う：

Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, c]]

パラメータの推定法と開始値を明示的に指定する：

Wolfram Language code: a0 = points["MeanPointCount"]; b0 = Min[DeleteCases[Flatten[DistanceMatrix[points["Points"]]], 0. | 0]];
Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, 2], {{a, a0}, {b, b0}}, Method -> "MaximumPseudoLikelihood"]

相互作用点過程を推定する：

Wolfram Language code: proc = StraussPointProcess[100, 0.5, 0.1, 2]; reg = Rectangle[];
Wolfram Language code: pts = RandomPointConfiguration[proc, reg, 3]
Wolfram Language code: ListPlot[pts]

点過程を推定する：

Wolfram Language code: EstimatedPointProcess[pts, StraussPointProcess[μ, γ, R, 2]]

オプション  (3)

PointProcessEstimator  (2)

クラスタ点過程を推定する：

Wolfram Language code: proc = ThomasPointProcess[20, 30, 1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];

"FindClusters"法を使って点過程モデルを推定する：

Wolfram Language code: EstimatedPointProcess[points, ThomasPointProcess[a, b, c, d], PointProcessEstimator -> "FindClusters"]

モーメント法を使う：

Wolfram Language code: EstimatedPointProcess[points, ThomasPointProcess[a, b, c, d], PointProcessEstimator -> "MethodOfMoments"]

相互作用過程を推定する：

Wolfram Language code: proc = HardcorePointProcess[40, .1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];

"MaximumPseudoLikelihood"法を使う：

Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, c], PointProcessEstimator -> "MaximumPseudoLikelihood"]

"MaximumLikelihood"法を使う：

Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, c], PointProcessEstimator -> "MaximumLikelihood"]

WorkingPrecision  (1)

クラスタ点過程を任意精度で推定する：

Wolfram Language code: proc = PoissonPointProcess[30, 2]; points = RandomPointConfiguration[proc, Disk[], WorkingPrecision -> 20];

WorkingPrecisionを指定する：

Wolfram Language code: EstimatedPointProcess[points, PoissonPointProcess[μ, d], WorkingPrecision -> 20]

EstimatedPointProcessは，デフォルトで，MachinePrecisionを使う：

Wolfram Language code: EstimatedPointProcess[points, PoissonPointProcess[μ, d]]
Wolfram Research (2020), EstimatedPointProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/EstimatedPointProcess.html.

テキスト

Wolfram Research (2020), EstimatedPointProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/EstimatedPointProcess.html.

CMS

Wolfram Language. 2020. "EstimatedPointProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/EstimatedPointProcess.html.

APA

Wolfram Language. (2020). EstimatedPointProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EstimatedPointProcess.html

BibTeX

@misc{reference.wolfram_2026_estimatedpointprocess, author="Wolfram Research", title="{EstimatedPointProcess}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/EstimatedPointProcess.html}", note=[Accessed: 05-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_estimatedpointprocess, organization={Wolfram Research}, title={EstimatedPointProcess}, year={2020}, url={https://reference.wolfram.com/language/ref/EstimatedPointProcess.html}, note=[Accessed: 05-September-2026]}