WOLFRAM

Wolfram 语言与系统参考资料中心

EstimatedProcess[data,proc]

根据 data 估计参数化过程 proc.

EstimatedProcess[data,proc,{{p,p0},{q,q0},…}]

估计参数 p、q、…，初始值为 p0、q0、… .

EstimatedProcess[data,proc,iproc]

估计过程 proc，其中初始值从实例化过程 iproc 取得.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
参数化过程  
时间序列过程  
排队过程  
有限马可夫过程  
选项  
ProcessEstimator  
WorkingPrecision  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

EstimatedProcess

EstimatedProcess[data,proc]

根据 data 估计参数化过程 proc.

EstimatedProcess[data,proc,{{p,p0},{q,q0},…}]

估计参数 p、q、…，初始值为 p0、q0、… .

EstimatedProcess[data,proc,iproc]

估计过程 proc，其中初始值从实例化过程 iproc 取得.

更多信息和选项

  • EstimatedProcess 返回符号过程 proc，并用估计的参数值替换非数字的值.
  • data 可以按下列形式给出：
  • {s0,…}时间 i 处状态为 si 的路径
    {{t0,s0},…}时间 ti 处状态为 si 的路径
    TemporalData[…]一个或者几个路径
  • 时间 ti 和状态 si 必须属于过程 proc 的时间和状态域.
  • 过程 proc 可以是任何参数化标量或者向量值过程.
  • 可以给出下列选项：
  • AccuracyGoalAutomatic追求的准确度
    ProcessEstimator Automatic使用哪个过程参数估值器
    PrecisionGoalAutomatic追求的精度
    WorkingPrecision Automatic在内部计算中使用的精度
  • 对 ProcessEstimator 可以使用下列基本设置：
  • Automatic自动选择参数估值器
    "MaximumLikelihood"直接最大化对数似然
    "MethodOfMoments"匹配协方差
  • 在单个随机过程参考页面中，对 ProcessEstimator 的特殊设置进行存档.
  • 时间序列过程的额外设置包括 "MaximumConditionalLikelihood" 和 "SpectralEstimator".
  • HiddenMarkovProcess 的额外设置包括 "BaumWelch" 和 "ViterbiTraining".

范例

打开所有单元 关闭所有单元

基本范例  (2)

估计 PoissonProcess 的参数：

Wolfram Language code: data = RandomFunction[PoissonProcess[.4], {0, 10 ^ 2}];
Wolfram Language code: eproc = EstimatedProcess[data, PoissonProcess[λ]]

将估计过程的模拟和原始数据比较：

Wolfram Language code: sims = RandomFunction[eproc, {0, 10 ^ 2}, 3];
Wolfram Language code: ListLinePlot[Join[data["Paths"], sims["Paths"]], PlotStyle -> {Thick, Dashed, Dashed, Dashed}, PlotLegends -> {"data", "simulations"}]

求 ARProcess 的参数：

Wolfram Language code: data = RandomFunction[ARProcess[{.2, .1, -.3}, .1], {1, 100}];
Wolfram Language code: eproc = EstimatedProcess[data, ARProcess[{a, b, c}, v]]

比较数据和估计过程的相关函数：

Wolfram Language code: ρdata = CorrelationFunction[data, {25}];
Wolfram Language code: ρproc = CorrelationFunction[eproc, {25}];
Wolfram Language code: ListLinePlot[{ρdata, ρproc}, DataRange -> {0, 25}, PlotLegends -> {"data", "process"}]

范围  (9)

参数化过程  (3)

估计 RandomWalkProcess 的参数：

