WOLFRAM

Wolfram 语言与系统参考资料中心

Flatten[list]

压平嵌套列表.

Flatten[list,n]

压平 n 层结构.

Flatten[list,n,h]

压平头部为 h 的子表达式.

Flatten[list,{{s11,s12,…},{s21,s22,…},…}]

通过组合所有级别 sij 压平 list 使每个级别 i 都在结果中.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
层次规范  
输入数组  
应用  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Flatten

Flatten[list]

压平嵌套列表.

Flatten[list,n]

压平 n 层结构.

Flatten[list,n,h]

压平头部为 h 的子表达式.

Flatten[list,{{s11,s12,…},{s21,s22,…},…}]

通过组合所有级别 sij 压平 list 使每个级别 i 都在结果中.

更多信息

  • Flatten 有效地删除内部括号，拆开列表.
  • Flatten[list,n] 有效地压平 list 中的顶层 n 次.
  • Flatten[f[e,…]] 压平具有头部 f 的子表达式.
  • 如果 mij 为矩阵，Flatten[{{m11,m12},{m21,m22}},{{1,3},{2,4}}] 实际上建立了由块 mij 组成的单个矩阵.
  • Flatten[list,{{i1},{i2},…}] 实际上改变 list 的顺序，将 list 中 ik 层放置到结果的第 k 层. 注意，函数Transpose 实际上使用这个规则的反过程.
  • Flatten 将 SparseArray 对象的所有层压平，如同在相应数组中一样. »

范例

打开所有单元 关闭所有单元

基本范例  (3)

压平列表的所有层：

Wolfram Language code: Flatten[{{a, b}, {c, {d}, e}, {f, {g, h}}}]

仅在第 1 层压平：

Wolfram Language code: Flatten[{{a, b}, {c, {d}, e}, {f, {g, h}}}, 1]

把深度为 3 的数组的第 2 层和第 3 层压平到所得矩阵的第 1 层：

Wolfram Language code: Flatten[RandomReal[1, {3, 5, 7}], {{2, 3}, {1}}]//Dimensions

范围  (10)

层次规范  (6)

没有压平：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 0]

压平到第 1 层：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 1]

压平到第 2 层：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 2]

压平到第 3 层：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 3]

压平到第 4 层：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 4]

这等同于 层：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, ∞]

这等同于不指定具体层：

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}]

对于如下矩阵：

Wolfram Language code: u = {{a, b}, {c, d}}

把一个有 u 的分块数组变成一个单一的矩阵：

Wolfram Language code: Flatten[{{u, 0 u}, {0 u, u}}, {{1, 3}, {2, 4}}]//MatrixForm

使用分块的转置有效地变成一个单一的矩阵：

Wolfram Language code: Flatten[{{u, 0 u}, {0 u, u}}, {{1, 4}, {2, 3}}]//MatrixForm

输入数组  (4)

压平一个稀疏数组：

Wolfram Language code: Flatten[SparseArray[{{1, 2} -> a, {6, 4} -> b}]]
Wolfram Language code: Normal[%]

压平一个 QuantityArray 对象：

Wolfram Language code: Flatten[QuantityArray[{{1, 2}, {3, 4}, {5, 6}}, "Knots"]]
Wolfram Language code: Normal[%]

Flatten 适用于任何头部的表达式：

Wolfram Language code: Flatten[f[f[x, y], z]]

压平相对于 g 的所有层：

Wolfram Language code: Flatten[f[g[u, v], f[x, y]], Infinity, g]

压平相对于 f 的所有层：

Wolfram Language code: Flatten[f[g[u, v], f[x, y]], Infinity, f]

应用  (5)

连接列表和单个元素：

Wolfram Language code: Range[5]
Wolfram Language code: Flatten[{%, x, %, %, y}]

拆开一个矩阵：

Wolfram Language code: Table[i ^ j, {i, 3}, {j, 4}]
Wolfram Language code: Flatten[%]

制作一个规则的压平列表：

Wolfram Language code: Table[i -> j, {i, 4}, {j, 3}]
Wolfram Language code: Flatten[%]

不规则矩阵的“转置”：

Wolfram Language code: list = Table[i + j - 1, {i, 4}, {j, i}]
Wolfram Language code: Flatten[list, {{2}, {1}}]

通过压平操作缩并 Dot 运算中的三层数组：

Wolfram Language code: array = RandomInteger[10, {2, 5, 6, 4}];
Wolfram Language code: Flatten[array, {{1}, {2, 3, 4}}].Flatten[array, {{2, 3, 4}, {1}}]

通过显式缩并三个层获取同样的结果：

Wolfram Language code: TensorContract[TensorProduct[array, array], {{2, 6}, {3, 7}, {4, 8}}]

属性和关系  (5)

Flatten 作为一个 Partition 的逆：

Wolfram Language code: Range[20]
Wolfram Language code: Partition[%, 4]
Wolfram Language code: Flatten[%]

ArrayReshape 在矩形数组上是 Flatten 的逆运算：

Wolfram Language code: array = RandomInteger[9, {3, 2, 4}]
Wolfram Language code: Flatten[array]
Wolfram Language code: ArrayReshape[%, {3, 2, 4}]

对于矩形数组 a，ArrayFlatten[a,r] 等价于 Flatten[a,{{1,r+1},{2,r+2},…,{r,2r}}]：

Wolfram Language code: array = RandomInteger[10, {2, 3, 4, 5, 6, 7, 8}];
Wolfram Language code: ArrayFlatten[array, 3] === Flatten[array, {{1, 4}, {2, 5}, {3, 6}}]

Flatten 实际上按照指标的词典顺序排列元素：

Wolfram Language code: Flatten[Array[a, {3, 4}]]
Wolfram Language code: Flatten[Array[100#1 + 10#2 + #3&, {3, 3, 3}]]

对于逆 的排列 p，Flatten[a,List/@p-1]==Transpose[a,p]:

Wolfram Language code: list = Array[Subscript[a, ##]&, {2, 3, 4, 2}];

一个随机排列：

Wolfram Language code: p = RandomSample[Range[4]]

获得它的逆：

Wolfram Language code: invp = InversePermutation[p]
Wolfram Language code: Flatten[list, List /@ invp] == Transpose[list, p]

巧妙范例  (1)

Framed 的连续层：

Wolfram Language code: NestList[Flatten[#, 1]&, Nest[Framed, x, 6], 10]
Wolfram Research (1988)，Flatten，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Flatten.html （更新于 2007 年）.

文本

Wolfram Research (1988)，Flatten，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Flatten.html （更新于 2007 年）.

CMS

Wolfram 语言. 1988. "Flatten." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2007. https://reference.wolfram.com/language/ref/Flatten.html.

APA

Wolfram 语言. (1988). Flatten. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Flatten.html 年

BibTeX

@misc{reference.wolfram_2026_flatten, author="Wolfram Research", title="{Flatten}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Flatten.html}", note=[Accessed: 13-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_flatten, organization={Wolfram Research}, title={Flatten}, year={2007}, url={https://reference.wolfram.com/language/ref/Flatten.html}, note=[Accessed: 13-November-2026]}