WOLFRAM

Wolfram 语言与系统参考资料中心

Exists[x,expr]

一个语句，表示当 expr 为 True 时存在着一个 x 值.

Exists[x,cond,expr]

表示当 expr 为 True 时，存在着一个满足条件 cond 的 x 值.

Exists[{x1,x2,…},expr]

表示当 expr 为 True 时，存在着所有 xi 值.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Exists

Exists[x,expr]

一个语句，表示当 expr 为 True 时存在着一个 x 值.

Exists[x,cond,expr]

表示当 expr 为 True 时，存在着一个满足条件 cond 的 x 值.

Exists[{x1,x2,…},expr]

表示当 expr 为 True 时，存在着所有 xi 值.

更多信息

  • Exists[x,expr] 可以输入为 exists _(x)expr. 字符 exists 可以用 ex 或 \[Exists] 输入. 变量 x 作为下标给出.
  • Exists[x,cond,expr] 可以输入为 exists _(x,cond)expr.
  • 在 StandardForm 中，Exists[x,expr] 输出为 exists _(x)expr.
  • Exists[x,cond,expr] 输出为 exists _(x,cond)expr.
  • Exists 可以用于诸如 Reduce、Resolve 和 FullSimplify 的函数中.
  • 条件 cond 通常用于指定一个变量的域，例如 x∈Integers.
  • Exists[x,cond,expr] 等价于 Exists[x,cond&&expr].
  • Exists[{x1,x2,…},…] 等价于 exists _(x_(1)) exists _(x_(2))....
  • Exists[x,expr] 中的 x 值可以视为局部的，如同在 Block 中.

范例

打开所有单元 关闭所有单元

基本范例  (1)

以下声明方程 存在一个正解：

Wolfram Language code: Exists[x, a x ^ 2 + b x + c == 0 && x > 0]

用 Resolve 获得一个语句为真的实参条件：

Wolfram Language code: Resolve[%, Reals]

Reduce 给出一个解形式的条件：

Wolfram Language code: Reduce[%%, {a, b, c}, Reals]

范围  (6)

以下声明对所有为真的方程式存在着 ：

Wolfram Language code: Exists[x, x ^ 2 - x + 1 == 0]

用 Resolve 证明该语句为真：

Wolfram Language code: Resolve[%]

表示为真的方程式存在着一个实数 ：

Wolfram Language code: Exists[x, Element[x, Reals], x ^ 2 - x + 1 == 0]

用 Resolve 证明该语句为假：

Wolfram Language code: Resolve[%]

以下声明存在着一对 ，不等式为真：

Wolfram Language code: Exists[{x, y}, x ^ 2 + y ^ 2 < 0]

未指定域时，Resolve 认为不等式中的代数变量为实数：

Wolfram Language code: Resolve[%]

当域为 Complexes 时，允许使不等式为 True 的复数值：

Wolfram Language code: Resolve[%%, Complexes]

以下声明一个重言式的否定是可以满足的：

Wolfram Language code: Exists[{p, q}, !Implies[p && Implies[p, q], q]]

用 Resolve 证明它为 False：

Wolfram Language code: Resolve[%]

如果该表达式没有直接包含变量，Exists 会自动化简：

Wolfram Language code: Exists[x, y == 0]
Wolfram Language code: Exists[{x, y, z}, y == z]

TraditionalForm 格式输出：

Wolfram Language code: Exists[x, p[x]]//TraditionalForm

应用  (4)

以下声明一个达到负值的二项式：

Wolfram Language code: Exists[x, a x ^ 2 + b x + c < 0]

它给出实数参数的条件：

Wolfram Language code: Resolve[%, Reals]

检验一个区域是否包括在另一个区域中：

Wolfram Language code: R1 = (2x) ^ 2 + y ^ 2 + 2 x y ≤ 1; R2 = x ^ 2 + y ^ 2 ≤ 2;

以下声明存在满足 R1 而不是 R2 的点：

Wolfram Language code: Exists[{x, y}, Element[x | y, Reals], R1 && !R2]

该语句为假，因此 R1 定义的区域被包括在 R2 定义的区域内：

Wolfram Language code: Resolve[%]

绘制关系图：

