WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Flatten[list]

ネストしたリストを平坦化する．

Flatten[list,n]

レベル n までを平坦化する．

Flatten[list,n,h]

頭部 h を持つ部分式を平坦化する．

Flatten[list,{{s11,s12,…},{s21,s22,…},…}]

結果的に各レベル i になるように全レベル sijを結合することで list を平坦化する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
レベル指定  
入力配列  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Flatten

Flatten[list]

ネストしたリストを平坦化する．

Flatten[list,n]

レベル n までを平坦化する．

Flatten[list,n,h]

頭部 h を持つ部分式を平坦化する．

Flatten[list,{{s11,s12,…},{s21,s22,…},…}]

結果的に各レベル i になるように全レベル sijを結合することで list を平坦化する．

詳細

  • Flattenは，内側のカッコを削除することでリストを「解く」．
  • Flatten[list,n]は，実質的にリスト list の最上レベルを n 回平坦にする．
  • Flatten[f[e,…]]は，頭部が f の部分式を平坦にする．
  • mijが行列のとき，Flatten[{{m11,m12},{m21,m22}},{{1,3},{2,4}}]は，実質的に「ブロック」mijから単一の行列を構築する．
  • Flatten[list,{{i1},{i2},…}]は，list 中のレベル ikが結果ではレベル k になるように，実質的に list 中のレベルを入れ換える．関数Transposeは実際のところ，この指定方法の逆を使用していることに注意のこと．
  • FlattenはSparseArrayオブジェクトのレベルを，対応する通常の配列におけるのと同じように平坦化する． »

例題

すべて開く すべて閉じる

例  (3)

リストをすべてのレベルで平坦化する：

Wolfram Language code: Flatten[{{a, b}, {c, {d}, e}, {f, {g, h}}}]

レベル1でだけ平坦化する：

Wolfram Language code: Flatten[{{a, b}, {c, {d}, e}, {f, {g, h}}}, 1]

深さ3の配列のレベル2と3を結果の行列のレベル1に平坦化する：

Wolfram Language code: Flatten[RandomReal[1, {3, 5, 7}], {{2, 3}, {1}}]//Dimensions

スコープ  (10)

レベル指定  (6)

平坦化は行わない：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 0]

レベル1まで平坦化：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 1]

レベル2まで平坦化：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 2]

レベル3まで平坦化：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 3]

レベル4まで平坦化：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 4]

次はレベルを使ったのと同じである：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, ∞]

また，レベル指定を行わないのと同じである：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}]

ここに行列がある：

Wolfram Language code: u = {{a, b}, {c, d}}

u型のブロックの配列を1つの行列に平坦化する：

Wolfram Language code: Flatten[{{u, 0 u}, {0 u, u}}, {{1, 3}, {2, 4}}]//MatrixForm

ブロックの転置を使って実質的に1つの行列に平坦化する：

Wolfram Language code: Flatten[{{u, 0 u}, {0 u, u}}, {{1, 4}, {2, 3}}]//MatrixForm

入力配列  (4)

疎な配列を平坦化する：

Wolfram Language code: Flatten[SparseArray[{{1, 2} -> a, {6, 4} -> b}]]
Wolfram Language code: Normal[%]

QuantityArrayオブジェクトを平坦化する：

Wolfram Language code: Flatten[QuantityArray[{{1, 2}, {3, 4}, {5, 6}}, "Knots"]]
Wolfram Language code: Normal[%]

Flattenは任意の頭部に使うことができる：

Wolfram Language code: Flatten[f[f[x, y], z]]

すべてのレベルをgについて平坦化する：

Wolfram Language code: Flatten[f[g[u, v], f[x, y]], Infinity, g]

すべてのレベルをfについて平坦化する：

Wolfram Language code: Flatten[f[g[u, v], f[x, y]], Infinity, f]

アプリケーション  (5)

リストと個々の要素を統合する：

Wolfram Language code: Range[5]
Wolfram Language code: Flatten[{%, x, %, %, y}]

行列を解体する：

Wolfram Language code: Table[i ^ j, {i, 3}, {j, 4}]
Wolfram Language code: Flatten[%]

規則の平坦化したリストを作る：

Wolfram Language code: Table[i -> j, {i, 4}, {j, 3}]
Wolfram Language code: Flatten[%]

不揃いの配列に「転置」を行う：

Wolfram Language code: list = Table[i + j - 1, {i, 4}, {j, i}]
Wolfram Language code: Flatten[list, {{2}, {1}}]

まず平坦化することで，配列の3つのレベルを単一のDot操作に簡約する：

Wolfram Language code: array = RandomInteger[10, {2, 5, 6, 4}];
Wolfram Language code: Flatten[array, {{1}, {2, 3, 4}}].Flatten[array, {{2, 3, 4}, {1}}]

レベルの3つのペアを明示的に簡約することで同じ結果を得る：

Wolfram Language code: TensorContract[TensorProduct[array, array], {{2, 6}, {3, 7}, {4, 8}}]

特性と関係  (5)

FlattenはPartitionと逆の働きをする：

Wolfram Language code: Range[20]
Wolfram Language code: Partition[%, 4]
Wolfram Language code: Flatten[%]

ArrayReshapeは矩形配列に対してはFlattenと逆の働きをする：

Wolfram Language code: array = RandomInteger[9, {3, 2, 4}]
Wolfram Language code: Flatten[array]
Wolfram Language code: ArrayReshape[%, {3, 2, 4}]

矩形配列 a については，ArrayFlatten[a,r]はFlatten[a,{{1,r+1},{2,r+2},…,{r,2r}}]に等しい：

Wolfram Language code: array = RandomInteger[10, {2, 3, 4, 5, 6, 7, 8}];
Wolfram Language code: ArrayFlatten[array, 3] === Flatten[array, {{1, 4}, {2, 5}, {3, 6}}]

Flattenは実質的に要素をその指標の辞書的順序に並べる：

Wolfram Language code: Flatten[Array[a, {3, 4}]]
Wolfram Language code: Flatten[Array[100#1 + 10#2 + #3&, {3, 3, 3}]]

置換 p とその逆の について，Flatten[a,List/@p-1]==Transpose[a,p]である：

Wolfram Language code: list = Array[Subscript[a, ##]&, {2, 3, 4, 2}];

ランダムな置換：

Wolfram Language code: p = RandomSample[Range[4]]

その逆を得る：

Wolfram Language code: invp = InversePermutation[p]
Wolfram Language code: Flatten[list, List /@ invp] == Transpose[list, p]

おもしろい例題  (1)

Framedの連続するレイヤーを剥ぎ取る：

Wolfram Language code: NestList[Flatten[#, 1]&, Nest[Framed, x, 6], 10]
Wolfram Research (1988), Flatten, Wolfram言語関数， https://reference.wolfram.com/language/ref/Flatten.html （2007年に更新）.

テキスト

Wolfram Research (1988), Flatten, Wolfram言語関数， https://reference.wolfram.com/language/ref/Flatten.html （2007年に更新）.

CMS

Wolfram Language. 1988. "Flatten." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/Flatten.html.

APA

Wolfram Language. (1988). Flatten. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Flatten.html

BibTeX

@misc{reference.wolfram_2026_flatten, author="Wolfram Research", title="{Flatten}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Flatten.html}", note=[Accessed: 15-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_flatten, organization={Wolfram Research}, title={Flatten}, year={2007}, url={https://reference.wolfram.com/language/ref/Flatten.html}, note=[Accessed: 15-October-2026]}