Wolfram 语言与系统参考资料中心

Factorial

给出 n 的阶乘.

背景

Factorial 表示阶乘函数. 具体来讲，Factorial[n] 返回给定数字的阶乘，对于正整数，其定义为 . 对于 n1,2,…，前几个值为 1,2,6,24,120,720,…. 特殊情况被定义为 1，与排列组合的解释一致，正好只有一种排列零个对象的方法. 对于一般复数，，其中 Gamma 函数的定义为 $TemplateBox[{z}, Gamma]=int_0^inftyⅇ^(-t) t^(z-1)dt$ ，该定义对所有复数成立，除了是负整数的情况（这时为负无穷）. 半整数的阶乘由的有理倍数给出.
最为大家熟知的是阶乘可以计算列表元素固定排序的数量，称为置换，可用 Permutations 生成. 对于由个（不同的）元素组成的列表，有种置换，原因是有个位置可以放置第一个元素，第一个元素放好后，有个位置可以放置第二个元素，前两个元素放好后，有个位置可以放置第三个元素，以此类推，直到只剩下一个位置，可以放置最后一个元素. 因此对于，有种置换，即、、、、和 .
更广泛地说，对于个元素的多重集合 (multiset), 其中有个不同的元素，第个不同的元素有份拷贝（因此），置换的数量等于由 Multinomial 给出的多项式系数 . 多项式系数也可以计算将个元素的集合划分成个有标签的、大小为 n₁,…,n_k 的子集的方法的数量. 因此由 Binomial 给出的二项式系数被定义为计算个元素组成的集合的个元素的子集的数量，它满足 .
阶乘函数满足循环关系式和 . 它比所有指数函数增长得都快，从 Stirling 逼近可以看出. 阶乘也出现在数论和分析的基本结果中. Wilson 定理指出，当且仅当为质数时. 如果是一个无限可微的标量函数，则其关于点（可用 Series 算出）的泰勒级数表示由给出. 在指数函数的泰勒级数中设置和给出了完美的 E（自然对数的底数）的恒等式 .
其他与 Factorial 有关的函数或拓展 Factorial 的函数包括 Factorial2、 FactorialPower、、QFactorial、BarnesG 和 Pochhammer.

范例

打开所有单元关闭所有单元

基本范例 (6)

计算前几个整数的阶乘：

Wolfram Language code: Table[n!, {n, 10}]

Wolfram Language code: 25!

在实数上进行计算：

Wolfram Language code: (1.5)!

在实数的子集上绘图：

