Hypergeometric1F1

Hypergeometric1F1[a,b,z]

クンマー(Kummer)の合流型超幾何関数である．

詳細

記号操作・数値操作の両方に適した数学関数である．
関数は，級数展開 $TemplateBox[{a, b, z}, Hypergeometric1F1]=sum_(k=0)^(infty)TemplateBox[{a, k}, Pochhammer]/TemplateBox[{b, k}, Pochhammer]z^k/k!$ を持つ．ここで，はPochhammer記号である．
特別な引数の場合，Hypergeometric1F1は，自動的に厳密値を計算する．
Hypergeometric1F1は任意の数値精度で評価できる．
Hypergeometric1F1は自動的にリストに縫い込まれる．
Hypergeometric1F1はIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (5)

数値的に評価する：

Wolfram Language code: Hypergeometric1F1[1, 2, 3.0]

実数の部分集合上でをプロットする：

Wolfram Language code: Plot[Hypergeometric1F1[1, 2, x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Hypergeometric1F1[1, 2, z ^ 2], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数：

Wolfram Language code: Series[Hypergeometric1F1[a, b, x], {x, 0, 3}]

Infinityにおける級数展開：

Wolfram Language code: Series[Hypergeometric1F1[a, b, x], {x, ∞, 2}]//Normal//FullSimplify

スコープ (40)

数値評価 (5)

高精度で評価する：

Wolfram Language code: N[Hypergeometric1F1[10, 1 / 3, -1], 50]

出力精度は入力精度に従う：

Wolfram Language code: Hypergeometric1F1[10, 1 / 3, -1.000000000000000000000000000000000000]

複素引数とパラメータについて評価する：

Wolfram Language code: Hypergeometric1F1[2 + I, 2, 0.5]

Hypergeometric1F1を高精度で効率よく評価する：

Wolfram Language code: Hypergeometric1F1[1, 2, 3`500]//Timing

Wolfram Language code: Hypergeometric1F1[1, 2, 3`50000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Hypergeometric1F1[1 / 2, 2 / 3, Interval[{0.21, 0.22}]]

Wolfram Language code: Hypergeometric1F1[1 / 2, 2 / 3, CenteredInterval[3 / 4, 1 / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Hypergeometric1F1[1, 1, Around[1 / 2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: Hypergeometric1F1[1, 1, {{1, 0}, {0, 1}}]

MatrixFunctionを使って行列のHypergeometric1F1関数を計算することもできる：

Wolfram Language code: MatrixFunction[Hypergeometric1F1[1, 1, #]&, {{1, 0}, {0, 1}}]

特定の値 (4)

Hypergeometric1F1は，ある種のパラメータについては，評価すると自動的により簡単な関数になる：

Wolfram Language code: Hypergeometric1F1[1 / 2, 1, x]

Wolfram Language code: Hypergeometric1F1[2, 1, x]

Wolfram Language code: Hypergeometric1F1[1, 1 / 2, x]

Hypergeometric1F1のいくつかのケースについての無限大における極限値：

Wolfram Language code: Limit[Hypergeometric1F1[1 / 2, Sqrt[2], x], x -> Infinity]

Wolfram Language code: Limit[Hypergeometric1F1[1 / 2, Sqrt[2], x], x -> I Infinity]

Wolfram Language code: Limit[Hypergeometric1F1[1 / 2, b, x], x -> Infinity]

方程式を満足するの値を求める：

Wolfram Language code:

f[x_] := Hypergeometric1F1[1 / 2, Sqrt[2], x] - 2;
xzero = Solve[f[x] == 0 && 0 < x < 3.1, x][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[f[x], {x, 0, 3}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

Heun関数は超幾何関数に簡約できる：

Wolfram Language code: Hypergeometric1F1[a, b, z] == HeunB[a, 0, b, -1, 0, z]

Wolfram Language code: Hypergeometric1F1[a, b, z] == HeunC[-a, -a, b, 0, -1, z]

可視化 (3)

Hypergeometric1F1関数をプロットする：

Wolfram Language code:

Plot[{Hypergeometric1F1[1 / 2, Sqrt[2], x], Hypergeometric1F1[1 / 2, Sqrt[3], x], Hypergeometric1F1[1 / 2, Sqrt[5], x]}, {x, -4, 4}]

Hypergeometric1F1をその第2パラメータの関数としてプロットする：

Wolfram Language code:

Plot[{Hypergeometric1F1[Sqrt[2], b, 1], Hypergeometric1F1[Sqrt[5], b, 1], Hypergeometric1F1[Sqrt[7], b, 1]}, {b, -3, 3}, IconizedObject[«PlotOptions»]]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Hypergeometric1F1[1, Sqrt[2], z]], {z, -5 - 5I, 5 + 5I}, Contours -> 24]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Hypergeometric1F1[1, Sqrt[2], z]], {z, -5 - 5I, 5 + 5I}, Contours -> 24]

関数の特性 (9)

Hypergeometric1F1の実領域：

Wolfram Language code: FunctionDomain[Hypergeometric1F1[a, b, x], x]

複素領域：

Wolfram Language code: FunctionDomain[Hypergeometric1F1[a, b, z], z, Complexes]

はかつの実数値について解析関数である：

Wolfram Language code: FunctionAnalytic[Hypergeometric1F1[a, b, z], z, Assumptions -> a < 0b∈Reals]//Reduce

が正の値のときは解析的であることもないこともある：

Wolfram Language code: FunctionAnalytic[Hypergeometric1F1[1, -1, z], z]

Wolfram Language code: FunctionAnalytic[Hypergeometric1F1[1, 1, z], z]

Hypergeometric1F1は特別の値を除いて非減少でも非増加でもない：

Wolfram Language code: Table[FunctionMonotonicity[Hypergeometric1F1[a, 1, z], z], {a, 4}]

は単射ではない：

Wolfram Language code: FunctionInjective[Hypergeometric1F1[Sqrt[3], Sqrt[2], z], z]

Wolfram Language code: Plot[{Hypergeometric1F1[Sqrt[3], Sqrt[2], z], -0.01}, {z, -10, -2}]

は全射ではない：

Wolfram Language code: FunctionSurjective[{Hypergeometric1F1[1, 2, z]}, z]

Wolfram Language code: Plot[{Hypergeometric1F1[1, 2, z], -2}, {z, -5, 5}]

Hypergeometric1F1は特定の値について非負である：

Wolfram Language code: FunctionSign[Hypergeometric1F1[1 / 2, 1 / 2, z], z]

Wolfram Language code: Plot[Hypergeometric1F1[1 / 2, 1 / 2, z], {z, -2, 5}]

は非負でも非正でもない：

Wolfram Language code: FunctionSign[Hypergeometric1F1[Sqrt[3], Sqrt[2], z], z]

はが負の整数のときに特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[Hypergeometric1F1[a, b, z], {a, b, z}]

Wolfram Language code: FunctionDiscontinuities[Hypergeometric1F1[a, b, z], {a, b, z}]

は凸である：

Wolfram Language code: FunctionConvexity[Hypergeometric1F1[-2, 1, z], z]

は凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Hypergeometric1F1[2, 1, z], z]

TraditionalFormによる表示：

Wolfram Language code: Hypergeometric1F1[a, b, z]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[Hypergeometric1F1[a, b, x], x]

高次導関数：

Wolfram Language code: derivs = Table[D[Hypergeometric1F1[a, b, x], {x, n}], {n, 1, 3}]//FullSimplify

高次導関数をとについてプロットする：

Wolfram Language code:

Plot[Evaluate[derivs /. {a -> 1 / 2, b -> Sqrt[2]}], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

次導関数の式：

Wolfram Language code: D[Hypergeometric1F1[a, b, x], {x, n}]

積分 (3)

IntegrateをHypergeometric1F1に適用する：

Wolfram Language code: Integrate[Hypergeometric1F1[a, b, x], x]//FullSimplify

Hypergeometric1F1の定積分：

Wolfram Language code: Integrate[Hypergeometric1F1[1, Sqrt[2], x], {x, 0, 1}]

その他の積分例：

Wolfram Language code: Integrate[t ^ (α - 1)Hypergeometric1F1[a, b, -t], {t, 0, Infinity}, Assumptions -> 0 < Re[α] < Re[a]]

Wolfram Language code: Integrate[Exp[-x]Hypergeometric1F1[a, b, x], x]//FullSimplify

級数展開 (4)

Hypergeometric1F1のテイラー(Taylor)展開：

Wolfram Language code: Series[Hypergeometric1F1[a, b, x], {x, 0, 4}]

の周りのの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[Hypergeometric1F1[1 / 2, Sqrt[2], x], {x, 0, m}], {m, 1, 3}];
Plot[{Hypergeometric1F1[1 / 2, Sqrt[2], x], terms}, {x, -3, 3}]

Hypergeometric1F1の級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Hypergeometric1F1[a, b, x], {x, 0, n}]

無限大の周りの級数においてHypergeometric1F1を展開する：

Wolfram Language code: Series[Hypergeometric1F1[1 / 3, 2 / 3, z], {z, Infinity, 2}]

Hypergeometric1F1をベキ級数に適用する：

Wolfram Language code: Hypergeometric1F1[1 / 7, 3 / 7, Log[1 + z] + O[z] ^ 5]

積分変換 (2)

LaplaceTransformを使ってラプラス(Laplace)変換を計算する：

Wolfram Language code: LaplaceTransform[Hypergeometric1F1[a, b, -t], t, s]

HankelTransform：

Wolfram Language code: HankelTransform[Hypergeometric1F1[a, b, -r], r, s ]//FullSimplify

関数の恒等式と簡約 (3)

引数の簡約：

Wolfram Language code: Exp[z]Hypergeometric1F1[a, b, -z]//FullSimplify

Hypergeometric1F1関数の総和：

Wolfram Language code:

Hypergeometric1F1[a, b, z] + (Gamma[a - b + 1]Gamma[b - 1]/Gamma[a]Gamma[1 - b])z^1 - b Hypergeometric1F1[a - b + 1, 2 - b, z]//FullSimplify

再帰関係：

Wolfram Language code:

Hypergeometric1F1[a, b, z] == (2 + 2 a - b + z/1 + a - b)Hypergeometric1F1[1 + a, b, z] - (a + 1/1 + a - b) Hypergeometric1F1[2 + a, b, z]//FullSimplify

関数表現 (4)

主定義：

Wolfram Language code: Underoverscript[∑, k = 0, ∞](Pochhammer[a, k]z^k/ Pochhammer[b, k]k!)

LaguerreL多項式との関係：

Wolfram Language code: Hypergeometric1F1[a, b, z] == (Gamma[1 - a]Gamma[b]/Gamma[b - a])LaguerreL[-a, b - 1, z]//FullSimplify

Hypergeometric1F1はDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[Hypergeometric1F1[a, b, x], x]

Hypergeometric1F1はMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[Hypergeometric1F1[a, b, x], x]

Wolfram Language code: Activate[%]//FullSimplify

一般化と拡張 (1)

Hypergeometric1F1をベキ級数に適用する：

Wolfram Language code: Hypergeometric1F1[1 / 7, 3 / 7, Log[1 + z] + O[z] ^ 5]

アプリケーション (3)

連続スペクトルについての水素原子の動径波動関数：

Wolfram Language code: ψ[ℰ_, l_, r_] := With[{k = Sqrt[ℰ]}, Exp[-I k r]r ^ l Hypergeometric1F1[I / k + (1 + l), 2 + 2 l, 2 I r k]]

微分方程式からエネルギー固有値を計算する：

Wolfram Language code: -((D[#, r, r]/#) + (2/r #)D[#, r] - (l(l + 1)/r^2) + (2/r))&[ψ[ℰ, l, r]]//FullSimplify

任意次数でのExpのパデ(Padé)近似の閉じた形：

Wolfram Language code: Table[(Hypergeometric1F1[-i, -i - j, z]/Hypergeometric1F1[-j, -i - j, -z]), {i, 2}, {j, 2}]

明示的な近似と比較する：

Wolfram Language code: Table[PadeApproximant[Exp[z], {z, 0, {i, j}}], {i, 2}, {j, 2}]

微分方程式を解く：

Wolfram Language code: DSolve[f''[r] + ((1/r) - 2r)f'[r] + (1 - (4/r^2))f[r] == 0, f[r], r]

特性と関係 (2)

IntegrateはHypergeometric1F1を含む結果を返すことがある：

Wolfram Language code: Integrate[t^a (Exp[-t]/Sqrt[1 + t]), {t, 0, Infinity}, Assumptions -> a > 0]

FunctionExpandを使って合流型超幾何関数に変換する：

Wolfram Language code: WhittakerM[m, k, x]//FunctionExpand

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Hypergeometric1F1

詳細

例題

例 (5)

スコープ (40)

数値評価 (5)

特定の値 (4)

可視化 (3)

関数の特性 (9)

微分 (3)

積分 (3)

級数展開 (4)

積分変換 (2)

関数の恒等式と簡約 (3)

関数表現 (4)

一般化と拡張 (1)

アプリケーション (3)

特性と関係 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

Hypergeometric1F1

詳細

例題

例 (5)

スコープ (40)

数値評価 (5)

特定の値 (4)

可視化 (3)

関数の特性 (9)

微分 (3)

積分 (3)

級数展開 (4)

積分変換 (2)

関数の恒等式と簡約 (3)

関数表現 (4)

一般化と拡張 (1)

アプリケーション (3)

特性と関係 (2)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX