WOLFRAM

Wolfram 语言与系统参考资料中心

EstimatedPointProcess[pdata,pproc]

根据点数据 pdata 估计参数化点过程 pproc.

EstimatedPointProcess[pdata,pproc,{{p,p0},{q,q0},…}]

从起始值 p0、q0、… 开始估计参数 p、q、….

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
聚类点过程  
Gibbs 点过程  
选项  
PointProcessEstimator  
WorkingPrecision  
参见
相关指南
历史
按以下格式引用：

EstimatedPointProcess

EstimatedPointProcess[pdata,pproc]

根据点数据 pdata 估计参数化点过程 pproc.

EstimatedPointProcess[pdata,pproc,{{p,p0},{q,q0},…}]

从起始值 p0、q0、… 开始估计参数 p、q、….

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

估计 PoissonPointProcess 的参数：

Wolfram Language code: data = RandomPointConfiguration[PoissonPointProcess[20, 2], Disk[]];
Wolfram Language code: eproc = EstimatedPointProcess[data, PoissonPointProcess[mu, 2]]

将估计所得过程的最近邻函数与原始数据进行比较：

Wolfram Language code: gdata = NearestNeighborG[data]; gproc = NearestNeighborG[eproc];
Wolfram Language code: Plot[{gdata[r], gproc[r]}, {r, 0, 0.3}]

范围  (3)

聚类点过程  (1)

模拟 Matern 点过程的点布局：

Wolfram Language code: proc = MaternPointProcess[20, 30, 1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];
Wolfram Language code: ListPlot[points]

用 "FindClusters"方法估计点过程模型：

Wolfram Language code: est = EstimatedPointProcess[points, MaternPointProcess[a, b, c, d], PointProcessEstimator -> "FindClusters"]

比较原来的过程和估计所得模型的 Ripley 测度：

Wolfram Language code: DiscretePlot[{RipleyK[est, r], RipleyK[proc, r]}, {r, 0.1, .5, .005}, PlotLegends -> {"original process", "estimated model"}]

Gibbs 点过程  (2)

估计硬核点过程：

Wolfram Language code: proc = HardcorePointProcess[30, .1, 2]; points = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: ListPlot[points]

使用自动方法：

Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, c]]

使用参数的固定值和初始值：

Wolfram Language code: a0 = points["MeanPointCount"]; b0 = Min[DeleteCases[Flatten[DistanceMatrix[points["Points"]]], 0. | 0]];
Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, 2], {{a, a0}, {b, b0}}, Method -> "MaximumPseudoLikelihood"]

估计交互点过程：

Wolfram Language code: proc = StraussPointProcess[100, 0.5, 0.1, 2]; reg = Rectangle[];
Wolfram Language code: pts = RandomPointConfiguration[proc, reg, 3]
Wolfram Language code: ListPlot[pts]

估计点过程：

Wolfram Language code: EstimatedPointProcess[pts, StraussPointProcess[μ, γ, R, 2]]

选项  (3)

PointProcessEstimator  (2)

估计聚类点过程：

Wolfram Language code: proc = ThomasPointProcess[20, 30, 1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];

用 "FindClusters" 方法估计点过程模型：

Wolfram Language code: EstimatedPointProcess[points, ThomasPointProcess[a, b, c, d], PointProcessEstimator -> "FindClusters"]

使用矩估计 (method of moments)：

Wolfram Language code: EstimatedPointProcess[points, ThomasPointProcess[a, b, c, d], PointProcessEstimator -> "MethodOfMoments"]

估计交互过程：

Wolfram Language code: proc = HardcorePointProcess[40, .1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];

使用 "MaximumPseudoLikelihood" 方法：

Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, c], PointProcessEstimator -> "MaximumPseudoLikelihood"]

使用 "MaximumLikelihood" 方法

Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, c], PointProcessEstimator -> "MaximumLikelihood"]

WorkingPrecision  (1)

以任意精度估计聚类点过程：

Wolfram Language code: proc = PoissonPointProcess[30, 2]; points = RandomPointConfiguration[proc, Disk[], WorkingPrecision -> 20];

指定 WorkingPrecision：

Wolfram Language code: EstimatedPointProcess[points, PoissonPointProcess[μ, d], WorkingPrecision -> 20]

默认情况下，EstimatedPointProcess 使用 MachinePrecision：

Wolfram Language code: EstimatedPointProcess[points, PoissonPointProcess[μ, d]]
Wolfram Research (2020)，EstimatedPointProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EstimatedPointProcess.html.

文本

Wolfram Research (2020)，EstimatedPointProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EstimatedPointProcess.html.

CMS

Wolfram 语言. 2020. "EstimatedPointProcess." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/EstimatedPointProcess.html.

APA

Wolfram 语言. (2020). EstimatedPointProcess. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EstimatedPointProcess.html 年

BibTeX

@misc{reference.wolfram_2026_estimatedpointprocess, author="Wolfram Research", title="{EstimatedPointProcess}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/EstimatedPointProcess.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_estimatedpointprocess, organization={Wolfram Research}, title={EstimatedPointProcess}, year={2020}, url={https://reference.wolfram.com/language/ref/EstimatedPointProcess.html}, note=[Accessed: 07-September-2026]}