Wolfram Language code: Plot[Factorial[x], {x, -5, 5}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[Factorial[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[Factorial[x], {x, 0, 2}]//FullSimplify

在 Infinity 的级数展开：

Wolfram Language code: Series[Factorial[x], {x, ∞, 2}]//FullSimplify//Normal

范围 (35)

数值计算 (6)

数值运算：

Wolfram Language code: Factorial[4]

Wolfram Language code: Factorial[0]

高精度计算：

Wolfram Language code: N[Factorial[1 / 13], 10]

输出精度与输入精度一致：

Wolfram Language code: Factorial[5.211111111111111111]

复数输入：

Wolfram Language code: N[Factorial[2 + I]]

高精度的高效计算：

Wolfram Language code: Factorial[13`100]//Timing

Wolfram Language code: Factorial[45`1000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: Factorial[Interval[{2.1, 2.2}]]

Wolfram Language code: Factorial[CenteredInterval[4, 1 / 100]]

或用 Around 计算普通的统计区间：

Wolfram Language code: Factorial[Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: Factorial[{{1, 2}, {3, 4}}]

或者用 MatrixFunction 计算矩阵形式的 Factorial 函数：:

Wolfram Language code: MatrixFunction[Factorial, {{1, 2}, {3, 4}}]//FullSimplify

特殊值 (5)

固定点的 Factorial 值：

Wolfram Language code: Table[Factorial[x ], {x, 1, 4}]

零处的值：

Wolfram Language code: Factorial[0]

参数较大的计算：

Wolfram Language code: 10000!//Short

Wolfram Language code: N[%]

半整数参数计算：

Wolfram Language code: (1 / 2)!

求 Factorial[x] 的正的最小值：

Wolfram Language code: xmin = FindRoot[D[Factorial[x ], x] == 0, {x, 0.2}][[1, 2]]

Wolfram Language code: Plot[Factorial[x], {x, -2, 4}, Epilog -> Style[Point[{xmin, Factorial[xmin]}], PointSize[Large], Red]]

可视化 (2)

绘制 Factorial 函数：

Wolfram Language code: Plot[Factorial[x], {x, -5, 5}]

绘制实部：

Wolfram Language code: ComplexContourPlot[Re[Factorial[z]], {z, -1 - I, 1 + I}, Contours -> 20]

绘制虚部：

Wolfram Language code: ComplexContourPlot[Im[Factorial[z]], {z, -1 - I, 1 + I}, Contours -> 20]

函数属性 (10)

阶乘的实数定义域：

Wolfram Language code: FunctionDomain[Factorial[x], x]

复数定义域：

Wolfram Language code: FunctionDomain[Factorial[z], z, Complexes]

Factorial 逐个作用于列表的每个元素：

Wolfram Language code: {2, 3, 5, 7, 11}!

阶乘具有镜像属性：

Wolfram Language code: FullSimplify[Factorial[Conjugate[z]] == Conjugate[Factorial[z]]]

Factorial 不是解析函数：

Wolfram Language code: FunctionAnalytic[Factorial[z], z]

然而，它是复平面上的亚纯函数：

Wolfram Language code: FunctionMeromorphic[Factorial[z], z]

Factorial 既不是非递减也不是非递增：

Wolfram Language code: FunctionMonotonicity[{Factorial[z], z > -1}, z]

Factorial 不是单射函数：

Wolfram Language code: FunctionInjective[Factorial[z], z]

Wolfram Language code: Plot[{Factorial[z], 1.2}, {z, -5, 5}]

Factorial 不是满射函数：

Wolfram Language code: FunctionSurjective[Factorial[z], z]

Wolfram Language code: Plot[{Factorial[z], 0}, {z, -5, 5}]

Factorial 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[Factorial[z], z]

Factorial 对负整数同时具有奇异性和不连续性：

Wolfram Language code: FunctionSingularities[Factorial[z], z]

Wolfram Language code: FunctionDiscontinuities[Factorial[z], z]

Factorial 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[Factorial[z], z]

微分 (2)

关于 z 的一阶导数：

Wolfram Language code: D[Factorial[z], z]

关于 z 的高阶导数：

Wolfram Language code: Table[D[Factorial[z], {z, k}], {k, 1, 3}]//FullSimplify

绘制关于 z 的高阶导数：

Wolfram Language code: Plot[%, {z, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

级数展开 (6)

使用 Series 求泰勒展开：

Wolfram Language code: Series[Factorial[x], {x, 0, 3}]// Normal// FullSimplify

绘制附近的前三个近似：

Wolfram Language code:

terms = Normal@Table[Series[Factorial[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{Factorial[x], terms}, {x, -5, 5}]

求 Infinity 处的级数展开式（斯特灵近似）：

Wolfram Language code: Series[Factorial[x], {x, Infinity, 1}]

Wolfram Language code: Simplify[Normal[%]]

在处的级数：

Wolfram Language code: Series[n!, {n, 1, 2}]

求任意符号方向上的级数展开式：

Wolfram Language code: Series[Factorial[x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]// FullSimplify

在奇点处的级数展开式：

Wolfram Language code: Series[Factorial[x], {x, -1, 2}, Assumptions -> x > 1]//FullSimplify

普通点的泰勒展开：

Wolfram Language code: Series[Factorial[x], {x, x0, 2}]// FullSimplify

递推恒等式和化简 (2)

递推关系式：

Wolfram Language code: Factorial[n] == n Factorial[n - 1]//FullSimplify

Wolfram Language code: n! == ((n + 1)!/n + 1)//FullSimplify

对于正整数，：

Wolfram Language code: FunctionExpand[(n - 1)!, {Element[n, Integers] && n > 0}]

函数表示 (2)

阶乘函数的积分表示：

Wolfram Language code: Integrate[t ^ n Exp[-t], {t, 0, Infinity}, Assumptions -> Re[n] > -1]

TraditionalForm 格式：

Wolfram Language code: Factorial[z]//TraditionalForm

推广和延伸 (4)

高精度计算：

Wolfram Language code: N[(22 / 10)!, 50]

输出精度与输入精度相一致：

Wolfram Language code: (2.20000000000000000000000)!

无穷参数给出符号结果：

Wolfram Language code: Factorial[Infinity]

Wolfram Language code: Factorial[-Infinity]

Factorial 允许求导：

Wolfram Language code: D[n!, n]

应用 (6)

制作半整数阶乘表：

Wolfram Language code: Table[(n - 1 / 2)!, {n, 10}]

6 个元素的排列数：

Wolfram Language code: Length[Permutations[Range[6]]]

Wolfram Language code: 6!

在复平面上绘制 Factorial 的绝对值：

Wolfram Language code: Plot3D[Abs[Factorial[x + I y]], {x, -5, 2}, {y, -1, 1}]

求阶乘比率的渐近展开：

Wolfram Language code: Series[(n + α)! / (n + β)!, {n, Infinity, 2}]//Simplify

n 维单位超球的体积：

Wolfram Language code: Pi ^ (n / 2) / (n / 2)!

低维的情形：

Wolfram Language code: Table[% r ^ n, {n, 1, 4}]

绘制单位超球的体积，作为维数的函数：

Wolfram Language code: ListPlot[Table[%%, {n, 0, 25}]]

求 -∞ 处的级数展开：

Wolfram Language code: Series[n!, {n, -Infinity, 3}]

Wolfram Language code: Simplify[Normal[%]]

属性和关系 (9)

用 FullSimplify 来化简包含 Factorial 的表达式：

Wolfram Language code: FullSimplify[(n + 3)! / n!]

计算涉及 Factorial 生成函数的和：

Wolfram Language code: Sum[x ^ n / n!, {n, Infinity}]

计算涉及 Factorial 的数值和：

Wolfram Language code: Underoverscript[∑, k = 0, n]k!

Wolfram Language code: Underoverscript[∑, k = 1, n](k - 1/k!)

生成函数是发散的：

Wolfram Language code: Sum[k! * x ^ k, {k, 0, Infinity}, Assumptions -> x != 0]

使用正规化以获得一个生成函数的解析形式：

Wolfram Language code: Sum[k! x ^ k, {k, 0, Infinity}, Regularization -> "Borel"]

Wolfram Language code: Series[%, {x, 0, 12}]

将生成函数当作是形式幂级数：

Wolfram Language code: Series[HypergeometricPFQ[{1, 1}, {}, x], {x, 0, 12}]

可以实现某些积分：

Wolfram Language code: Integrate[Log[n!], {n, 0, 1}]

阶乘的连乘积：

Wolfram Language code: Product[(3k + 1)!, {k, n}]

Wolfram Language code: Round[% /. n -> 10]

Wolfram Language code: Product[(3k + 1)!, {k, 10}]

Factorial 可被表示为 DifferenceRoot：

Wolfram Language code: DifferenceRootReduce[Factorial[k], k]

FindSequenceFunction 可以识别 Factorial 序列：

Wolfram Language code: Table[Factorial[n], {n, 10}]

Wolfram Language code: FindSequenceFunction[%, n]

Factorial 的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[Factorial[n], n, x]

可能存在的问题 (2)

过大的参数导致结果太大，以致不能直接计算，甚至近似计算：

Wolfram Language code: (10 ^ 16.)!

较小的值可以计算：

Wolfram Language code: (10. ^ 6)!

机器数输入可以给出高精度结果：

Wolfram Language code: Factorial[10. ^ 3]

Wolfram Language code: MachineNumberQ[%]

巧妙范例 (3)

计算并获取一个大数的阶乘中各个数字的直方图：

Wolfram Language code: DigitCount[100000!]

Wolfram Language code: Histogram[IntegerDigits[100000!]]

复平面内的嵌套阶乘：

Wolfram Language code: DensityPlot[Arg[Nest[Factorial, x + I y, 3]], {x, -1, -0.65}, {y, -0.2, 0.2}]

在无穷大处绘制 Factorial：

Wolfram Language code: DensityPlot[Arg[Factorial[1 / (x + I y)]], {x, -0.4, 0.4}, {y, -0.4, 0.4}]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Factorial

更多信息

背景

范例

基本范例 (6)

范围 (35)

数值计算 (6)

特殊值 (5)

可视化 (2)

函数属性 (10)

微分 (2)

级数展开 (6)

递推恒等式和化简 (2)

函数表示 (2)

推广和延伸 (4)

应用 (6)

属性和关系 (9)

可能存在的问题 (2)

巧妙范例 (3)

文本

CMS

APA

BibTeX

BibLaTeX

Factorial

更多信息

背景

范例

基本范例 (6)

范围 (35)

数值计算 (6)

特殊值 (5)

可视化 (2)

函数属性 (10)

微分 (2)

级数展开 (6)

递推恒等式和化简 (2)

函数表示 (2)

推广和延伸 (4)

应用 (6)

属性和关系 (9)

可能存在的问题 (2)

巧妙范例 (3)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX