Wolfram 语言与系统参考资料中心

FindArgMax

FindArgMax[f,x]

给出 f 的一个局部最大值的坐标 x_max.

FindArgMax[f,{x,x₀}]

给出 f 的一个局部最大值的坐标 x_max，通过从点 x=x₀ 开始搜索求出.

FindArgMax[f,{{x,x₀},{y,y₀},…}]

给出多元函数的一个局部最大值的坐标 {x_max,y_max,…}.

FindArgMax[{f,cons},{{x,x₀},{y,y₀},…}]

给出约束 cons 下的一个局部最大值的坐标.

FindArgMax[{f,cons},{x,y,…}]

在约束定义的区域内的一个点开始.

FindArgMax

FindArgMax[f,x]

给出 f 的一个局部最大值的坐标 x_max.

FindArgMax[f,{x,x₀}]

给出 f 的一个局部最大值的坐标 x_max，通过从点 x=x₀ 开始搜索求出.

FindArgMax[f,{{x,x₀},{y,y₀},…}]

给出多元函数的一个局部最大值的坐标 {x_max,y_max,…}.

FindArgMax[{f,cons},{{x,x₀},{y,y₀},…}]

给出约束 cons 下的一个局部最大值的坐标.

FindArgMax[{f,cons},{x,y,…}]

在约束定义的区域内的一个点开始.

范例

打开所有单元关闭所有单元

基本范例 (4)

求出点 {x}，在该点一元函数 -2x^2-3x+5 有一个最大值：

Wolfram Language code: FindArgMax[-2x ^ 2 - 3x + 5, x]

求出点 {x,y}，在该点函数 Sin[x]Sin[2y] 有一个最大值：

Wolfram Language code: FindArgMax[Sin[x]Sin[2y], {x, y}]

求出约束下函数在一个点有一个最大值：

Wolfram Language code: FindArgMax[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

在一个几何区域上，求函数的最大值所在的点：

Wolfram Language code: FindArgMax[{x + y, {x, y}∈Disk[]}, {x, y}]

绘制图线：

Wolfram Language code: Show[ContourPlot[x + y, {x, y}∈Disk[]], Graphics[{Red, PointSize[Large], Point[%]}]]

范围 (12)

在不同起点下，得到不同局部最大值的坐标：

Wolfram Language code: FindArgMax[x Cos[x], {x, 5}]

Wolfram Language code: FindArgMax[x Cos[x], {x, 10}]

从 x=2、y=2 点开始，二元变量函数的一个局部最大值的坐标：

Wolfram Language code: FindArgMax[Sin[x]Sin[2y], {{x, 2}, {y, 2}}]

约束在一个圆内的一个局部最大值的坐标：

Wolfram Language code: FindArgMax[{Sin[x]Sin[2y], x ^ 2 + y ^ 2 < 3}, {{x, 2}, {y, 2}}]

不提供起点：

Wolfram Language code: FindArgMax[{Sin[x]Sin[2y], x ^ 2 + y ^ 2 < 3}, {x, y}]

对于线性对象和约束条件，可以加上整数约束条件：

Wolfram Language code: FindArgMax[{-x - y, 3x + 2y ≥ 7 && x ≥ 0 && y ≥ 0}, {x, y}]

Wolfram Language code: FindArgMax[{-x - y, 3x + 2y ≥ 7 && x ≥ 0 && y ≥ 0 && x∈Integers}, {x, y}]

可以指定 Or 约束：

Wolfram Language code: FindArgMax[{x + y, x ^ 2 + y ^ 2 ≤ 1 || (x + 2) ^ 2 + (y + 2) ^ 2 ≤ 1}, {x, y}]

求一个范围内的最大值：

Wolfram Language code: ℛ = Cylinder[{{-1, 0, 1}, {1, 0, -1}}, 1];

Wolfram Language code: FindArgMax[{z, {x, y, z}∈ℛ}, {x, y, z}]

绘制图线：

Wolfram Language code: Graphics3D[{{Opacity[0.5], Green, ℛ}, {Red, PointSize[Large], Point[%]}}]

求实现两个区域直接最大距离的点：

Wolfram Language code:

Subscript[ℛ, 1] = Disk[];
Subscript[ℛ, 2] = Line[{{-(1/2), -(1/2)}, {-(1/2), (1/2)}, {(1/2), (1/2)}, {(1/2), -(1/2)}, {-(1/2), -(1/2)}}];

Wolfram Language code: FindArgMax[{(x - u)^2 + (y - v)^2, {{x, y}∈Subscript[ℛ, 1], {u, v}∈Subscript[ℛ, 2]}}, {x, y, u, v}]

绘制图线：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[Partition[%, 2]]}}]

