WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

n!

n の階乗を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
級数展開  
再帰恒等式と簡約  
関数表現  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Factorial

n!

n の階乗を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 整数ではない n については，Gamma[1+n]によって与えられる n!の数値的な値が与えられる．
  • 整数と半整数については，Factorialは，自動的に厳密値を計算する．
  • Factorialは任意の数値精度で評価できる．
  • Factorialは自動的にリストに縫い込まれる．
  • FactorialはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

  • Factorialは階乗関数を表す．具体的に言うと，Factorial[n]は与えられた数 の階乗 を返す．これは，正の整数については，と定義される．n1,2,…の最初のいくつかの値は1,2,6,24,120,720,…となる．特殊ケースの は1と定義される．この定義は，0個のオブジェクトを並べる方法は厳密に1通りであるという組合せ論の解釈と矛盾しない．一般的な複素数 については，z!=TemplateBox[{{z, +, 1}}, Gamma]となる．ここに含まれるGamma関数 TemplateBox[{z}, Gamma]は， が負の整数である場合（この場合の は複素無限大となる）を除く， のすべての複素値について，TemplateBox[{z}, Gamma]=int_0^inftyⅇ^(-t) t^(z-1)dt と定義される．半整数の階乗はの有理数倍で表される．
  • 階乗は，置換として知られる，リストの元の一定の順序への並べ替えを数える場合がよく知られている．置換はPermutationsで生成することができる．相異なる 個の元のリストには 通りの置換がある．これは，最初の元が置ける場所は 個，最初の元の場所が決まった後で2番目の元が置ける場所は 個，最初の2個の元の場所が決まった後で3番目の元が置ける場所は 個と言う具合にして，最後に残った場所に最後に残った元を置くまで続ける．これに従うと，の置換は 通りで，，，，，，となる．
  • より一般的に言うと，相異なる 個の元（ 番目の元は 個のコピーを持つ）の 個の多重集合（したがって，）の置換数は，Multinomialが与える多項係数に等しい．多項係数(n;n_1,...,n_(k))もまた， 個の元を，大きさが n1,…,nkのラベル付きの 個の部分集合に分割する方法を数える．これは，Binomialが与える二項係数TemplateBox[{n, m}, Binomial]と同じで， 元の集合の 元部分集合を数えると定義され，TemplateBox[{n, m}, Binomial]=(n;m,n-m)=(n!)/(m! (n-m)!)を満足する．
  • 階乗関数は，再帰関数 および を満足する．階乗関数は，スターリング(Stirling)の近似 が示すように，他のどの指数関数よりも急激に増大する．階乗は整数論とその解析の基本的な結果にも出現する．ウィルソン(Wilson)の定理には， が素数のときかつそのときに限りTemplateBox[{{{{(, {n, -, 1}, )}, !}, =, {-, 1}}, n}, Mod]，とある．が無限に微分可能なスカラー関数であれば，点 （Seriesで計算可）の周りのテイラー(Taylor)級数表現は で与えられる．指数関数 のテイラー級数でおよび と設定すると，E（自然対数の底）についての美しい恒等式 が与えられる．
  • Factorialと関連がある，あるいはこれの一般化である関数には，Factorial2，FactorialPower，TemplateBox[{Subfactorial, paclet:ref/Subfactorial}, RefLink, BaseStyle -> {InlineFormula}]，QFactorial，BarnesG，Pochhammerがある．

例題

すべて開く すべて閉じる

例  (6)

最初のいくつかの整数の階乗を計算する：

Wolfram Language code: Table[n!, {n, 10}]
Wolfram Language code: 25!

実数値で評価する：

