WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

x>y

が より大きいと判定されるとTrueを返す．

x1>x2>x3

が狭義減少数列をなす場合，Trueを返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値不等式  
記号不等式  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Greater

x>y

が より大きいと判定されるとTrueを返す．

x1>x2>x3

が狭義減少数列をなす場合，Trueを返す．

詳細

  • Greaterは，強不等式あるいは厳密な不等式としても知られている．
  • Greaterはその引数が実数である場合，TrueまたはFalseを返す．
  • Greaterは，引数が数でなければある簡約化を実行する．
  • 厳密な数において，Greaterは数値順序付けを行うために，数値近似を内部的に使う．この手続きは，大域変数$MaxExtraPrecisionの設定に影響を受けることがある．

例題

すべて開く すべて閉じる

例  (2)

数を比較する：

Wolfram Language code: 1 > 0
Wolfram Language code: 2 / 17 > 1 / 5 > Pi / 10

不等式を表す：

Wolfram Language code: x ^ 3 - 2x + 1 > 0
Wolfram Language code: Reduce[%, x]

スコープ  (9)

数値不等式  (7)

不等式は実数についてのみ定義される：

Wolfram Language code: I > 0

有理数を比べる：

Wolfram Language code: 3 / 2 > 4 / 3

二進法で最高でも最後の8桁しか違わない近似数は等しいとみなされる：

Wolfram Language code: 1. > 1. - 2 ^ 7 10 ^ -16
Wolfram Language code: 1. > 1. - 2 ^ 8 10 ^ -16

厳密な数値表現と近似数を比較する：

Wolfram Language code: N[Pi, 20] > Pi
Wolfram Language code: N[Pi, 20] > Pi(1 - 2 ^ 8 10 ^ -20)

2つの厳密な数式を比較する．不等式の証明には数値テストで十分なことがある：

Wolfram Language code: E ^ Pi > Pi ^ E

この不等式の証明には記号的なメソッドが必要である：

Wolfram Language code: Sqrt[2] + Sqrt[3] > Sqrt[5 + 2Sqrt[6]]

Greaterで使われる数値メソッドと記号メソッドでは，この不等式が誤りであると証明するのには不十分である：

