Wolfram言語＆システムドキュメントセンター

EventData

EventData[{e₁,e₂,…}]

明示的に指定された打切り e_i持つ事象データを表す．

EventData[{e₁,e₂,…},{ci₁,ci₂,…}]

打切り指標 ci_iの事象データ e_iを表す．

EventData[{e₁,e₂,…},{cc₁,cc₂,…}]

打切り数 cc_iの事象データ e_iを表す．

EventData[{e₁,e₂,…},cspec,{tr₁,tr₂,…}]

打切りと切断 tr_iの事象データを表す．

EventData

EventData[{e₁,e₂,…}]

明示的に指定された打切り e_i持つ事象データを表す．

EventData[{e₁,e₂,…},{ci₁,ci₂,…}]

打切り指標 ci_iの事象データ e_iを表す．

EventData[{e₁,e₂,…},{cc₁,cc₂,…}]

打切り数 cc_iの事象データ e_iを表す．

EventData[{e₁,e₂,…},cspec,{tr₁,tr₂,…}]

打切りと切断 tr_iの事象データを表す．

詳細

EventDataは打切りと切断の情報があるデータを増強する．
e_iについて次の事象指定を使うことができる．

	t_i	打切りなし．事象は tt_i に発生する
	{t_i,∞}	右側打切り．事象は t_i≤t であるなんらかの t で発生する
	{-∞,t_i}	左側打切り．事象は t<t_iであるなんらかの t で発生する
	{t_i,min,t_i,max}	区間打切り．事象は t_i,min<t≤t_i,maxであるなんらかの t で発生する

ci_iには次の打切り指標が使える．
0, None {t,t} 打切りなし

1, Right {t,∞} 右側打切り

-1,Left {-∞,t} 左側打切り
cc_iには次の数指定が使える．

	{ n_i}	e_iにおいて n_i回の事象
	{n_i,r_i}	e_iにおいて n_i回の事象と r_i回の右側打切り事象
	{n_i,r_i,l_i}	e_iにおいて n_i回の事象，r_i回の右側打切り事象，l_i回の左側打切り事象

tr_iには次の事象指定を使うことができる．
t_i,{t_i,∞} 左側切断．で可観測

{-∞,t_i} 右側切断．で可観測

{t_i,min,t_i,max} 両側切断．t_i,min≤t≤t_i,maxで可観測
EventDataは以下の統計関数で使うことができる．

	Mean,Variance,…	記述統計関数
	EmpiricalDistribution,…	ノンパラメトリック分布推定
	EstimatedDistribution,…	パラメトリック分布推定
	SurvivalModelFit,…	生存率分析のための関数

EventDataの特性はEventData[…]["property"]を指定することで得ることができる．
EventData[…]["Properties"]を使って使用可能な特性リストが得られる．
EventDataには次の特性がある．

	"CensoringIndicators"	打切り指標{ci₁,…}
	"CensoredData"	{{t₁,∞},…}の形での打切り事象区間
	"EmpiricalPDF"	事象の位置と対応する推定された重み
	"InputData"	入力事象指定{e₁,…}
	"MetaInformation"	メタ情報規則のリスト
	"TruncationIntervals"	切断区間{tr₁,…}
	"CensoringType"	存在する最も一般的な打切りのタイプ
	"TruncationType"	存在する最も一般的な切断のタイプ

例題

すべて開くすべて閉じる

例 (1)

右側打切りデータの値を示す：

Wolfram Language code:

e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};

Wolfram Language code: 𝒜 = EventData[e, ci]

いくつかの記述統計を計算する：

Wolfram Language code: Median[𝒜]

Wolfram Language code: InterquartileRange[𝒜]

スコープ (12)

基本的な用法 (5)

事象データの記述統計を計算する：

Wolfram Language code:

t = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
c = {1, 0, 0, 0, 0, 0, 1, 1, 0, 0};

Wolfram Language code: 𝒜 = EventData[t, c]

Wolfram Language code: Table[{i, i[𝒜]}, {i, {Mean, Median, Variance, StandardDeviation, Kurtosis, Skewness, InterquartileRange}}]//Grid

ノンパラメトリック分布を事象データにフィットする：

Wolfram Language code:

data = RandomVariate[WeibullDistribution[3, 4], 50];
t = Table[If[i > 4, 4, i], {i, data}];
c = Table[Boole[i == 4], {i, t}];

Wolfram Language code: 𝒜 = EventData[t, c]