Wolfram Language code: (1.5)!

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Factorial[x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Factorial[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[Factorial[x], {x, 0, 2}]//FullSimplify

Infinityにおける級数展開：

Wolfram Language code: Series[Factorial[x], {x, ∞, 2}]//FullSimplify//Normal

スコープ  (35)

数値評価  (6)

数値的に評価する：

Wolfram Language code: Factorial[4]
Wolfram Language code: Factorial[0]

高精度で評価する：

Wolfram Language code: N[Factorial[1 / 13], 10]

出力精度は入力精度に従う：

Wolfram Language code: Factorial[5.211111111111111111]

複素数入力：

Wolfram Language code: N[Factorial[2 + I]]

高精度で効率的に評価する：

Wolfram Language code: Factorial[13`100]//Timing
Wolfram Language code: Factorial[45`1000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Factorial[Interval[{2.1, 2.2}]]
Wolfram Language code: Factorial[CenteredInterval[4, 1 / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Factorial[Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: Factorial[{{1, 2}, {3, 4}}]

MatrixFunctionを使って行列のFactorial関数を計算することもできる：

Wolfram Language code: MatrixFunction[Factorial, {{1, 2}, {3, 4}}]//FullSimplify

特定の値  (5)

固定点におけるFactorialの値：

Wolfram Language code: Table[Factorial[x ], {x, 1, 4}]

0における値：

Wolfram Language code: Factorial[0]

大きい引数について評価する：

Wolfram Language code: 10000!//Short
Wolfram Language code: N[%]

半整数の引数について評価する：

Wolfram Language code: (1 / 2)!

Factorial[x]の正の最小値を求める：

Wolfram Language code: xmin = FindRoot[D[Factorial[x ], x] == 0, {x, 0.2}][[1, 2]]
Wolfram Language code: Plot[Factorial[x], {x, -2, 4}, Epilog -> Style[Point[{xmin, Factorial[xmin]}], PointSize[Large], Red]]

可視化  (2)

Factorial関数をプロットする：

Wolfram Language code: Plot[Factorial[x], {x, -5, 5}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Factorial[z]], {z, -1 - I, 1 + I}, Contours -> 20]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Factorial[z]], {z, -1 - I, 1 + I}, Contours -> 20]

関数の特性  (10)

階乗の実領域：

Wolfram Language code: FunctionDomain[Factorial[x], x]

複素領域：

Wolfram Language code: FunctionDomain[Factorial[z], z, Complexes]

Factorialは要素単位でリストに縫い込まれる：

Wolfram Language code: {2, 3, 5, 7, 11}!

階乗は鏡特性を持つ：

Wolfram Language code: FullSimplify[Factorial[Conjugate[z]] == Conjugate[Factorial[z]]]

Factorialは解析関数ではない：

Wolfram Language code: FunctionAnalytic[Factorial[z], z]

しかし，複素平面では有理型関数である：

Wolfram Language code: FunctionMeromorphic[Factorial[z], z]

Factorialは非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[{Factorial[z], z > -1}, z]

Factorialは単射ではない：

Wolfram Language code: FunctionInjective[Factorial[z], z]
Wolfram Language code: Plot[{Factorial[z], 1.2}, {z, -5, 5}]

Factorialは全射ではない：

Wolfram Language code: FunctionSurjective[Factorial[z], z]
Wolfram Language code: Plot[{Factorial[z], 0}, {z, -5, 5}]

Factorialは非負でも非正でもない：

Wolfram Language code: FunctionSign[Factorial[z], z]

Factorialは負の整数について特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[Factorial[z], z]
Wolfram Language code: FunctionDiscontinuities[Factorial[z], z]

Factorialは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Factorial[z], z]

微分  (2)

z についての導関数を求める：

Wolfram Language code: D[Factorial[z], z]

z についての高次導関数：

Wolfram Language code: Table[D[Factorial[z], {z, k}], {k, 1, 3}]//FullSimplify

z についての高次導関数をプロットする：

Wolfram Language code: Plot[%, {z, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

級数展開  (6)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[Factorial[x], {x, 0, 3}]// Normal// FullSimplify

の周りの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[Factorial[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{Factorial[x], terms}, {x, -5, 5}]

Infinityにおける級数展開（スターリング(Stirling)の近似）を求める：

Wolfram Language code: Series[Factorial[x], {x, Infinity, 1}]
Wolfram Language code: Simplify[Normal[%]]

における級数：

Wolfram Language code: Series[n!, {n, 1, 2}]

任意の記号方向 についての級数展開を求める：

Wolfram Language code: Series[Factorial[x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]// FullSimplify

特異点における級数展開：

Wolfram Language code: Series[Factorial[x], {x, -1, 2}, Assumptions -> x > 1]//FullSimplify

生成点におけるテイラー展開：

Wolfram Language code: Series[Factorial[x], {x, x0, 2}]// FullSimplify

再帰恒等式と簡約  (2)

漸化式：

Wolfram Language code: Factorial[n] == n Factorial[n - 1]//FullSimplify
Wolfram Language code: n! == ((n + 1)!/n + 1)//FullSimplify

正の整数(n-1)! = TemplateBox[{n}, Gamma]について：

Wolfram Language code: FunctionExpand[(n - 1)!, {Element[n, Integers] && n > 0}]

関数表現  (2)

階乗関数の積分表現：

Wolfram Language code: Integrate[t ^ n Exp[-t], {t, 0, Infinity}, Assumptions -> Re[n] > -1]

TraditionalFormによる表示：

Wolfram Language code: Factorial[z]//TraditionalForm

一般化と拡張  (4)

高精度で評価する：

Wolfram Language code: N[(22 / 10)!, 50]

出力精度は入力精度に従う：

Wolfram Language code: (2.20000000000000000000000)!

無限大の引数は記号的な結果を与える：

Wolfram Language code: Factorial[Infinity]
Wolfram Language code: Factorial[-Infinity]

Factorialは導関数を許容する：

Wolfram Language code: D[n!, n]

アプリケーション  (6)

半整数の階乗の表を作る：

Wolfram Language code: Table[(n - 1 / 2)!, {n, 10}]

6個の要素の順列の数：

Wolfram Language code: Length[Permutations[Range[6]]]
Wolfram Language code: 6!

複素平面におけるFactorialの絶対値のプロット：

Wolfram Language code: Plot3D[Abs[Factorial[x + I y]], {x, -5, 2}, {y, -1, 1}]

階乗の割合の漸近展開を求める：

Wolfram Language code: Series[(n + α)! / (n + β)!, {n, Infinity, 2}]//Simplify

n次元の単位超球の体積：

Wolfram Language code: Pi ^ (n / 2) / (n / 2)!

低次元の場合：

Wolfram Language code: Table[% r ^ n, {n, 1, 4}]

単位超球の体積を次元の関数としてプロットする：

Wolfram Language code: ListPlot[Table[%%, {n, 0, 25}]]

-∞における級数展開を求める：

Wolfram Language code: Series[n!, {n, -Infinity, 3}]
Wolfram Language code: Simplify[Normal[%]]

特性と関係  (9)

FullSimplifyを使ってFactorialを含む式を簡約する：

Wolfram Language code: FullSimplify[(n + 3)! / n!]

Factorialを含む母関数の総和を計算する：

Wolfram Language code: Sum[x ^ n / n!, {n, Infinity}]

Factorialを含む数値的な総和を計算する：

Wolfram Language code: Underoverscript[∑, k = 0, n]k!
Wolfram Language code: Underoverscript[∑, k = 1, n](k - 1/k!)

母関数は発散する：

Wolfram Language code: Sum[k! * x ^ k, {k, 0, Infinity}, Assumptions -> x != 0]

正規化を使って母関数の閉じた形を求める：

Wolfram Language code: Sum[k! x ^ k, {k, 0, Infinity}, Regularization -> "Borel"]
Wolfram Language code: Series[%, {x, 0, 12}]

母関数を形式的ベキ級数とみなす：

Wolfram Language code: Series[HypergeometricPFQ[{1, 1}, {}, x], {x, 0, 12}]

いくつかの積分が可能である：

Wolfram Language code: Integrate[Log[n!], {n, 0, 1}]

階乗関数の積：

Wolfram Language code: Product[(3k + 1)!, {k, n}]
Wolfram Language code: Round[% /. n -> 10]
Wolfram Language code: Product[(3k + 1)!, {k, 10}]

FactorialはDifferenceRootとして表すことができる：

Wolfram Language code: DifferenceRootReduce[Factorial[k], k]

FindSequenceFunctionはFactorial数列を認識する：

Wolfram Language code: Table[Factorial[n], {n, 10}]
Wolfram Language code: FindSequenceFunction[%, n]

Factorialの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[Factorial[n], n, x]

考えられる問題  (2)

大きい引数は，たとえ近似的にでも明示的に計算するのには大きすぎる結果を与えることがある：

Wolfram Language code: (10 ^ 16.)!

値を小さくするとちゃんと動く：

Wolfram Language code: (10. ^ 6)!

機械数の入力で高精度の結果が得られることがある：

Wolfram Language code: Factorial[10. ^ 3]
Wolfram Language code: MachineNumberQ[%]

おもしろい例題  (3)

大きな階乗の各桁を計算し，そのヒストグラムを作成する：

Wolfram Language code: DigitCount[100000!]
Wolfram Language code: Histogram[IntegerDigits[100000!]]

複素平面におけるネストした階乗：

Wolfram Language code: DensityPlot[Arg[Nest[Factorial, x + I y, 3]], {x, -1, -0.65}, {y, -0.2, 0.2}]

Factorialを無限大でプロットする：

Wolfram Language code: DensityPlot[Arg[Factorial[1 / (x + I y)]], {x, -0.4, 0.4}, {y, -0.4, 0.4}]
Wolfram Research (1988), Factorial, Wolfram言語関数， https://reference.wolfram.com/language/ref/Factorial.html （2022年に更新）.

テキスト

Wolfram Research (1988), Factorial, Wolfram言語関数， https://reference.wolfram.com/language/ref/Factorial.html （2022年に更新）.

CMS

Wolfram Language. 1988. "Factorial." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/Factorial.html.

APA

Wolfram Language. (1988). Factorial. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Factorial.html

BibTeX

@misc{reference.wolfram_2026_factorial, author="Wolfram Research", title="{Factorial}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/Factorial.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_factorial, organization={Wolfram Research}, title={Factorial}, year={2022}, url={https://reference.wolfram.com/language/ref/Factorial.html}, note=[Accessed: 07-September-2026]}