Wolfram Language code: Sqrt[2] + Sqrt[3] > Root[# ^ 4 - 10# ^ 2 + 1&, 4]

RootReduceを使って代数的数の符号を決定する：

Wolfram Language code: RootReduce[%[[1]] - %[[2]]] > 0

Greaterが使う数値メソッドは，この不等式を証明するのに十分な精度ではない：

Wolfram Language code: Sqrt[2] + Sqrt[3] > Root[# ^ 4 - 10# ^ 2 + 1&, 4] - 10 ^ -100

RootReduceは厳密なメソッドを使ってこの不等式を証明する：

Wolfram Language code: RootReduce[%[[1]] - %[[2]]] > 0

$MaxExtraPrecisionの値を大きくすることによっても，この不等式が証明できるかもしれない：

Wolfram Language code: Block[{$MaxExtraPrecision = 100}, Sqrt[2] + Sqrt[3] > Root[# ^ 4 - 10# ^ 2 + 1&, 4] - 10 ^ -100]

記号不等式  (2)

x は実数ではないかもしれないので，記号不等式は未評価のまま残される：

Wolfram Language code: x > x

Refineを使い，x が実数であると仮定して不等式を再評価する：

Wolfram Language code: Refine[%, Element[x, Reals]]

記号不等式：

Wolfram Language code: ineq = x ^ 2 - y ^ 2 > 1

Reduceを使って解集合の明示的な表示を求める：

Wolfram Language code: Reduce[ineq, {x, y}]

FindInstanceを使って解の例を求める：

Wolfram Language code: FindInstance[ineq, {x, y}]

Minimizeを使って，不等式で定義された領域での最適化を行う：

Wolfram Language code: Minimize[{x ^ 2, ineq}, {x, y}]

Refineを使って不等式で定義された仮定の下で簡約する：

Wolfram Language code: Refine[Sqrt[(1 - x ^ 2) ^ 2], ineq]

特性と関係  (12)

2引数のGreaterの否定はLessEqualである：

Wolfram Language code: Not[x > y]

3引数のGreaterの否定は自動的には簡約されない：

Wolfram Language code: Not[x > y > z]

LogicalExpandを使って，否定を2引数のLessEqualで表す：

Wolfram Language code: LogicalExpand[%]

これは，3引数のLessEqualとは等しくない：

Wolfram Language code: LogicalExpand[x ≤ y ≤ z]

Greaterが数式間の不等性が判断できない場合，不等式は未評価で返される：

Wolfram Language code: a = Log[Sqrt[2] + Sqrt[3]]; b = Log[5 + 2Sqrt[6]] / 2; a > b

FullSimplifyは厳密な記号変換で不等式が正しくないことを証明する：

Wolfram Language code: FullSimplify[%]

Positive[x]は と等価である：

Wolfram Language code: Positive /@ {-1, 0, 1, I}

Reduceを使って不等式を解く：

Wolfram Language code: Reduce[x ^ 5 - 3x + 2 > 0, x]
Wolfram Language code: Reduce[y ^ 2 - 4x ^ 2 + 4x ^ 4 > 0, {x, y}]

FindInstanceを使って解の例を求める：

Wolfram Language code: FindInstance[y ^ 2 - 4x ^ 2 + 4x ^ 4 > z ^ 2, {x, y, z}]

RegionPlotおよび RegionPlot3Dを使って不等式の解集合を可視化する：

Wolfram Language code: RegionPlot[y ^ 2 - 4x ^ 2 + 4x ^ 4 > 0, {x, -1, 1}, {y, -1, 1}]
Wolfram Language code: RegionPlot3D[y ^ 2 - 4x ^ 2 + 4x ^ 4 > z ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

不等式の仮定：

Wolfram Language code: Refine[Sqrt[x ^ 2], x > 0]
Wolfram Language code: Limit[a ^ n, n -> Infinity, Assumptions -> a > 1]

MinimizeおよびMaximizeを使って不等式で制約された最適化問題を解く：

Wolfram Language code: Minimize[{x - y, -y ^ 2 + 4x ^ 2 - 4x ^ 4 > 0}, {x, y}]

NMinimizeおよびNMaximizeを使って制約条件付き最適化問題を数値的に解く：

Wolfram Language code: NMinimize[{x - y, 2 > Tan[x] + Tan[y] > 1}, {x, y}]

不等式の解集合上で関数を積分する：

Wolfram Language code: Integrate[x ^ 2 Boole[2 > x ^ 2 + y ^ 2 > 1], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]

Median，Quantile，Quartilesを 番目の最大数に使う：

Wolfram Language code: {x1, x2, x3} = {1, 2, 3};
Wolfram Language code: x3 > x2 > x1
Wolfram Language code: Median[{x2, x3, x1}]

考えられる問題  (3)

機械精度の近似数についての不等式は微妙である：

Wolfram Language code: 2.00006 - 2.00005 > 0.00001

厳密な不等性は余分な桁に依存している：

Wolfram Language code: 2.00006 - 2.00005//InputForm

任意精度の近似数にはこの問題はない：

Wolfram Language code: 2.00006`16 - 2.00005`16 > 0.00001`16

自動精度追跡機能のお陰で，Greaterは最初の10桁だけを見ればよいと分かっている：

Wolfram Language code: Precision[2.00006`16 - 2.00005`16]

この場合，機械数間の不等式は予想の結果を返す：

Wolfram Language code: 2.6 - 2.5 > 0.1

Greaterはこの場合の余分桁を無視する：

Wolfram Language code: 2.6 - 2.5//InputForm
Wolfram Research (1988), Greater, Wolfram言語関数， https://reference.wolfram.com/language/ref/Greater.html （1996年に更新）.

テキスト

Wolfram Research (1988), Greater, Wolfram言語関数， https://reference.wolfram.com/language/ref/Greater.html （1996年に更新）.

CMS

Wolfram Language. 1988. "Greater." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 1996. https://reference.wolfram.com/language/ref/Greater.html.

APA

Wolfram Language. (1988). Greater. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Greater.html

BibTeX

@misc{reference.wolfram_2026_greater, author="Wolfram Research", title="{Greater}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/Greater.html}", note=[Accessed: 06-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_greater, organization={Wolfram Research}, title={Greater}, year={1996}, url={https://reference.wolfram.com/language/ref/Greater.html}, note=[Accessed: 06-November-2026]}