WOLFRAM

Wolfram 语言与系统参考资料中心

EventData[{e1,e2,…}]

表示具有显式指定的删截 ei 的事件数据.

EventData[{e1,e2,…},{ci1,ci2,…}]

表示具有删截指示 cii 的事件数据 ei.

EventData[{e1,e2,…},{cc1,cc2,…}]

表示具有删截数目 cci 的事件数据 ei.

EventData[{e1,e2,…},cspec,{tr1,tr2,…}]

表示删截和截断 tri 的事件数据.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用途  
指定删截和截断  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

EventData

EventData[{e1,e2,…}]

表示具有显式指定的删截 ei 的事件数据.

EventData[{e1,e2,…},{ci1,ci2,…}]

表示具有删截指示 cii 的事件数据 ei.

EventData[{e1,e2,…},{cc1,cc2,…}]

表示具有删截数目 cci 的事件数据 ei.

EventData[{e1,e2,…},cspec,{tr1,tr2,…}]

表示删截和截断 tri 的事件数据.

更多信息

  • 具有删截和截断信息的 EventData 参数数据.
  • 下列事件指定可用于 ei：
  • ti没有删截；事件发生在 tti
    {ti,∞}右删截；事件发生在某 t 其中 ti≤t
    {-∞,ti}左删截；事件发生在某 t 其中 t<ti
    {ti,min,ti,max}区间删截；事件发生在某 t 其中 ti,min<t≤ti,max
  • 对于 cii 可使用下列删截指示：
  • 0, None{t,t}没有删截
    1, Right{t,∞}右删截
    -1,Left{-∞,t}左删截
  • 对于 cci 可以使用下列数目指定：
  • { ni}ei 处的 ni 个事件
    {ni,ri}ei 处的 ni 个事件和 ri 个右删截事件
    {ni,ri,li}ei 处的 ni 个事件，ri 个右删截事件和 li 个左删截事件
  • 对于 tri 可以使用下列事件指定：
  • ti,{ti,∞}左删截；对于 t>=t_(i) 可观测
    {-∞,ti}右删截；对于 t<=t_(i) 可观测
    {ti,min,ti,max}区间删截；在 ti,min≤t≤ti,max 上可观测
  • EventData 可用于统计函数包括：
  • Mean,Variance,…描述性统计函数
    EmpiricalDistribution,…非参数化分布估计
    EstimatedDistribution,…参数化分布估计
    SurvivalModelFit,…生存分析函数
  • EventData 的属性可以通过指定 EventData[…]["property"] 获得.
  • 可用属性列表可以通过 EventData[…]["Properties"] 获得.
  • EventData 具有下列属性：
  • "CensoringIndicators"删截指示 {ci1,…}
    "CensoredData"形如 {{t1,∞},…} 的删截事情区间
    "EmpiricalPDF"事件位置和相应的估计权值
    "InputData"输入事件指定 {e1,…}
    "MetaInformation"元信息规则列表
    "TruncationIntervals"截断区间 {tr1,…}
    "CensoringType"删截出现的最常见类型
    "TruncationType"截断出现的最常见类型

范例

打开所有单元 关闭所有单元

基本范例  (1)

表明右删截数据值：

Wolfram Language code: e = {1.0, 2.1, 3.2, 4.5, 5.7}; ci = {0, 0, 0, 1, 0};
Wolfram Language code: 𝒜 = EventData[e, ci]

计算某些描述性统计量：

Wolfram Language code: Median[𝒜]
Wolfram Language code: InterquartileRange[𝒜]

范围  (12)

基本用途  (5)

计算事件数据的描述性统计量：

Wolfram Language code: t = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3}; c = {1, 0, 0, 0, 0, 0, 1, 1, 0, 0};
Wolfram Language code: 𝒜 = EventData[t, c]
Wolfram Language code: Table[{i, i[𝒜]}, {i, {Mean, Median, Variance, StandardDeviation, Kurtosis, Skewness, InterquartileRange}}]//Grid

对事情数据进行非参数分布拟合：