Wolfram Language code: {r1, r2} = {RegionPlot[R1, {x, -2, 2}, {y, -2, 2}, PlotPoints -> 35, PlotStyle -> Pink], RegionPlot[R2, {x, -2, 2}, {y, -2, 2}]};
Wolfram Language code: Show[{r2, r1}]

检验几何猜想：

Wolfram Language code: triangle = a > 0 && b > 0 && c > 0 && a + b > c && a + c > b && b + c > a; s = 1 / 2(a + b + c); F = Sqrt[s(s - a)(s - b)(s - c)]; conjecture = 27(b ^ 2 + c ^ 2 - a ^ 2) ^ 2(a ^ 2 + c ^ 2 - b ^ 2) ^ 2(a ^ 2 + b ^ 2 - c ^ 2) ^ 2 ≤ (4F) ^ 6;

以下声明存在着一个三角形，使猜想不为真：

Wolfram Language code: Exists[{a, b, c}, Element[a | b | c, Reals], triangle && !conjecture]

该语句为真，因此对于任意三角形，猜想为真：

Wolfram Language code: Resolve[%]

以下声明存在着一个锐角三角形，使猜想不为真：

Wolfram Language code: acute = a ^ 2 + b ^ 2 > c ^ 2 && a ^ 2 + c ^ 2 > b ^ 2 && b ^ 2 + c ^ 2 > a ^ 2;
Wolfram Language code: Exists[{a, b, c}, Element[a | b | c, Reals], triangle && acute && !conjecture]

该语句为假，因此对于所有锐角三角形，猜想为真：

Wolfram Language code: Resolve[%]

证明一个语句是一个重言式：

Wolfram Language code: statement = (a && ((a && !(b || (a && c))) || b || (a && c))) || !a || !((a && !(b || (a && c))) || b || (a && c));

它证明不为真的语句不存在 值：

Wolfram Language code: Resolve[Exists[{a, b, c}, !statement]]

它同样可以用 TautologyQ 证明：

Wolfram Language code: TautologyQ[statement]

属性和关系  (5)

Exists 的否定给出 ForAll：

Wolfram Language code: !Exists[x, x == a]
Wolfram Language code: !Exists[x, Element[x, Reals], x == a]

可以用 Resolve 或 Reduce 去掉量词：

Wolfram Language code: form = Exists[{x, y}, x ≠ y && a x ^ 2 + b x + c == 0 && a y ^ 2 + b y + c == 0]

它消去量词：

Wolfram Language code: Resolve[form, Reals]

它消去量词，并且求解方程式和不等式：

Wolfram Language code: Reduce[form, {a, b, c}, Reals]

以下声明一个不等式方程组有解：

Wolfram Language code: ineqs = x ^ 2 + y ^ 2 < 2 && (x - 1) ^ 2 + (y - 1) ^ 2 < 2
Wolfram Language code: Resolve[Exists[{x, y}, ineqs], Reals]

用 FindInstance 求出一个特解：

Wolfram Language code: FindInstance[ineqs, {x, y}, Reals]

以下声明存在满足方程的一个复数 ：

Wolfram Language code: Exists[x, x ^ 2 + y ^ 2 + z ^ 2 == 1 && x y == z ^ 3]

用 Resolve 求出语句为真的 和 的条件：

Wolfram Language code: Resolve[%]

用 Eliminate 解决同样的问题：

Wolfram Language code: Eliminate[x ^ 2 + y ^ 2 + z ^ 2 == 1 && x y == z ^ 3, x]

它求出复代数集 沿 轴的投影：

Wolfram Language code: Reduce[Exists[y, x y == 1], x]

它求出沿 轴，实数单位圆的投影：

Wolfram Language code: Reduce[Exists[y, x ^ 2 + y ^ 2 ≤ 1], x, Reals]
Wolfram Research (2003)，Exists，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Exists.html.

文本

Wolfram Research (2003)，Exists，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Exists.html.

CMS

Wolfram 语言. 2003. "Exists." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Exists.html.

APA

Wolfram 语言. (2003). Exists. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Exists.html 年

BibTeX

@misc{reference.wolfram_2026_exists, author="Wolfram Research", title="{Exists}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/Exists.html}", note=[Accessed: 05-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_exists, organization={Wolfram Research}, title={Exists}, year={2003}, url={https://reference.wolfram.com/language/ref/Exists.html}, note=[Accessed: 05-September-2026]}