WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EstimatedProcess[data,proc]

data からパラメトリック過程 proc を推定する．

EstimatedProcess[data,proc,{{p,p0},{q,q0},…}]

初期値 p0, q0, …の母数 p, q, …を推定する．

EstimatedProcess[data,proc,iproc]

例示化された過程 iproc からの初期値を使って，過程 proc を推定する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
パラメトリック過程  
時系列過程  
待ち行列過程  
有限マルコフ過程  
オプション  
ProcessEstimator  
WorkingPrecision  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

EstimatedProcess

EstimatedProcess[data,proc]

data からパラメトリック過程 proc を推定する．

EstimatedProcess[data,proc,{{p,p0},{q,q0},…}]

初期値 p0, q0, …の母数 p, q, …を推定する．

EstimatedProcess[data,proc,iproc]

例示化された過程 iproc からの初期値を使って，過程 proc を推定する．

詳細とオプション

  • EstimatedProcessは，任意の非数値について母数推定が挿入された記号過程 proc を返す．
  • data は次の形で与えることができる．
  • {s0,…}時間 i における状態が siの経路
    {{t0,s0},…}時間 tiにおける状態が siの経路
    TemporalData[…]1本あるいは複数の経路
  • 時間 tiおよび状態 siは，過程 proc の時間および状態の領域に属するものでなければならない．
  • 過程 proc は任意のパラメトリックスカラー過程あるいはパラメトリックベクトル過程でよい．
  • 使用可能なオプション
  • AccuracyGoalAutomatic目標確度
    ProcessEstimator Automaticどの過程母数推定器を使うか
    PrecisionGoalAutomatic目標精度
    WorkingPrecision Automatic内部計算で使用する精度
  • ProcessEstimatorには次の基本設定を使うことができる．
  • Automatic母数推定器を自動的に選択する
    "MaximumLikelihood"対数尤度を直接最大化する
    "MethodOfMoments"共分散をマッチする
  • ProcessEstimatorの特殊設定は，個別のランダム過程参照ページに記載されている．
  • 時系列過程のこの他の設定には，"MaximumConditionalLikelihood"および"SpectralEstimator"がある．
  • HiddenMarkovProcessのこの他の設定には，"BaumWelch"および"ViterbiTraining"がある．

例題

すべて開く すべて閉じる

例  (2)

PoissonProcessの母数を推定する：

Wolfram Language code: data = RandomFunction[PoissonProcess[.4], {0, 10 ^ 2}];
Wolfram Language code: eproc = EstimatedProcess[data, PoissonProcess[λ]]

推定過程のシミュレーションともとのデータを比較する：

Wolfram Language code: sims = RandomFunction[eproc, {0, 10 ^ 2}, 3];
Wolfram Language code: ListLinePlot[Join[data["Paths"], sims["Paths"]], PlotStyle -> {Thick, Dashed, Dashed, Dashed}, PlotLegends -> {"data", "simulations"}]

ARProcessの母数を求める：

Wolfram Language code: data = RandomFunction[ARProcess[{.2, .1, -.3}, .1], {1, 100}];
Wolfram Language code: eproc = EstimatedProcess[data, ARProcess[{a, b, c}, v]]

データと推定過程の相関関数を比較する：

Wolfram Language code: ρdata = CorrelationFunction[data, {25}];
Wolfram Language code: ρproc = CorrelationFunction[eproc, {25}];
Wolfram Language code: ListLinePlot[{ρdata, ρproc}, DataRange -> {0, 25}, PlotLegends -> {"data", "process"}]

スコープ  (9)

パラメトリック過程  (3)

RandomWalkProcessの母数を推定する：