Wolfram Language code: data = RandomVariate[WeibullDistribution[3, 4], 50]; t = Table[If[i > 4, 4, i], {i, data}]; c = Table[Boole[i == 4], {i, t}];
Wolfram Language code: 𝒜 = EventData[t, c]
Wolfram Language code: dists = Table[𝒟[𝒜], {𝒟, {EmpiricalDistribution, HistogramDistribution, SmoothKernelDistribution}}];
Wolfram Language code: Table[Plot[SurvivalFunction[i, x], {x, 0, 5}, PlotLabel -> Row[{"Median: ", Median[i]}], PlotRange -> {0, 1}], {i, dists}]

对事情数据进行参数化分布拟合：

Wolfram Language code: data = BlockRandom[SeedRandom[10];RandomVariate[WeibullDistribution[3, 4], 50]]; t = Table[If[i > 4, 4, i], {i, data}]; c = Table[Boole[i == 4], {i, t}];
Wolfram Language code: 𝒜 = EventData[t, c]
Wolfram Language code: 𝒟1 = EstimatedDistribution[𝒜, WeibullDistribution[a, b]]

绘制分布和经验估计的图线：

Wolfram Language code: 𝒟2 = EmpiricalDistribution[𝒜];
Wolfram Language code: Plot[{SurvivalFunction[𝒟1, x], SurvivalFunction[𝒟2, x]}, {x, 0, 5}]

使用 SurvivalModelFit 进行模型拟合：

Wolfram Language code: t = {7, 23, 22, 6, 25, 20, 19, 6, 17, 6, 13}; c = {0, 0, 0, 0, 1, 1, 1, 0, 1, 0, 0};
Wolfram Language code: e = EventData[t, c]
Wolfram Language code: 𝒮 = SurvivalModelFit[e];

具有置信带的经验生存函数：

Wolfram Language code: Plot[{𝒮[x], 𝒮["PointwiseBands"][x]}, {x, 5, 30}]

使用 CoxModelFit 拟合协方差模型：

Wolfram Language code: y = EventData[{8, 22, 6, 4, 12, 11, 2, 34, 25, 15, 8, 6, 34, 6, 32, 1, 15, 9, 9, 6}, {0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0}]
Wolfram Language code: x = {1, 0, 0, 1, 1, 1, 1, 0, 0, 1, 1, 0, 0, 0, 0, 1, 1, 0, 0, 0};
Wolfram Language code: phMod = CoxModelFit[{x, y}, {g}, {g}]

参数估计：

Wolfram Language code: phMod["ParameterTable"]

比较两组数据的生存率：

Wolfram Language code: Plot[Evaluate@Table[phMod["SF"][i][t], {i, {{0}, {1}}}], {t, 0, 35}, PlotPoints -> 75]

指定删截和截断  (7)

以多种方法指定右删截：

Wolfram Language code: 𝒜1 = EventData[{2, 3, {4, ∞}, 5}]; 𝒜2 = EventData[{2, 3, 4, 5}, {0, 0, 1, 0}]; 𝒜3 = EventData[{2, 3, 4, 5}, {None, None, Right, None}]; 𝒜4 = EventData[{2, 3, 4, 5}, {{1}, {1}, {0, 1}, {1}}];

所有对象都表示四个相同的观测，其中第三个是右删截：

Wolfram Language code: SurvivalModelFit[𝒜1]["EventMatrixPlot"]
Wolfram Language code: Equal@@Table[CDF[EmpiricalDistribution[𝒜], x], {𝒜, {𝒜1, 𝒜2, 𝒜3, 𝒜4}}]

左删截：

Wolfram Language code: 𝒜1 = EventData[{2, 3, {-∞, 4}, 5}]; 𝒜2 = EventData[{2, 3, 4, 5}, {0, 0, -1, 0}]; 𝒜3 = EventData[{2, 3, 4, 5}, {None, None, Left, None}]; 𝒜4 = EventData[{2, 3, 4, 5}, {{1}, {1}, {0, 0, 1}, {1}}];

所有对象表示相同的四个观测，其中第三个观测是左删截的：

Wolfram Language code: SurvivalModelFit[𝒜1]["EventMatrixPlot"]
Wolfram Language code: Equal@@Table[CDF[EmpiricalDistribution[𝒜], x], {𝒜, {𝒜1, 𝒜2, 𝒜3, 𝒜4}}]

区间删截：

Wolfram Language code: 𝒜 = EventData[{2, 3, {2, 4}, 5}];

对象表示四个观测，其中第三个是区间删截：

Wolfram Language code: SurvivalModelFit[𝒜]["EventMatrixPlot"]