求的最大值，以使得矩形和椭圆仍然相交：

Wolfram Language code:

Subscript[ℛ, 1] = Rectangle[];
Subscript[ℛ, 2] = Circle[{(1/3), (1/3)}, {2 r, r}];

Wolfram Language code: FindArgMax[{r, {x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2]}, {r, x, y}]

绘制图线：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. Thread[{r, x, y} -> %]]

求的最大值，以使得包含给定的三个点：

Wolfram Language code: Subscript[ℛ, 3] = Disk[{a, b}, {r, 2 - r}];

Wolfram Language code: FindArgMax[{r, ({0, 0} | {1, 0} | {0, 1})∈Subscript[ℛ, 3]}, {a, b, r}]

绘制图线：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 3]} /. Thread[{a, b, r} -> %], {Red, Point[{{0, 0}, {1, 0}, {0, 1}}]}}]

使用指定是中的一个向量：

Wolfram Language code: ℛ = Sphere[];

Wolfram Language code: FindArgMax[{x.{1, 2, 3}, x∈ℛ}, x]

求实现两个区域直接最大距离的点：

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Disk[{2, 2}, 1];

Wolfram Language code: FindArgMax[{EuclideanDistance[x, y], {x∈Subscript[ℛ, 1], y∈Subscript[ℛ, 2]}}, {x, y}]

绘制图线：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Red, Point[%]}}]

选项 (7)

AccuracyGoal 和 PrecisionGoal (2)

下面指定收敛规则 $TemplateBox[{{{x, _, k}, -, {x, ^, *}}}, Norm]<=max(10^(-9),10^(-8)TemplateBox[{{x, _, k}}, Norm])$ 和 $TemplateBox[{{del , {f, (, {x, _, k}, )}}}, Norm]<=10^(-9)$ :

Wolfram Language code: FindArgMax[Sin[x / 2], {x, 1}, AccuracyGoal -> 9, PrecisionGoal -> 8]

下面指定收敛规则 $TemplateBox[{{{x, _, k}, -, {x, ^, *}}}, Norm]<=max(10^(-20),10^(-18)TemplateBox[{{x, _, k}}, Norm])$ 和 $TemplateBox[{{del , {f, (, {x, _, k}, )}}}, Norm]<=10^(-20)$ :

Wolfram Language code: FindArgMax[Sin[x / 2], {x, 1}, AccuracyGoal -> 20, PrecisionGoal -> 18]

提高 WorkingPrecision，将使得过程收敛：

Wolfram Language code: FindArgMax[Sin[x / 2], {x, 1}, AccuracyGoal -> 20, PrecisionGoal -> 18, WorkingPrecision -> 40]

EvaluationMonitor (1)

绘制收敛于局部最大值：

Wolfram Language code: ListPlot[Last[Reap[FindArgMax[x Cos[x], {x, 5}, EvaluationMonitor :> Sow[x]]]]]

Gradient (1)

下面用给定梯度，自动计算 Hessian：

Wolfram Language code: FindArgMax[Sin[x]Sin[2 y], {x, y}, Gradient -> {Cos[x] Sin[2 y], 2 Cos[2 y] Sin[x]}, Method -> "Newton"]

下面用提供的梯度和 Hessian：

Wolfram Language code:

FindArgMax[Sin[x]Sin[2y], {x, y}, Gradient -> {Cos[x] Sin[2 y], 2 Cos[2 y] Sin[x]}, Method -> {"Newton", Hessian -> {{-Sin[x] Sin[2 y], 2 Cos[x] Cos[2 y]}, {2 Cos[x] Cos[2 y], -4 Sin[x] Sin[2 y]}}}]

Method (1)

在这个例子中，用默认的基于导数的方式会有困难：

Wolfram Language code: FindArgMax[-RealAbs[x + 1] - RealAbs[x + 1.01] - RealAbs[y + 1], {x, y}]

