WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Floor[x]

x 以下の最大の整数（切り下げ）を返す．

Floor[x,a]

x 以下で最大の a の倍数を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
関数の特性  
微分と積分  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Floor

Floor[x]

x 以下の最大の整数（切り下げ）を返す．

Floor[x,a]

x 以下で最大の a の倍数を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • Floor[x]はStandardFormやInputForm内で，⌊x⌋やlf rfあるいは\[LeftFloor]x \[RightFloor]という形で入力できる． »
  • Floor[x]は， が任意の数値である場合整数を返す．この際，x が明示的な数値であるかないかにかかわらない． »
  • Floor[x]は複素数の実部と虚部に別々に適用される．
  • a が正の実数でなければ，Floor[x,a]は式Floor[x,a]a Floor[x/a]によって定義される． »
  • 厳密な数値に対して，Floorは結果を見出すために数値近似を行う．この手続きは，大域変数$MaxExtraPrecisionの設定により影響を受ける．
  • Floorは自動的にリストに縫い込まれる． »

例題

すべて開く すべて閉じる

例  (4)

最も近い整数に切り下げる：

Wolfram Language code: Floor[2.4]
Wolfram Language code: Floor[2.6]

最も近い10の倍数に切り下げる：

Wolfram Language code: Floor[226, 10]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Floor[x, 10], {x, -30, 30}]

lf と rf を使ってFloorの簡単な表記を入力する：

Wolfram Language code: ⌊x⌋

スコープ  (30)

数値評価  (7)

数値的に評価する：

Wolfram Language code: Floor[5.37]
Wolfram Language code: Floor[-3.7]
Wolfram Language code: Floor[-10.3, 3.5]
Wolfram Language code: Floor[2Pi - E, 5 / 4]

複素数入力：

Wolfram Language code: Floor[5.37 - 1.3I]

1引数のFloorは常に厳密な結果を返す：

Wolfram Language code: Floor[123.4`45]

2引数の形は第2引数の精度に従う：

Wolfram Language code: Floor[100`45, 13.2456`10]

高精度で効率的に評価する：

Wolfram Language code: Floor[7545 / 4660`10000]//Timing
Wolfram Language code: N[Floor[(E + Pi) ^ 2 - E ^ 2 - Pi ^ 2 - 2 E Pi], 10^5]//Quiet//Timing

Floorは実数値区間を扱うことができる：

Wolfram Language code: Floor[Interval[{-1, 3 / 2}]]

Aroundを使って平均的な場合の統計区間を計算する：

Wolfram Language code: Floor[ Around[-1, 0.01]]

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: **Floor**[{{1 / 2, -1}, {0, -1 / 2}}]

MatrixFunctionを使って行列のFloor関数を計算することもできる：

Wolfram Language code: MatrixFunction[Floor, {{1 / 2, -1}, {0, -1 / 2}}]

特定の値  (6)

固定点におけるFloorの値：

Wolfram Language code: Table[Floor[n], {n, {1 / 7, 5 / 4, 7 / 3, 7 / 2}}]

ゼロにおける値：

Wolfram Language code: Floor[0]

Infinityにおける値：

Wolfram Language code: Floor[∞]

記号的に評価する：

Wolfram Language code: PiecewiseExpand[Floor[x, 2], 0 < x < 4]

Floorを記号的に操作する：

Wolfram Language code: Simplify[Floor[x] + Floor[x + 1]]
Wolfram Language code: Reduce[Floor[x] + Floor[2x - 1] == 0, x, Reals]

TemplateBox[{x}, Floor]=2となるような x の値を求める：

Wolfram Language code: xval = x /. FindRoot[Floor[x] == 2, {x, 2.5}]
Wolfram Language code: Plot[Floor[x], {x, -1, 4}, Epilog -> Style[Point[{xval, Floor[xval]}], PointSize[Large], Red], ExclusionsStyle -> Dotted]

可視化  (4)

Floor関数をプロットする：

Wolfram Language code: Plot[Floor[x], {x, -3, 3}, Filling -> Axis]

2引数の形を可視化する：

Wolfram Language code: Plot[Floor[x, .5], {x, -3, 3}, Filling -> Axis]

Floorを三次元でプロットする：

Wolfram Language code: Plot3D[Floor[x, y], {x, -3, 3}, {y, -3, 3}, ColorFunction -> "BlueGreenYellow"]

Floorを複素平面で可視化する：

Wolfram Language code: ComplexPlot3D[Floor[z], {z, 3}, PlotLegends -> Automatic]

関数の特性  (9)

Floorは実数と複素数のすべての入力について定義される：

Wolfram Language code: FunctionDomain[Floor[x], x]
Wolfram Language code: FunctionDomain[Floor[x], x, Complexes]

Floorは無限に大きいあるいは小さい結果を生成することができる：

Wolfram Language code: FunctionRange[Floor[x], x, y]//Quiet

Floorは解析関数ではない：

Wolfram Language code: FunctionAnalytic[Floor[x], x]

特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[Floor[x], x]
Wolfram Language code: FunctionDiscontinuities[Floor[x], x]

Floorは非減少である：

Wolfram Language code: FunctionMonotonicity[Floor[x], x]

Floorは単射ではない：

Wolfram Language code: FunctionInjective[Floor[x, 5], x]
Wolfram Language code: Plot[{Floor[x, 5], 5}, {x, -20, 20}, PlotStyle -> {Thick}]

Floorは全射ではない：

Wolfram Language code: FunctionSurjective[Floor[x, 5], x]
Wolfram Language code: Plot[{Floor[x, 5], -2}, {x, -20, 20}, PlotStyle -> {Thick}]

Floorは非負でも非正でもない：

Wolfram Language code: FunctionSign[Floor[x], x]

Floorは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Floor[x], x]

TraditionalFormによる表示：

Wolfram Language code: Floor[x]//TraditionalForm

微分と積分  (4)

x についての一次導関数：

Wolfram Language code: D[Floor[x], x]

a についての一次導関数：

Wolfram Language code: D[Floor[x, a], a]//FullSimplify

Floorの定積分：

Wolfram Language code: Integrate[Floor[x], {x, 0, E}]
Wolfram Language code: Integrate[Floor[x ^ 2], {x, 0, 3}]

級数展開：

Wolfram Language code: Series[Floor[x ^ 2], {x, 1, 2}, Assumptions -> Element[x, Reals]]

アプリケーション  (4)

実関数の切下げを実軸に沿ってプロットする：

Wolfram Language code: Plot[Floor[x + x ^ 2], {x, -3, 3}]

2D関数の切下げをプロットする：

Wolfram Language code: Plot3D[Floor[x y], {x, -2, 2}, {y, -2, 2}]

10を底とした分数1/997の100万桁目の数字を求める：

Wolfram Language code: Floor[10 Mod[PowerMod[10, 10 ^ 6 - 1, 997], 997] / 997]
Wolfram Language code: RealDigits[1 / 997, 10, 10 ^ 6, -1][[1, -1]]

変数についての仮定を与えて複数の関数を展開する：

Wolfram Language code: PowerExpand[Sqrt[z ^ 2], Assumptions -> {z∈Reals}] PowerExpand[Log[1 / z], Assumptions -> {z > 0}]

次に，同じ関数を変数についての仮定なしで展開する：

Wolfram Language code: PowerExpand[Sqrt[z ^ 2], Assumptions -> {}] PowerExpand[Log[1 / z], Assumptions -> {}]

特性と関係  (12)

負の数はい最も近い整数まで切り捨てられる：

Wolfram Language code: Floor[{-2.4, -2.5, -2.6}]

a>0のとき，Floor[x,a]は，x 以下の最大の a の倍数を与える：

Wolfram Language code: Floor[16, 3]

a のその他の値については，Floor[x,a]は以下の式で定義される：