Wolfram Language code: dists = Table[𝒟[𝒜], {𝒟, {EmpiricalDistribution, HistogramDistribution, SmoothKernelDistribution}}];

Wolfram Language code:

Table[Plot[SurvivalFunction[i, x], {x, 0, 5}, PlotLabel -> Row[{"Median: ", Median[i]}], PlotRange -> {0, 1}], {i, dists}]

パラメトリック分布を事象データにフィットする：

Wolfram Language code:

data = BlockRandom[SeedRandom[10];RandomVariate[WeibullDistribution[3, 4], 50]];
t = Table[If[i > 4, 4, i], {i, data}];
c = Table[Boole[i == 4], {i, t}];

Wolfram Language code: 𝒜 = EventData[t, c]

Wolfram Language code: 𝒟1 = EstimatedDistribution[𝒜, WeibullDistribution[a, b]]

分布と経験的推定をプロットする：

Wolfram Language code: 𝒟2 = EmpiricalDistribution[𝒜];

Wolfram Language code: Plot[{SurvivalFunction[𝒟1, x], SurvivalFunction[𝒟2, x]}, {x, 0, 5}]

SurvivalModelFitを使ってモデルをフィットする：

Wolfram Language code:

t = {7, 23, 22, 6, 25, 20, 19, 6, 17, 6, 13};
c = {0, 0, 0, 0, 1, 1, 1, 0, 1, 0, 0};

Wolfram Language code: e = EventData[t, c]

Wolfram Language code: 𝒮 = SurvivalModelFit[e];

信頼帯のある経験的生存関数：

Wolfram Language code: Plot[{𝒮[x], 𝒮["PointwiseBands"][x]}, {x, 5, 30}]

CoxModelFitを使って共変量のあるモデルをフィットする：

Wolfram Language code:

y = EventData[{8, 22, 6, 4, 12, 11, 2, 34, 25, 15, 8, 6, 34, 6, 32, 1, 15, 9, 9, 6}, {0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0}]

Wolfram Language code: x = {1, 0, 0, 1, 1, 1, 1, 0, 0, 1, 1, 0, 0, 0, 0, 1, 1, 0, 0, 0};

Wolfram Language code: phMod = CoxModelFit[{x, y}, {g}, {g}]

パラメトリック推定：

Wolfram Language code: phMod["ParameterTable"]

2つのグループの生存率の比較：

Wolfram Language code: Plot[Evaluate@Table[phMod["SF"][i][t], {i, {{0}, {1}}}], {t, 0, 35}, PlotPoints -> 75]

打切りと切断の指定 (7)

さまざまな方法で右側打切りを指定する：

Wolfram Language code:

𝒜1 = EventData[{2, 3, {4, ∞}, 5}];
𝒜2 = EventData[{2, 3, 4, 5}, {0, 0, 1, 0}];
𝒜3 = EventData[{2, 3, 4, 5}, {None, None, Right, None}];
𝒜4 = EventData[{2, 3, 4, 5}, {{1}, {1}, {0, 1}, {1}}];

オブジェクトはどれも3番目が右側打切りになった同じ4つの観測を表している：

Wolfram Language code: SurvivalModelFit[𝒜1]["EventMatrixPlot"]

Wolfram Language code: Equal@@Table[CDF[EmpiricalDistribution[𝒜], x], {𝒜, {𝒜1, 𝒜2, 𝒜3, 𝒜4}}]

左側打切り：

Wolfram Language code:

𝒜1 = EventData[{2, 3, {-∞, 4}, 5}];
𝒜2 = EventData[{2, 3, 4, 5}, {0, 0, -1, 0}];
𝒜3 = EventData[{2, 3, 4, 5}, {None, None, Left, None}];
𝒜4 = EventData[{2, 3, 4, 5}, {{1}, {1}, {0, 0, 1}, {1}}];

オブジェクトはどれも3番目が左側打切りになった同じ4つの観測を表している：

Wolfram Language code: SurvivalModelFit[𝒜1]["EventMatrixPlot"]

Wolfram Language code: Equal@@Table[CDF[EmpiricalDistribution[𝒜], x], {𝒜, {𝒜1, 𝒜2, 𝒜3, 𝒜4}}]

区間打切り：

Wolfram Language code: 𝒜 = EventData[{2, 3, {2, 4}, 5}];

オブジェクトはどれも3番目が区間打切りになった4つの観測を表している：

Wolfram Language code: SurvivalModelFit[𝒜]["EventMatrixPlot"]

複数の等価観測を示すために数値を使う：

Wolfram Language code:

𝒜1 = EventData[{2, 3, 3, 3, 4, {4, ∞}, {4, ∞}, {-∞, 4}, 5}];
𝒜2 = EventData[{2, 3, 4, 5}, {{1}, {3}, {1, 2, 1}, {1}}];

それぞれのオブジェクトは同じ9つの観測を表している：

Wolfram Language code: SurvivalModelFit[𝒜1]["EventMatrixPlot"]

Wolfram Language code: Equal@@Table[CDF[EmpiricalDistribution[𝒜], x], {𝒜, {𝒜1, 𝒜2}}]

左側切断を指定する：

Wolfram Language code:

𝒜1 = EventData[{5, 6, 7, 8}, None, {{4, ∞}, {5, ∞}, {6, ∞}, {7, ∞}}];
𝒜2 = EventData[{5, 6, 7, 8}, None, {4, 5, 6, 7}];

オブジェクトは左側切断で打切りなしのデータを等しく表している：

Wolfram Language code: {SurvivalModelFit[𝒜1]["EventMatrixPlot"], SurvivalModelFit[𝒜1]["TruncationMatrixPlot"]}

Wolfram Language code: Equal@@Table[CDF[EmpiricalDistribution[𝒜], x], {𝒜, {𝒜1, 𝒜2}}]

右側切断を指定する：

Wolfram Language code: 𝒜 = EventData[{5, 6, 7, 8}, None, {{-∞, 6}, {-∞, 7}, {-∞, 8}, {-∞, 9}}];

オブジェクトは右側切断で打切りなしのデータを表している：

Wolfram Language code: {SurvivalModelFit[𝒜]["EventMatrixPlot"], SurvivalModelFit[𝒜]["TruncationMatrixPlot"]}

データは打ち切りかつ切断されることができる：

Wolfram Language code: 𝒜 = EventData[{2, 3, 4, 5}, {0, 0, 1, 0}, {1, 2, 3, 4}];

オブジェクトは右側打切りで左側切断のデータを表している：

Wolfram Language code: {SurvivalModelFit[𝒜]["EventMatrixPlot"], SurvivalModelFit[𝒜]["TruncationMatrixPlot"]}

アプリケーション (1)

推定生存関数のプロットで右側打切りをマークする：

Wolfram Language code:

𝒜 = EventData[Automatic, {{7, 23, 22, 6, 25, 20, 19, 6, 17, 6, 13}, {0, 0, 0, 0, 1, 1, 1, 0, 1, 0, 0}, 
  None}];

推定生存関数：

Wolfram Language code: sf[t_] := SurvivalModelFit[𝒜][t]

打切りマーカを作る：

Wolfram Language code: rc = Cases[Transpose[{𝒜["CensoredData"], 𝒜["CensoringIndicators"]}], {_, 1}]

Wolfram Language code: cns = Graphics[Table[Line[{{i, sf[i] - .05}, {i, sf[i] + .05}}], {i, rc[[All, 1]]}]];

推定生存関数のプロットと打切りマーカを示す：

Wolfram Language code: Show[Plot[sf[t], {t, 0, 30}, Exclusions -> None, PlotRange -> {0, 1}], cns]

特性と関係 (1)

記述統計は潜在的なSurvivalDistributionに基づいている：

Wolfram Language code:

𝒜 = EventData[{8, 22, 6, 4, 12, 11, 2, 34, 25, 15, 8, 6, 34, 6, 32, 1, 15, 9, 9, 6}, {0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0}]

Wolfram Language code: 𝒟 = SurvivalDistribution[𝒜];

Wolfram Language code: {{Mean[𝒜], Median[𝒜]}, {Mean[𝒟], Median[𝒟]}}

サンプル推定は母集団推定と異なるときに与えられる：

Wolfram Language code: StandardDeviation[𝒜]

Wolfram Language code: StandardDeviation[𝒟]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

EventData

詳細

例題

例 (1)

スコープ (12)

基本的な用法 (5)

打切りと切断の指定 (7)

アプリケーション (1)

特性と関係 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

0, None	{t,t}	打切りなし
1, Right	{t,∞}	右側打切り
-1,Left	{-∞,t}	左側打切り

	t_i,{t_i,∞}	左側切断．で可観測
	{-∞,t_i}	右側切断．で可観測
	{t_i,min,t_i,max}	両側切断．t_i,min≤t≤t_i,maxで可観測

EventData

詳細

例題

例 (1)

スコープ (12)

基本的な用法 (5)

打切りと切断の指定 (7)

アプリケーション (1)

特性と関係 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX