WOLFRAM

Wolfram 语言与系统参考资料中心

GeoWithinQ[reg,loc]

如果地点 loc 包含在区域 reg 中则返回 True，否则返回 False.

GeoWithinQ[reg]

表示 GeoWithinQ 的操作符形式，可作用于一个位置.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
地理数据  
历史数据  
选项  
"FullyContained"  
TimeContraint  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

GeoWithinQ

GeoWithinQ[reg,loc]

如果地点 loc 包含在区域 reg 中则返回 True，否则返回 False.

GeoWithinQ[reg]

表示 GeoWithinQ 的操作符形式，可作用于一个位置.

更多信息和选项

  • 在 GeoWithinQ[reg,loc] 中，reg 可以指定为地理域的实体，如 "City"、"Country" 或 "HistoricalCountry"；Dated[…] 对象；GeoVariant[…] 表达式或扩展的 GeoGraphics 基元. 位置 loc 还可以指定为 GeoPosition 或相关的类点位置对象.
  • 对于与时间相关的实体，GeoWithinQ[reg,loc] 默认返回在它们历史上的某个时刻，loc 是否包含在 reg 中. 如果实体的时间跨度不同，则 GeoWithinQ 返回 False.
  • Dated[entity,dates] 可用于将与时间相关的 entity 限制在给定的日期或日期间隔内. GeoVariant[entity,"UnionArea"] 可用于使计算忽略日期信息.
  • GeoWithinQ 的两个参数都接受列表，事实上会在输入列表上调用 Outer.
  • GeoWithinQ[reg][loc] 等价于 GeoWithinQ[reg,loc].
  • GeoWithinQ 接受以下选项：
  • "FullyContained" Falseloc 是否被完全包含在 reg 中
    TimeConstraint20最大计算时间（以秒为单位）
  • 选项设置 "FullyContained"->True 下，只有当 loc 完全包含在 reg 中时，GeoWithinQ[reg,loc] 才会返回 True.

范例

打开所有单元 关闭所有单元

基本范例  (2)

纽约市位于美国境内：

Wolfram Language code: GeoWithinQ[Entity["Country", "UnitedStates"], Entity["City", {"NewYork", "NewYork", "UnitedStates"}]]

但它不在佛罗里达州：

Wolfram Language code: GeoWithinQ[Entity["AdministrativeDivision", {"Florida", "UnitedStates"}], Entity["City", {"NewYork", "NewYork", "UnitedStates"}]]

确定你当前的位置是否在伊利诺伊州香槟市：

Wolfram Language code: GeoWithinQ[Entity["City", {"Champaign", "Illinois", "UnitedStates"}], Here]

范围  (8)

地理数据  (5)

测试法国是否在下列多边形中：

Wolfram Language code: poly = Polygon[GeoPosition[{{40.42, -3.71}, {48.86, 2.34}, {52.52, 13.38}}]]; GeoWithinQ[poly, Entity["Country", "France"]]

可视化法国和多边形：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "France"]], Red, poly}]

测试几个机场是否在芝加哥市中：

Wolfram Language code: GeoWithinQ[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], {Entity["Airport", "KORD"], Entity["Airport", "KMDW"], Entity["Airport", "KBMI"], Entity["Airport", "KCMI"]}]

测试某个特定地点是否在几个不同区域中：

Wolfram Language code: GeoWithinQ[{EntityClass["Country", "NorthAmerica"], EntityClass["Country", "Europe"], Entity["Country", "UnitedStates"], Entity["Country", "France"], Entity["Country", "UnitedKingdom"]}, GeoPosition[{50.08, 14.43}]]
Wolfram Language code: GeoGraphics[GeoMarker[{50.08, 14.43}], GeoRange -> "Country"]

同时测试几个区域中若干城市的所属区域：

Wolfram Language code: GeoWithinQ[{EntityClass["Country", "NorthAmerica"], EntityClass["Country", "Europe"], Entity["Country", "UnitedStates"], Entity["Country", "France"], Entity["Country", "UnitedKingdom"]}, {Entity["City", {"Oxford", "Oxfordshire", "UnitedKingdom"}], Entity["City", {"Champaign", "Illinois", "UnitedStates"}], Entity["City", {"Lima", "Lima", "Peru"}], Entity["City", {"Frankfurt", "Hesse", "Germany"}]}]

每一行是关于单个地区的所有地点的结果：