Wolfram Language code: FunctionExpand[Floor[x, a]]

a<0のとき，結果は x 以上になる：

Wolfram Language code: {Floor[x, a], %} /. {x -> 16, a -> -3}

Floor[x,-a]はCeiling[x,a]に等しい：

Wolfram Language code: FullSimplify[Floor[x, -a] == Ceiling[x, a]]

FloorをPiecewiseに変換する：

Wolfram Language code: PiecewiseExpand[Floor[x ^ 2], 0 < x < 2]

Floor関数のネストを外す：

Wolfram Language code: PiecewiseExpand[Floor[x + 1 / 3 + Floor[1 - x / 2] ^ 3], -1 < x < 1]

PowerExpandからFloorを得る：

Wolfram Language code: PowerExpand[Sqrt[z ^ 2], Assumptions -> {}]
Wolfram Language code: PowerExpand[ArcSin[Sin[z]], Assumptions -> {}]

Floorを含む式を簡約する：

Wolfram Language code: Reduce[Floor[x + 1 / 2] == 3Floor[x ^ 2] - 2 && -2 < x < 2, x, Reals]

複素平面上のFloor関数：

Wolfram Language code: ContourPlot[Abs[Floor[x + I y]], {x, -3, 3}, {y, -3, 3}]

Floorを含むいくつかの式：

Wolfram Language code: Sum[Floor[k / 3], {k, 1, n}, Assumptions -> n > 1]
Wolfram Language code: Sum[(k/Floor[k] + 1), {k, 1, n}]

FloorはDifferenceRootとして表すことができる：

Wolfram Language code: DifferenceRootReduce[Floor[k], k]
Wolfram Language code: DifferenceRootReduce[Floor[k, 3], k]

Floorの母関数：

Wolfram Language code: GeneratingFunction[Floor[n, 4], n, x]
Wolfram Language code: Series[%, {x, 0, 10}]

Floorの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[Floor[n, 4], n, x]

考えられる問題  (2)

Floorは自動的に値を結合しない：

Wolfram Language code: Floor[π ^ 2 + 2π + 1 - (π + 1) ^ 2]
Wolfram Language code: Simplify[%]

保護桁がFloorの結果に影響することがある：

Wolfram Language code: Floor[1`100 - 10 ^ -130]
Wolfram Language code: Floor[1`100 + 10 ^ -130]
Wolfram Language code: 1`100 - 10 ^ -130 === 1`100 + 10 ^ -130

おもしろい例題  (3)

自身を数える数列：

Wolfram Language code: Table[Floor[Sqrt[2k] + 1 / 2], {k, 21}]

Floorを含む和の連分数を調べる：

Wolfram Language code: Sum[1 / 2 ^ Floor[n / GoldenRatio], {n, 1, 10000}];
Wolfram Language code: Log[2, Take[ContinuedFraction[%], 15]]
Wolfram Language code: Table[Fibonacci[k], {k, -1, 13}]

Floorのフーリエ級数の収束：

Wolfram Language code: Plot[Evaluate[Table[x + 1 / 2 - UnitStep[x] + Sum[Sin[2Pi k x] / k, {k, 1, o}] / Pi, {o, 10}]], {x, 0, 4}]
Wolfram Research (1988), Floor, Wolfram言語関数， https://reference.wolfram.com/language/ref/Floor.html （2007年に更新）.

テキスト

Wolfram Research (1988), Floor, Wolfram言語関数， https://reference.wolfram.com/language/ref/Floor.html （2007年に更新）.

CMS

Wolfram Language. 1988. "Floor." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/Floor.html.

APA

Wolfram Language. (1988). Floor. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Floor.html

BibTeX

@misc{reference.wolfram_2026_floor, author="Wolfram Research", title="{Floor}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Floor.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_floor, organization={Wolfram Research}, title={Floor}, year={2007}, url={https://reference.wolfram.com/language/ref/Floor.html}, note=[Accessed: 12-September-2026]}