Wolfram Language code: SeedRandom[1234];data = RandomFunction[RandomWalkProcess[0.3], {0, 400}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: EstimatedProcess[data, RandomWalkProcess[p]]

使用参数的初始值：

Wolfram Language code: EstimatedProcess[data, RandomWalkProcess[p], {{p, .5}}]

估计 RenewalProcess 的参数：

Wolfram Language code: data = RandomFunction[RenewalProcess[GammaDistribution[2, 1]], {0, 10 ^ 3}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: EstimatedProcess[data, RenewalProcess[GammaDistribution[a, b]]]

估计 Wiener 过程的参数：

Wolfram Language code: data = RandomFunction[WienerProcess[.4, .7], {0, 100, 0.01}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: EstimatedProcess[data, WienerProcess[μ, σ]]

时间序列过程  (3)

估计 ARProcess 的参数：

Wolfram Language code: proc = ARProcess[{-.2, .3, -.3}, .1];
Wolfram Language code: data = RandomFunction[proc, {0, 10 ^ 3}];
Wolfram Language code: eproc = EstimatedProcess[data, ARProcess[3]]

比较协方差函数：

Wolfram Language code: DiscretePlot[Evaluate@(CovarianceFunction[#, h]& /@ {proc, eproc}), {h, 0, 10}, ExtentSize -> 1 / 2]

估计 ARMAProcess：

Wolfram Language code: proc = ARMAProcess[{.2, .3}, {0.26}, .1];
Wolfram Language code: data = RandomFunction[proc, {0, 1000}];
Wolfram Language code: eproc = EstimatedProcess[data, ARMAProcess[2, 1]]

比较协方差函数：

Wolfram Language code: DiscretePlot[Evaluate@(CorrelationFunction[#, h]& /@ {proc, eproc}), {h, 0, 4}, ExtentSize -> 1 / 2]

提供 ARProcess 估计的初始值：

Wolfram Language code: proc = ARProcess[{-.2, .3, -.3}, .1]; data = RandomFunction[proc, {0, 10 ^ 3}];
Wolfram Language code: EstimatedProcess[data, ARProcess[{a, b, c}, v], {{a, -.2}, {b, .3}, {c, -.3}, {v, .1}}]

也可以用含有数值参数的对应模型给出初始值：

Wolfram Language code: EstimatedProcess[data, ARProcess[{a, b, c}, v], proc]

求解重复参数：

Wolfram Language code: data = RandomFunction[ARProcess[{-.2, .3, -.3}, .1], {0, 10 ^ 3}];
Wolfram Language code: EstimatedProcess[data, ARProcess[{a, b, a}, v]]

排队过程  (1)

对 M/M/1 队列的参数估计：

Wolfram Language code: 𝒬 = QueueingProcess[5., 13];
Wolfram Language code: data = RandomFunction[𝒬, {0, 200}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: 𝒬1 = EstimatedProcess[data, QueueingProcess[λ, μ]]

对数据使用相应的随机路径：

Wolfram Language code: 𝒬2 = EstimatedProcess[data["Path"], QueueingProcess[λ, μ]]

比较原始过程和估计过程的系统尺寸：

Wolfram Language code: {QueueProperties[𝒬, "MeanSystemSize"], QueueProperties[𝒬2, "MeanSystemSize"]}

有限马可夫过程  (2)

估计四状态离散马可夫过程：

Wolfram Language code: 𝒫 = DiscreteMarkovProcess[3, {{1 / 2, 1 / 2, 0, 0}, {1 / 2, 1 / 2, 0, 0}, {1 / 4, 1 / 4, 1 / 4, 1 / 4}, {0, 0, 0, 1}}];
Wolfram Language code: data = RandomFunction[𝒫, {0, 10 ^ 4}, 10];
Wolfram Language code: Map[MatrixForm, estproc = EstimatedProcess[data, DiscreteMarkovProcess[4], WorkingPrecision -> MachinePrecision]]

估计四状态连续马可夫过程：

Wolfram Language code: 𝒫 = ContinuousMarkovProcess[{1, 0, 0, 0}, (⁠| | | | | | -- | -- | -- | - | | -3 | 1 | 2 | 0 | | 3 | -6 | 2 | 1 | | 4 | 2 | -9 | 3 | | 0 | 0 | 0 | 0 |⁠)];
Wolfram Language code: data = RandomFunction[𝒫, {0, 10 ^ 2}, 10 ^ 3];
Wolfram Language code: Map[MatrixForm, estproc = EstimatedProcess[data, ContinuousMarkovProcess[4], WorkingPrecision -> MachinePrecision]]

选项  (5)

ProcessEstimator  (4)

参数过程的最大似然：

Wolfram Language code: data = RandomFunction[WienerProcess[0, 1], {0, 100, .1}];
Wolfram Language code: EstimatedProcess[data, WienerProcess[a, b], ProcessEstimator -> "MaximumLikelihood"]

时间序列过程：

Wolfram Language code: data = RandomFunction[ARProcess[{.3, .2}, 1], {10 ^ 3}];
Wolfram Language code: EstimatedProcess[data, ARProcess[2], ProcessEstimator -> "MaximumLikelihood"]

参数过程的矩方法：

Wolfram Language code: data = RandomFunction[PoissonProcess[3], {0, 10 ^ 4}];
Wolfram Language code: EstimatedProcess[data, PoissonProcess[m], ProcessEstimator -> "MethodOfMoments"]

时间序列过程：

Wolfram Language code: data = RandomFunction[ARMAProcess[{.3, .2}, {.5}, 1], {10 ^ 4}];
Wolfram Language code: EstimatedProcess[data, ARMAProcess[2, 1], ProcessEstimator -> "MethodOfMoments"]

时间序列过程的最大条件似然：

Wolfram Language code: data = RandomFunction[ARMAProcess[{.3, .2}, {.5}, 1], {10 ^ 4}];
Wolfram Language code: EstimatedProcess[data, ARMAProcess[2, 1], ProcessEstimator -> "MaximumConditionalLikelihood"]

时间序列过程的谱估值：

Wolfram Language code: data = RandomFunction[ARProcess[{.3, .2}, 1], {10 ^ 3}];
Wolfram Language code: EstimatedProcess[data, ARProcess[2], ProcessEstimator -> "SpectralEstimator"]

WorkingPrecision  (1)

使用默认机器精度估计过程：

Wolfram Language code: data = RandomFunction[QueueingProcess[5, 11], {0, 150}];
Wolfram Language code: EstimatedProcess[data, QueueingProcess[λ, μ]]

使用较高的精度：

Wolfram Language code: data = RandomFunction[QueueingProcess[5, 11], {0, 150}, WorkingPrecision -> 20];
Wolfram Language code: EstimatedProcess[data, QueueingProcess[λ, μ], WorkingPrecision -> 20]

应用  (2)

对2012年8月香槟每日平均温度建模：

Wolfram Language code: temp = TemporalData[TimeSeries, {{{20.5, 20.89, 22.5, 27.44, 26.5, 20.33, 18.83, 23.06, 20.83, 19.72, 14.89, 15.28, 18.11, 18.72, 17.5, 20.83, 17.94, 13.56, 16.44, 14.33, 14.72, 15.83, 17.28, 19.89, 20.44, 21.39, 24.89, 22.78, 22.83, 20.22, 24.4 ... te", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 1, MetaInformation -> {"Source" -> HoldForm[WeatherData["Champaign", "MeanTemperature", {{2012, 8}, {2012, 8}, "Day"}]]}}}, True, 10.1];
Wolfram Language code: temp["Source"]
Wolfram Language code: DateListPlot[temp, Joined -> True, Filling -> Axis]

求过程参数：

Wolfram Language code: eproc = EstimatedProcess[temp, ARProcess[20]]

比较模型和数据的 CorrelationFunction：

Wolfram Language code: ListPlot[TemporalData[CorrelationFunction[#, {30}]& /@ {eproc, temp}], Filling -> {1 -> {2}}, PlotStyle -> PointSize[Medium], PlotLegends -> {"Model", "Data"}]

预测从2012年5月至2012年9月欧元对美元的汇率：

Wolfram Language code: data = TemporalData[TimeSeries, {{{1.31, 1.31, 1.31, 1.3, 1.3, 1.3, 1.29, 1.29, 1.29, 1.27, 1.28, 1.28, 1.27, 1.26, 1.26, 1.26, 1.25, 1.24, 1.24, 1.23, 1.24, 1.24, 1.25, 1.26, 1.25, 1.26, 1.25, 1.25, 1.26, 1.26, 1.26, 1.26, 1.27, 1.27, 1.25, 1.2 ... yRange"]}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, MetaInformation -> {"Source" -> HoldForm[FinancialData]["EUR/USD", {{2012, 5, 1}, {2012, 9, 30}}]}}}, True, 10.1];
Wolfram Language code: data["Source"]
Wolfram Language code: DateListPlot[data, Joined -> True, Filling -> Bottom]

对汇率拟合 AR 过程：

Wolfram Language code: eproc = EstimatedProcess[data, ARProcess[3]]

预测未来20个工作日：

Wolfram Language code: forecast = TimeSeriesForecast[eproc, data, {20}]

绘制预测和原始数据图线：

Wolfram Language code: DateListPlot[{data, forecast}, Joined -> True, Filling -> Bottom]

属性和关系  (2)

EstimatedProcess 估计参数化过程：

Wolfram Language code: data = RandomFunction[PoissonProcess[3], {0, 10 ^ 4}];
Wolfram Language code: EstimatedProcess[data, PoissonProcess[m]]

FindProcessParameters 对过程返回参数估值列表：

Wolfram Language code: FindProcessParameters[data, PoissonProcess[m]]

EstimatedProcess 估计参数化过程：

Wolfram Language code: data = RandomFunction[BernoulliProcess[0.4], {0, 10 ^ 5}];
Wolfram Language code: EstimatedProcess[data, BernoulliProcess[p]]

EstimatedDistribution 估计参数式分布：

Wolfram Language code: data = RandomVariate[BernoulliDistribution[0.4], 10 ^ 5];
Wolfram Language code: EstimatedDistribution[data, BernoulliDistribution[p]]
Wolfram Research (2012)，EstimatedProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EstimatedProcess.html.

文本

Wolfram Research (2012)，EstimatedProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EstimatedProcess.html.

CMS

Wolfram 语言. 2012. "EstimatedProcess." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/EstimatedProcess.html.

APA

Wolfram 语言. (2012). EstimatedProcess. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EstimatedProcess.html 年

BibTeX

@misc{reference.wolfram_2026_estimatedprocess, author="Wolfram Research", title="{EstimatedProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/EstimatedProcess.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_estimatedprocess, organization={Wolfram Research}, title={EstimatedProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/EstimatedProcess.html}, note=[Accessed: 13-September-2026]}