Wolfram Language code: First[%] === GeoWithinQ[EntityClass["Country", "NorthAmerica"], {Entity["City", {"Oxford", "Oxfordshire", "UnitedKingdom"}], Entity["City", {"Champaign", "Illinois", "UnitedStates"}], Entity["City", {"Lima", "Lima", "Peru"}], Entity["City", {"Frankfurt", "Hesse", "Germany"}]}]

使用 GeoWithinQ 的操作符形式：

Wolfram Language code: GeoWithinQ[Entity["Country", "UnitedKingdom"]][Entity["City", {"Bath", "BathAndNorthEastSomerset", "UnitedKingdom"}]]

历史数据  (3)

扎马战役（battle of Zama）发生时，该战役的地点还不在罗马共和国境内：

Wolfram Language code: GeoWithinQ[Entity["HistoricalCountry", "RomanRepublic"], Entity["MilitaryConflict", "BattleOfZama"]]

扎马战役的地点随着时间推移在后期落在罗马共和国境内：

Wolfram Language code: pos = GeoPosition[Entity["MilitaryConflict", "BattleOfZama"]]
Wolfram Language code: GeoWithinQ[Entity["HistoricalCountry", "RomanRepublic"], pos]

公元前 250 年，巴黎城并不在罗马共和国境内：

Wolfram Language code: GeoWithinQ[Dated[Entity["HistoricalCountry", "RomanRepublic"], -250], Entity["City", {"Paris", "IleDeFrance", "France"}]]

公元前 50 年，罗马共和国将其纳入版图：

Wolfram Language code: GeoWithinQ[Dated[Entity["HistoricalCountry", "RomanRepublic"], -50], Entity["City", {"Paris", "IleDeFrance", "France"}]]

威尼斯共和国从未属于罗马帝国，因为两者在时间上并不重叠：

Wolfram Language code: GeoWithinQ[Entity["HistoricalCountry", "RomanEmpire"], Entity["HistoricalCountry", "RepublicVenice"]]

GeoVariant[entity,"UnionArea"] 表示 entity 在其历史上所有时间的所有多边形的集合，因此 GeoWithinQ 可以忽略时间信息：

Wolfram Language code: GeoWithinQ[GeoVariant[Entity["HistoricalCountry", "RomanEmpire"], "UnionArea"], Entity["HistoricalCountry", "RepublicVenice"]]

选项  (2)

"FullyContained"  (1)

英国被认为是在伦敦内，因为两个实体重叠：

Wolfram Language code: GeoWithinQ[Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}], Entity["Country", "UnitedKingdom"]]

选项 "FullyContained"->True 排除了延伸到实体外的地区：

Wolfram Language code: GeoWithinQ[Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}], Entity["Country", "UnitedKingdom"], "FullyContained" -> True]

伦敦总被认为是在英国内部：

Wolfram Language code: GeoWithinQ[Entity["Country", "UnitedKingdom"], Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}], "FullyContained" -> True]

TimeContraint  (1)

设置非常短的时间限制可能会使函数不能正常工作：

Wolfram Language code: GeoWithinQ[Entity["Country", "UnitedStates"], Entity["AdministrativeDivision", {"California", "UnitedStates"}], TimeConstraint -> 0.1]

默认的时间限制允许计算得出预期结果：

Wolfram Language code: GeoWithinQ[Entity["Country", "UnitedStates"], Entity["AdministrativeDivision", {"California", "UnitedStates"}]]

应用  (1)

判断哪些点在美国中部州中：

Wolfram Language code: points = {GeoPosition[{40.38, -95.32}], GeoPosition[{35.44, -111.98}], GeoPosition[{37.11, -93.83}], GeoPosition[{45.16, -111.35}], GeoPosition[{44.67, -75.44}]};
Wolfram Language code: group = GeoGroup[{Entity["AdministrativeDivision", {"Missouri", "UnitedStates"}], Entity["AdministrativeDivision", {"Illinois", "UnitedStates"}], Entity["AdministrativeDivision", {"Iowa", "UnitedStates"}], Entity["AdministrativeDivision", {"Kansas", "UnitedStates"}]}];
Wolfram Language code: GeoWithinQ[group, points]

属性和关系  (2)

GeoWithinQ[list1,list2] 实际上等价于 Outer[GeoWithinQ,list1,list2]：

Wolfram Language code: GeoWithinQ[{EntityClass["Country", "NorthAmerica"], EntityClass["Country", "Europe"]}, {Entity["City", {"Oxford", "Oxfordshire", "UnitedKingdom"}], Entity["City", {"Champaign", "Illinois", "UnitedStates"}], Entity["City", {"Lima", "Lima", "Peru"}]}] === Outer[GeoWithinQ, {EntityClass["Country", "NorthAmerica"], EntityClass["Country", "Europe"]}, {Entity["City", {"Oxford", "Oxfordshire", "UnitedKingdom"}], Entity["City", {"Champaign", "Illinois", "UnitedStates"}], Entity["City", {"Lima", "Lima", "Peru"}]}]

GeoWithinQ 可以使用 GeoNearest 和 MemberQ 的组合实现：

Wolfram Language code: continentalUS = GeoVariant[Entity["Country", "UnitedStates"], "DefaultMapArea"]; point = GeoPosition[{33.92, -118.71}]; GeoWithinQ[continentalUS, point]
Wolfram Language code: MemberQ[GeoNearest[{continentalUS}, point, {All, 0}], continentalUS]

GeoNearest 允许指定半径：

Wolfram Language code: MemberQ[GeoNearest[{continentalUS}, point, {All, Quantity[100, "Kilometers"]}], continentalUS]

该点在加州马里布海岸之外：

Wolfram Language code: GeoGraphics[{PointSize[Large], Point@point}]

可能存在的问题  (2)

如果使用默认选项值 "FullyContained"False，GeoWithinQ 将会检查多边形交叉的情况，可能会导致意外结果：

Wolfram Language code: GeoWithinQ[Entity["GeographicRegion", "Africa"], Entity["Country", "Spain"]]

默认情况下，GeoWithinQ 使用国家的 "PrincipalArea" 地理变体， 其中，西班牙将包含加那利群岛：

Wolfram Language code: GeoGraphics[{Polygon[Entity["GeographicRegion", "Africa"]], GeoStyling[Red], Polygon[GeoVariant[Entity["Country", "Spain"], "PrincipalArea"]]}, GeoCenter -> Entity["Island", "Lanzarote"], GeoRange -> Quantity[300, "Miles"]]

用 "FullyContained"True 检查实际的情况：

Wolfram Language code: GeoWithinQ[Entity["GeographicRegion", "Africa"], Entity["Country", "Spain"], "FullyContained" -> True]

或使用不包含重叠区域的地理变体：

Wolfram Language code: GeoWithinQ[Entity["GeographicRegion", "Africa"], GeoVariant[Entity["Country", "Spain"], "DefaultMapArea"]]

GeoWithinQ[entity,loc] 使用可用于给定实体的边界多边形，该边界多边形可能没有足够的分辨率来正确解析某些位置，尤其是靠近海岸的地方：

Wolfram Language code: loc = Interpreter["Location"]["brooklyn bridge"]
Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "UnitedStates"]], GeoMarker[loc]}, GeoCenter -> loc, GeoRange -> Quantity[3, "Miles"]]

因此，该受限的 Interpreter 调用失败：

Wolfram Language code: Interpreter[Restricted["Location", Entity["Country", "UnitedStates"]]]["brooklyn bridge"]

纽约市的边界多边形不包含该位置：

Wolfram Language code: Interpreter[Restricted["Location", Entity["City", {"NewYork", "NewYork", "UnitedStates"}]]]["brooklyn bridge"]
Wolfram Language code: GeoGraphics[{Polygon[Entity["City", {"NewYork", "NewYork", "UnitedStates"}]], GeoMarker[loc]}]
Wolfram Research (2014)，GeoWithinQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GeoWithinQ.html （更新于 2024 年）.

文本

Wolfram Research (2014)，GeoWithinQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GeoWithinQ.html （更新于 2024 年）.

CMS

Wolfram 语言. 2014. "GeoWithinQ." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/GeoWithinQ.html.

APA

Wolfram 语言. (2014). GeoWithinQ. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/GeoWithinQ.html 年

BibTeX

@misc{reference.wolfram_2026_geowithinq, author="Wolfram Research", title="{GeoWithinQ}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/GeoWithinQ.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_geowithinq, organization={Wolfram Research}, title={GeoWithinQ}, year={2024}, url={https://reference.wolfram.com/language/ref/GeoWithinQ.html}, note=[Accessed: 03-November-2026]}