WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GeoDirection[{lat1,lon1},{lat2,lon2}]

地球上のある緯度・経度位置から別の位置への方位角の方向を与える．

GeoDirection[loc1,loc2]

位置オブジェクトあるいは地理実体によって指定された位置間の方位角の方向を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

GeoDirection

GeoDirection[{lat1,lon1},{lat2,lon2}]

地球上のある緯度・経度位置から別の位置への方位角の方向を与える．

GeoDirection[loc1,loc2]

位置オブジェクトあるいは地理実体によって指定された位置間の方位角の方向を与える．

詳細

  • 地理的方向は，方位（角）としても知られている．
  • GeoDirection[loc1,loc2]は，loc1で計測された，真北と loc1から loc2までの測地線との間の時計回りの角度を与える．高さは無視される．
  • 結果は，"AngularDegrees"が単位のQuantity角として返される．
  • 経緯度は，度を単位とした数，DMS文字列，あるいはQuantity角として与えられる．
  • GeoDirection[loc1,loc2]における位置オブジェクトは，GeoPosition，GeoPositionXYZ，GeoPositionENU，GeoGridPositionのオブジェクトとして与えられる．
  • GeoDirection[loc1,loc2]は，デフォルトで，pos1の測地系に関連付けられた準拠楕円体を使う．
  • GeoDirectionおよびGeoDistanceは測地上の逆の問題を解く．

例題

すべて開く すべて閉じる

例  (2)

準拠楕円体上の2つの位置間の前方位角：

Wolfram Language code: GeoDirection[{37, -109}, {40.112981, -88.261227}]

2つの完全に指定された測地位置間の方位角：

Wolfram Language code: GeoDirection[GeoPosition[{37, -109, 150}, "ITRF00"], GeoPosition[{40.112981, -88.261227, 192.868}, "ITRF00"]]

スコープ  (4)

デフォルトの測地系"ITRF00"のパラメータを使った，地球上の任意の2点間の方位角：

Wolfram Language code: GeoDirection[{46.42, -21.02}, {-30.23, 40.51}]

角はDMS文字列を使って指定することもできる：

Wolfram Language code: GeoDirection["46d25m12s N 21d1m12s W", {"30°13'48.''S", "40°30'36.''E"}]

異なる形式による測地位置間の方向：

Wolfram Language code: p = GeoPosition[{46.42, -21.02}]
Wolfram Language code: q = GeoGridPosition[{0.7, 0.9}, "Mercator"]
Wolfram Language code: GeoDirection[p, q]
Wolfram Language code: GeoDirection[GeoPositionXYZ[p], GeoPositionENU[q, GeoPosition[{0, 0}]]]

高さと時点の情報は，GeoDirectionの計算では無視される：

Wolfram Language code: GeoDirection[GeoPosition[{20, 30, 100}], GeoPosition[{-20, -30, 200, 3.6 10 ^ 9}]]
Wolfram Language code: % === GeoDirection[GeoPosition[{20, 30}], GeoPosition[{-20, -30}]]

異なる測地系の2点間の方向．計算は2番目の点の測地系を最初の点の測地系に変更してから行われる：

Wolfram Language code: GeoDirection[GeoPosition[{30., 40.}, "ITRF90"], GeoPosition[{-50., -60.}, "WGS72"]]
Wolfram Language code: GeoDirection[GeoPosition[{30., 40.}], GeoPosition[{-50., -60.}]]

差は非常に小さい：

Wolfram Language code: % - %%

特性と関係  (8)

GeoDirectionは対称関数ではない：

Wolfram Language code: p = GeoPosition[{30, 40}]; q = GeoPosition[{50, 60}];
Wolfram Language code: GeoDirection[p, q]
Wolfram Language code: GeoDirection[q, p]

GeoDirectionはGeoDestinationの部分的な逆である：

Wolfram Language code: GeoDestination[GeoPosition[{30, 40}], {10 ^ 6, 135}]
Wolfram Language code: GeoDirection[GeoPosition[{30, 40}], %]