使用数目指定来表明多个等价观测：

Wolfram Language code: 𝒜1 = EventData[{2, 3, 3, 3, 4, {4, ∞}, {4, ∞}, {-∞, 4}, 5}]; 𝒜2 = EventData[{2, 3, 4, 5}, {{1}, {3}, {1, 2, 1}, {1}}];

每个对象表示相同的九个观测：

Wolfram Language code: SurvivalModelFit[𝒜1]["EventMatrixPlot"]
Wolfram Language code: Equal@@Table[CDF[EmpiricalDistribution[𝒜], x], {𝒜, {𝒜1, 𝒜2}}]

指定左截断：

Wolfram Language code: 𝒜1 = EventData[{5, 6, 7, 8}, None, {{4, ∞}, {5, ∞}, {6, ∞}, {7, ∞}}]; 𝒜2 = EventData[{5, 6, 7, 8}, None, {4, 5, 6, 7}];

对象表示左截断非删截数据：

Wolfram Language code: {SurvivalModelFit[𝒜1]["EventMatrixPlot"], SurvivalModelFit[𝒜1]["TruncationMatrixPlot"]}
Wolfram Language code: Equal@@Table[CDF[EmpiricalDistribution[𝒜], x], {𝒜, {𝒜1, 𝒜2}}]

指定右删截：

Wolfram Language code: 𝒜 = EventData[{5, 6, 7, 8}, None, {{-∞, 6}, {-∞, 7}, {-∞, 8}, {-∞, 9}}];

对象表示右截断非删截数据：

Wolfram Language code: {SurvivalModelFit[𝒜]["EventMatrixPlot"], SurvivalModelFit[𝒜]["TruncationMatrixPlot"]}

数据可以同时被删截和截断：

Wolfram Language code: 𝒜 = EventData[{2, 3, 4, 5}, {0, 0, 1, 0}, {1, 2, 3, 4}];

对象表示右删截左截断数据：

Wolfram Language code: {SurvivalModelFit[𝒜]["EventMatrixPlot"], SurvivalModelFit[𝒜]["TruncationMatrixPlot"]}

应用  (1)

在估计生存函数的图线加上右删截记号：

Wolfram Language code: 𝒜 = EventData[Automatic, {{7, 23, 22, 6, 25, 20, 19, 6, 17, 6, 13}, {0, 0, 0, 0, 1, 1, 1, 0, 1, 0, 0}, None}];

估计生存函数：

Wolfram Language code: sf[t_] := SurvivalModelFit[𝒜][t]

创建删截记号：

Wolfram Language code: rc = Cases[Transpose[{𝒜["CensoredData"], 𝒜["CensoringIndicators"]}], {_, 1}]
Wolfram Language code: cns = Graphics[Table[Line[{{i, sf[i] - .05}, {i, sf[i] + .05}}], {i, rc[[All, 1]]}]];

显示具有估计生存的删截记号图线：

Wolfram Language code: Show[Plot[sf[t], {t, 0, 30}, Exclusions -> None, PlotRange -> {0, 1}], cns]

属性和关系  (1)

描述性统计量基于内部的 SurvivalDistribution：

Wolfram Language code: 𝒜 = EventData[{8, 22, 6, 4, 12, 11, 2, 34, 25, 15, 8, 6, 34, 6, 32, 1, 15, 9, 9, 6}, {0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0}]
Wolfram Language code: 𝒟 = SurvivalDistribution[𝒜];
Wolfram Language code: {{Mean[𝒜], Median[𝒜]}, {Mean[𝒟], Median[𝒟]}}

当样本估计与总体估计不同时，给出样本估计：

Wolfram Language code: StandardDeviation[𝒜]
Wolfram Language code: StandardDeviation[𝒟]
Wolfram Research (2012)，EventData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EventData.html.

文本

Wolfram Research (2012)，EventData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EventData.html.

CMS

Wolfram 语言. 2012. "EventData." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/EventData.html.

APA

Wolfram 语言. (2012). EventData. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EventData.html 年

BibTeX

@misc{reference.wolfram_2026_eventdata, author="Wolfram Research", title="{EventData}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/EventData.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_eventdata, organization={Wolfram Research}, title={EventData}, year={2012}, url={https://reference.wolfram.com/language/ref/EventData.html}, note=[Accessed: 09-September-2026]}