WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Exists[x,expr]

expr がTrueとなるような xの値が存在するという陳述を表す．

Exists[x,cond,expr]

expr がTrueとなるような条件 cond を満足する x が存在することを宣言する．

Exists[{x1,x2,…},expr]

すべての xiについて expr がTrueであるような値が存在することを宣言する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Exists

Exists[x,expr]

expr がTrueとなるような xの値が存在するという陳述を表す．

Exists[x,cond,expr]

expr がTrueとなるような条件 cond を満足する x が存在することを宣言する．

Exists[{x1,x2,…},expr]

すべての xiについて expr がTrueであるような値が存在することを宣言する．

詳細

  • Exists[x,expr]は exists _(x)expr と入力できる． exists 記号はexあるいは\[Exists]と入力できる．変数 x は下付き文字として与えられる．
  • Exists[x,cond,expr]は exists _(x,cond)expr と入力できる．
  • StandardFormでは，Exists[x,expr]は exists _(x)expr と出力される．
  • Exists[x,cond,expr]は exists _(x,cond)expr として出力される．
  • Existsは，Reduce，Resolve，FullSimplify等の関数で用いることができる．
  • 制約条件 cond は，x∈Integersのように，しばしば変数の領域を指定するのに用いられる．
  • Exists[x,cond,expr]はExists[x,cond&&expr]と等価である．
  • Exists[{x1,x2,…},…]は exists _(x_(1)) exists _(x_(2))... と等価である．
  • Exists[x,expr]における x の値はBlockにおけるように局所化されると解釈される．

例題

すべて開く すべて閉じる

例  (1)

次は，方程式 に正の解が存在すると述べている：

Wolfram Language code: Exists[x, a x ^ 2 + b x + c == 0 && x > 0]

Resolveを使ってこの陳述が真になる実数パラメータの条件を求める：

Wolfram Language code: Resolve[%, Reals]

Reduceは，解かれた形で条件を返す：

Wolfram Language code: Reduce[%%, {a, b, c}, Reals]

スコープ  (6)

次は，方程式が真になる が存在すると述べている：

Wolfram Language code: Exists[x, x ^ 2 - x + 1 == 0]

Resolveを使ってこの陳述が真であることを証明する：

Wolfram Language code: Resolve[%]

次は，方程式が真となる実数 が存在すると述べている：

Wolfram Language code: Exists[x, Element[x, Reals], x ^ 2 - x + 1 == 0]

Resolveを使ってこの陳述が偽であることを証明する：

Wolfram Language code: Resolve[%]

次は，不等式が真となるペアが存在すると述べている：

Wolfram Language code: Exists[{x, y}, x ^ 2 + y ^ 2 < 0]

領域指定がないので，Resolveは不等式中の代数的変数が実数であるとみなす：

Wolfram Language code: Resolve[%]

領域をComplexesとすると，不等式がTrueになる複素数値が使える：

Wolfram Language code: Resolve[%%, Complexes]

次は，トートロジーの否定が満足できると述べている：

Wolfram Language code: Exists[{p, q}, !Implies[p && Implies[p, q], q]]

Resolveを使ってこれがFalseであることを証明する：

Wolfram Language code: Resolve[%]

式が明示的に変数を含まない場合，Existsは自動的に簡約する：

Wolfram Language code: Exists[x, y == 0]
Wolfram Language code: Exists[{x, y, z}, y == z]

TraditionalFormによる表示：

Wolfram Language code: Exists[x, p[x]]//TraditionalForm

アプリケーション  (4)

次は，二次方程式が負の値に達すると述べている：

Wolfram Language code: Exists[x, a x ^ 2 + b x + c < 0]

次は，実数パラメータで明示的な条件を返す：

Wolfram Language code: Resolve[%, Reals]

1つの領域が他の領域に含まれるかどうかテストする：

Wolfram Language code: R1 = (2x) ^ 2 + y ^ 2 + 2 x y ≤ 1; R2 = x ^ 2 + y ^ 2 ≤ 2;

次は，R1は満足するがR2は満足しない点があると述べている：

Wolfram Language code: Exists[{x, y}, Element[x | y, Reals], R1 && !R2]

この陳述は偽である．したがってR1で定義された範囲はR2で定義された範囲に含まれる：

Wolfram Language code: Resolve[%]

この関係をプロットする：

Wolfram Language code: {r1, r2} = {RegionPlot[R1, {x, -2, 2}, {y, -2, 2}, PlotPoints -> 35, PlotStyle -> Pink], RegionPlot[R2, {x, -2, 2}, {y, -2, 2}]};
Wolfram Language code: Show[{r2, r1}]

幾何学的な推測をテストする：

Wolfram Language code: triangle = a > 0 && b > 0 && c > 0 && a + b > c && a + c > b && b + c > a; s = 1 / 2(a + b + c); F = Sqrt[s(s - a)(s - b)(s - c)]; conjecture = 27(b ^ 2 + c ^ 2 - a ^ 2) ^ 2(a ^ 2 + c ^ 2 - b ^ 2) ^ 2(a ^ 2 + b ^ 2 - c ^ 2) ^ 2 ≤ (4F) ^ 6;

次は，推測が真ではない三角形が存在すると述べている：

Wolfram Language code: Exists[{a, b, c}, Element[a | b | c, Reals], triangle && !conjecture]

この陳述は真である．したがって推測は任意の三角形について真である訳ではない：

Wolfram Language code: Resolve[%]

次は，推測が真ではない鋭角三角形が存在すると述べている：

Wolfram Language code: acute = a ^ 2 + b ^ 2 > c ^ 2 && a ^ 2 + c ^ 2 > b ^ 2 && b ^ 2 + c ^ 2 > a ^ 2;
Wolfram Language code: Exists[{a, b, c}, Element[a | b | c, Reals], triangle && acute && !conjecture]

この陳述は偽である．したがってこの推測はすべての鋭角三角形について真である：

Wolfram Language code: Resolve[%]

この陳述がトートロジーであることを証明する：

Wolfram Language code: statement = (a && ((a && !(b || (a && c))) || b || (a && c))) || !a || !((a && !(b || (a && c))) || b || (a && c));

次は，この陳述が真ではないの値は存在しないことを証明している：

Wolfram Language code: Resolve[Exists[{a, b, c}, !statement]]

これは，TautologyQを用いても証明できる：

Wolfram Language code: TautologyQ[statement]

特性と関係  (5)

Existsを否定するとForAllが返される：

Wolfram Language code: !Exists[x, x == a]
Wolfram Language code: !Exists[x, Element[x, Reals], x == a]

ResolveまたはReduceを使って量限定子を除去することができる：

Wolfram Language code: form = Exists[{x, y}, x ≠ y && a x ^ 2 + b x + c == 0 && a y ^ 2 + b y + c == 0]

このように量限定子を除去する：

Wolfram Language code: Resolve[form, Reals]

次では，量限定子を除去し，結果の方程式と不等式を解く：

Wolfram Language code: Reduce[form, {a, b, c}, Reals]

次は，不等式系が解を持つことを示している：

Wolfram Language code: ineqs = x ^ 2 + y ^ 2 < 2 && (x - 1) ^ 2 + (y - 1) ^ 2 < 2
Wolfram Language code: Resolve[Exists[{x, y}, ineqs], Reals]

FindInstanceを使って明示的な解の例を求める：

Wolfram Language code: FindInstance[ineqs, {x, y}, Reals]

次は，方程式を満足する複素数 が存在すると述べている：

Wolfram Language code: Exists[x, x ^ 2 + y ^ 2 + z ^ 2 == 1 && x y == z ^ 3]

Resolveを使って，この陳述が真となる と の条件を求める：

Wolfram Language code: Resolve[%]

次は，Eliminateを使って同じ問題を解いている：

Wolfram Language code: Eliminate[x ^ 2 + y ^ 2 + z ^ 2 == 1 && x y == z ^ 3, x]

次は，複素代数集合 の 軸に沿った投影を求める：

Wolfram Language code: Reduce[Exists[y, x y == 1], x]

次は，実単位円の 軸に沿った投影を求める：

Wolfram Language code: Reduce[Exists[y, x ^ 2 + y ^ 2 ≤ 1], x, Reals]
Wolfram Research (2003), Exists, Wolfram言語関数， https://reference.wolfram.com/language/ref/Exists.html.

テキスト

Wolfram Research (2003), Exists, Wolfram言語関数， https://reference.wolfram.com/language/ref/Exists.html.

CMS

Wolfram Language. 2003. "Exists." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Exists.html.

APA

Wolfram Language. (2003). Exists. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Exists.html

BibTeX

@misc{reference.wolfram_2026_exists, author="Wolfram Research", title="{Exists}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/Exists.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_exists, organization={Wolfram Research}, title={Exists}, year={2003}, url={https://reference.wolfram.com/language/ref/Exists.html}, note=[Accessed: 09-September-2026]}