GeoDirectionは，GeoDisplacementが返した情報の一部を返す：

Wolfram Language code: p = Entity["City", {"Oslo", "Oslo", "Norway"}]; q = Entity["City", {"BuenosAires", "BuenosAires", "Argentina"}];
Wolfram Language code: GeoDirection[p, q]
Wolfram Language code: GeoDisplacement[p, q]

点のリスト間の方位を計算する：

Wolfram Language code: points = {{-20, 10}, {40, 20}, {-23, 45}, {82, -132}};
Wolfram Language code: GeoDirection@@@Partition[points, 2, 1]

標準方位から始めて，測地円上に点を作る：

Wolfram Language code: points = First@GeoDestination[{70, 0}, {1000000, Range[0, 360, 6]}];

円の点間の方位角は，角度決定を法として増加する：

Wolfram Language code: ListPlot[GeoDirection@@@Partition[points, 2, 1]]

測地線に沿って等間隔で置かれた複数の点を作る：

Wolfram Language code: points = First@GeoDestination[{70, 0}, {Range[0, 1000000, 100000], 90}]

方位は測地線に沿って一定ではない：

Wolfram Language code: GeoDirection@@@Partition[points, 2, 1]

GeoDirectionは，ほぼ対蹠的な点については平滑関数ではない：

Wolfram Language code: f[ϕ_ ? NumericQ, λ_ ? NumericQ] := QuantityMagnitude@GeoDirection[GeoPosition[{30, 0}], GeoPosition[{ϕ, λ}]]
Wolfram Language code: Plot[f[-30, λ], {λ, -181, -179}]
Wolfram Language code: Plot3D[f[ϕ, λ], {λ, -181, -179}, {ϕ, -29, -31}, Exclusions -> {{λ == -180, ϕ < -30}}]

球面上の対応する結果と比較する：

Wolfram Language code: fsph[ϕ_ ? NumericQ, λ_ ? NumericQ] := QuantityMagnitude@GeoDirection[GeoPosition[{30, 0}, 1], GeoPosition[{ϕ, λ}, 1]]
Wolfram Language code: Plot[fsph[-30, λ], {λ, -181, -179}]
Wolfram Language code: Plot3D[fsph[ϕ, λ], {λ, -181, -179}, {ϕ, -29, -31}, Exclusions -> {{λ == -180, ϕ < -30}}]

2点の対蹠点ペアを結ぶ測地線の初期方位は相補的である：

Wolfram Language code: p = GeoPosition[{35.1, 75.7}]; q = GeoPosition[{60.4, 130.9}];
Wolfram Language code: α = GeoDirection[p, q]
Wolfram Language code: ap = GeoAntipode[p]; aq = GeoAntipode[q];
Wolfram Language code: β = GeoDirection[ap, aq]
Wolfram Language code: α + β

地理的に見る：

Wolfram Language code: {GeoGraphics[{Arrow[GeoPath[{p, q}]], PointSize[Large], Red, Point[p], Green, Point[q]}], GeoGraphics[{Arrow[GeoPath[{ap, aq}]], PointSize[Large], Red, Point[ap], Green, Point[aq]}]}
Wolfram Research (2008), GeoDirection, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoDirection.html （2014年に更新）.

テキスト

Wolfram Research (2008), GeoDirection, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoDirection.html （2014年に更新）.

CMS

Wolfram Language. 2008. "GeoDirection." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/GeoDirection.html.

APA

Wolfram Language. (2008). GeoDirection. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoDirection.html

BibTeX

@misc{reference.wolfram_2026_geodirection, author="Wolfram Research", title="{GeoDirection}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/GeoDirection.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_geodirection, organization={Wolfram Research}, title={GeoDirection}, year={2014}, url={https://reference.wolfram.com/language/ref/GeoDirection.html}, note=[Accessed: 03-November-2026]}