Wolfram Language code: SeedRandom[1234];data = RandomFunction[RandomWalkProcess[0.3], {0, 400}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: EstimatedProcess[data, RandomWalkProcess[p]]

パラメータに開始値を使う：

Wolfram Language code: EstimatedProcess[data, RandomWalkProcess[p], {{p, .5}}]

RenewalProcessの母数を推定する：

Wolfram Language code: data = RandomFunction[RenewalProcess[GammaDistribution[2, 1]], {0, 10 ^ 3}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: EstimatedProcess[data, RenewalProcess[GammaDistribution[a, b]]]

ウィナー(Wiener)過程の母数を推定する：

Wolfram Language code: data = RandomFunction[WienerProcess[.4, .7], {0, 100, 0.01}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: EstimatedProcess[data, WienerProcess[μ, σ]]

時系列過程  (3)

ARProcessの母数を推定する：

Wolfram Language code: proc = ARProcess[{-.2, .3, -.3}, .1];
Wolfram Language code: data = RandomFunction[proc, {0, 10 ^ 3}];
Wolfram Language code: eproc = EstimatedProcess[data, ARProcess[3]]

共分散関数を比較する：

Wolfram Language code: DiscretePlot[Evaluate@(CovarianceFunction[#, h]& /@ {proc, eproc}), {h, 0, 10}, ExtentSize -> 1 / 2]

ARMAProcessを推定する：

Wolfram Language code: proc = ARMAProcess[{.2, .3}, {0.26}, .1];
Wolfram Language code: data = RandomFunction[proc, {0, 1000}];
Wolfram Language code: eproc = EstimatedProcess[data, ARMAProcess[2, 1]]

相関関数を比較する：

Wolfram Language code: DiscretePlot[Evaluate@(CorrelationFunction[#, h]& /@ {proc, eproc}), {h, 0, 4}, ExtentSize -> 1 / 2]

ARProcessの推定のために初期値を与える：

Wolfram Language code: proc = ARProcess[{-.2, .3, -.3}, .1]; data = RandomFunction[proc, {0, 10 ^ 3}];
Wolfram Language code: EstimatedProcess[data, ARProcess[{a, b, c}, v], {{a, -.2}, {b, .3}, {c, -.3}, {v, .1}}]

初期値は，数値パラメータを持つ対応するモデルとして与えることもできる：

Wolfram Language code: EstimatedProcess[data, ARProcess[{a, b, c}, v], proc]

繰り返された母数について解く：

Wolfram Language code: data = RandomFunction[ARProcess[{-.2, .3, -.3}, .1], {0, 10 ^ 3}];
Wolfram Language code: EstimatedProcess[data, ARProcess[{a, b, a}, v]]

待ち行列過程  (1)

M/M/1の待ち行列の母数推定：

Wolfram Language code: 𝒬 = QueueingProcess[5., 13];
Wolfram Language code: data = RandomFunction[𝒬, {0, 200}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: 𝒬1 = EstimatedProcess[data, QueueingProcess[λ, μ]]

データの対応するランダムな経路を使う：

Wolfram Language code: 𝒬2 = EstimatedProcess[data["Path"], QueueingProcess[λ, μ]]

もとの過程と推定された過程について系の大きさを比べる：

Wolfram Language code: {QueueProperties[𝒬, "MeanSystemSize"], QueueProperties[𝒬2, "MeanSystemSize"]}

有限マルコフ過程  (2)

4状態離散マルコフ(Markov)過程を推定する：

Wolfram Language code: 𝒫 = DiscreteMarkovProcess[3, {{1 / 2, 1 / 2, 0, 0}, {1 / 2, 1 / 2, 0, 0}, {1 / 4, 1 / 4, 1 / 4, 1 / 4}, {0, 0, 0, 1}}];
Wolfram Language code: data = RandomFunction[𝒫, {0, 10 ^ 4}, 10];
Wolfram Language code: Map[MatrixForm, estproc = EstimatedProcess[data, DiscreteMarkovProcess[4], WorkingPrecision -> MachinePrecision]]

4状態連続マルコフ過程を推定する：

Wolfram Language code: 𝒫 = ContinuousMarkovProcess[{1, 0, 0, 0}, (⁠| | | | | | -- | -- | -- | - | | -3 | 1 | 2 | 0 | | 3 | -6 | 2 | 1 | | 4 | 2 | -9 | 3 | | 0 | 0 | 0 | 0 |⁠)];
Wolfram Language code: data = RandomFunction[𝒫, {0, 10 ^ 2}, 10 ^ 3];
Wolfram Language code: Map[MatrixForm, estproc = EstimatedProcess[data, ContinuousMarkovProcess[4], WorkingPrecision -> MachinePrecision]]

オプション  (5)

ProcessEstimator  (4)

パラメトリック過程についての最大尤度：

Wolfram Language code: data = RandomFunction[WienerProcess[0, 1], {0, 100, .1}];
Wolfram Language code: EstimatedProcess[data, WienerProcess[a, b], ProcessEstimator -> "MaximumLikelihood"]

時系列過程：

Wolfram Language code: data = RandomFunction[ARProcess[{.3, .2}, 1], {10 ^ 3}];
Wolfram Language code: EstimatedProcess[data, ARProcess[2], ProcessEstimator -> "MaximumLikelihood"]

パラメトリック過程についてのモーメント法：

Wolfram Language code: data = RandomFunction[PoissonProcess[3], {0, 10 ^ 4}];
Wolfram Language code: EstimatedProcess[data, PoissonProcess[m], {{m, 3}}, ProcessEstimator -> "MethodOfMoments"]

時系列過程：

Wolfram Language code: data = RandomFunction[ARMAProcess[{.3, .2}, {.5}, 1], {10 ^ 4}];
Wolfram Language code: EstimatedProcess[data, ARMAProcess[2, 1], ProcessEstimator -> "MethodOfMoments"]

時系列過程についての条件付き最大尤度：

Wolfram Language code: data = RandomFunction[ARMAProcess[{.3, .2}, {.5}, 1], {10 ^ 4}];
Wolfram Language code: EstimatedProcess[data, ARMAProcess[2, 1], ProcessEstimator -> "MaximumConditionalLikelihood"]

時系列過程についてのスペクトル推定量：

Wolfram Language code: data = RandomFunction[ARProcess[{.3, .2}, 1], {10 ^ 3}];
Wolfram Language code: EstimatedProcess[data, ARProcess[2], ProcessEstimator -> "SpectralEstimator"]

WorkingPrecision  (1)

デフォルトの機械精度で過程を推定する：

Wolfram Language code: data = RandomFunction[QueueingProcess[5, 11], {0, 150}];
Wolfram Language code: EstimatedProcess[data, QueueingProcess[λ, μ]]

より高い精度を使う：

Wolfram Language code: data = RandomFunction[QueueingProcess[5, 11], {0, 150}, WorkingPrecision -> 20];
Wolfram Language code: EstimatedProcess[data, QueueingProcess[λ, μ], WorkingPrecision -> 20]

アプリケーション  (2)

2012年8月のシャンペーンについて，日ごとの平均気温をモデル化する：

Wolfram Language code: temp = TemporalData[TimeSeries, {{{20.5, 20.89, 22.5, 27.44, 26.5, 20.33, 18.83, 23.06, 20.83, 19.72, 14.89, 15.28, 18.11, 18.72, 17.5, 20.83, 17.94, 13.56, 16.44, 14.33, 14.72, 15.83, 17.28, 19.89, 20.44, 21.39, 24.89, 22.78, 22.83, 20.22, 24.4 ... te", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 1, MetaInformation -> {"Source" -> HoldForm[WeatherData["Champaign", "MeanTemperature", {{2012, 8}, {2012, 8}, "Day"}]]}}}, True, 10.1];
Wolfram Language code: temp["Source"]
Wolfram Language code: DateListPlot[temp, Joined -> True, Filling -> Axis]

過程母数を求める：

Wolfram Language code: eproc = EstimatedProcess[temp, ARProcess[20]]

モデルとデータのCorrelationFunctionを比較する：

Wolfram Language code: ListPlot[TemporalData[CorrelationFunction[#, {30}]& /@ {eproc, temp}], Filling -> {1 -> {2}}, PlotStyle -> PointSize[Medium], PlotLegends -> {"Model", "Data"}]

2012年の5月から9月までのユーロ・ドル間の日ごとの為替レートを予測する：

Wolfram Language code: data = TemporalData[TimeSeries, {{{1.31, 1.31, 1.31, 1.3, 1.3, 1.3, 1.29, 1.29, 1.29, 1.27, 1.28, 1.28, 1.27, 1.26, 1.26, 1.26, 1.25, 1.24, 1.24, 1.23, 1.24, 1.24, 1.25, 1.26, 1.25, 1.26, 1.25, 1.25, 1.26, 1.26, 1.26, 1.26, 1.27, 1.27, 1.25, 1.2 ... yRange"]}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, MetaInformation -> {"Source" -> HoldForm[FinancialData]["EUR/USD", {{2012, 5, 1}, {2012, 9, 30}}]}}}, True, 10.1];
Wolfram Language code: data["Source"]
Wolfram Language code: DateListPlot[data, Joined -> True, Filling -> Bottom]

為替レートにAR過程をフィットさせる：

Wolfram Language code: eproc = EstimatedProcess[data, ARProcess[3]]

20営業日先を予測する：

Wolfram Language code: forecast = TimeSeriesForecast[eproc, data, {20}]

予測をもとのデータとともにプロットする：

Wolfram Language code: DateListPlot[{data, forecast}, Joined -> True, Filling -> Bottom]

特性と関係  (2)

EstimatedProcessはパラメトリック過程を推定する：

Wolfram Language code: data = RandomFunction[PoissonProcess[3], {0, 10 ^ 4}];
Wolfram Language code: EstimatedProcess[data, PoissonProcess[m]]

FindProcessParametersは過程についての母数推定のリストを返す：

Wolfram Language code: FindProcessParameters[data, PoissonProcess[m]]

EstimatedProcessはパラメトリック過程を推定する：

Wolfram Language code: data = RandomFunction[BernoulliProcess[0.4], {0, 10 ^ 5}];
Wolfram Language code: EstimatedProcess[data, BernoulliProcess[p]]

EstimatedDistributionはパラメトリック分布を推定する：

Wolfram Language code: data = RandomVariate[BernoulliDistribution[0.4], 10 ^ 5];
Wolfram Language code: EstimatedDistribution[data, BernoulliDistribution[p]]
Wolfram Research (2012), EstimatedProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/EstimatedProcess.html.

テキスト

Wolfram Research (2012), EstimatedProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/EstimatedProcess.html.

CMS

Wolfram Language. 2012. "EstimatedProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/EstimatedProcess.html.

APA

Wolfram Language. (2012). EstimatedProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EstimatedProcess.html

BibTeX

@misc{reference.wolfram_2026_estimatedprocess, author="Wolfram Research", title="{EstimatedProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/EstimatedProcess.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_estimatedprocess, organization={Wolfram Research}, title={EstimatedProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/EstimatedProcess.html}, note=[Accessed: 16-September-2026]}