Wolfram Language code: FindArgMax[-RealAbs[x + 1] - RealAbs[x + 1.01] - RealAbs[y + 1], {x, y}, Method -> "ConjugateGradient"]

在这些例子中，不需要导数的直接搜索方式会有帮助：

Wolfram Language code: FindArgMax[-RealAbs[x + 1] - RealAbs[x + 1.01] - RealAbs[y + 1], {x, y}, Method -> "PrincipalAxis"]

NMaximize 也可以使用直接搜索方式的范围：

Wolfram Language code: NMaximize[{-RealAbs[x + 1] - RealAbs[x + 1.01] - RealAbs[y + 1]}, {x, y}]

StepMonitor (1)

在求函数的最大值过程中，FindArgMax 采用的步长：

Wolfram Language code:

pts = Reap[FindArgMax[-(1 - x) ^ 2 - 100(-x ^ 2 - y) ^ 2 - 1, {{x, -1.2}, {y, 1}}, StepMonitor :> Sow[{x, y}]]][[2, 1]];
pts  = Join[{{-1.2, 1}}, pts];

Wolfram Language code:

ContourPlot[-(1 - x) ^ 2 - 100(-x ^ 2 - y) ^ 2 - 1//Minus//Log, {x, -1.3, 1.5}, {y, -1.5, 1.4}, Epilog -> {Red, Line[pts], Point[pts]}]

WorkingPrecision (1)

设置工作精度为；默认情况下 AccuracyGoal 和 PrecisionGoal 设置为：

Wolfram Language code: FindArgMax[Cos[x ^ 2 - 3 y] + Sin[x ^ 2 + y ^ 2], {x, y}, Method -> "Newton", WorkingPrecision -> 20]

属性和关系 (1)

FindMaximum 给出最大点和最小点的值：

Wolfram Language code: FindMaximum[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

FindArgMax 给出最大值的坐标：

Wolfram Language code: FindArgMax[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

FindMaxValue 给出最大点的值：

Wolfram Language code: FindMaxValue[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

可能存在的问题 (4)

如果限定区域为空，算法不会收敛：

Wolfram Language code: FindArgMax[{x + y, x ^ 2 + y ^ 2 ≥ 2 && x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

如果最大值不是有限的，算法不会收敛：

Wolfram Language code: FindArgMax[Tan[x], {x, 2}]

Wolfram Language code: FindArgMax[{x ^ 2 + y ^ 2, x ^ 2 + y ^ 2 > 10}, {x, y}]

整数的线性程序算法仅对机器数问题有效：

Wolfram Language code: FindArgMax[{-x - y, x + 2y ≥ 3 && x > 1 && y > 1 && x∈Integers}, {x, y}, WorkingPrecision -> 20]

某些时候提供一个适当的初始值，对收敛算法会有帮助：

Wolfram Language code: FindArgMax[-x * Sin[1 / x] ^ 2, {x}]

Wolfram Language code: FindArgMax[-x * Sin[1 / x] ^ 2, {x, .3}]

Top

	lhs==rhs	方程
	lhs>rhs 或者 lhs>=rhs	不等式
	{x,y,…}∈reg	范围指定

AccuracyGoal	Automatic	精确查询
EvaluationMonitor	None	当计算 f 值时，运行的表达式
Gradient	Automatic	梯度函数列表 {D[f,x],D[f,y],…}
MaxIterations	Automatic	使用迭代的最大数
Method	Automatic	使用的方法
PrecisionGoal	Automatic	查询的精度
StepMonitor	None	对表达式求值时采取的步长
WorkingPrecision	MachinePrecision	内部计算中的精度

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

FindArgMax

更多信息和选项

所有选项的列表

范例

基本范例 (4)

范围 (12)

选项 (7)

AccuracyGoal 和 PrecisionGoal (2)

EvaluationMonitor (1)

Gradient (1)

Method (1)

StepMonitor (1)

WorkingPrecision (1)

属性和关系 (1)

可能存在的问题 (4)

文本

CMS

APA

BibTeX

BibLaTeX

FindArgMax

更多信息和选项

所有选项的列表

范例

基本范例 (4)

范围 (12)

选项 (7)

AccuracyGoal 和 PrecisionGoal (2)

EvaluationMonitor (1)

Gradient (1)

Method (1)

StepMonitor (1)

WorkingPrecision (1)

属性和关系 (1)

可能存在的问题 (4)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX