KroneckerProduct

KroneckerProduct[m₁,m₂,…]

配列 m_iのクロネッカー(Kronecker)積を構築する．

詳細

KroneckerProductは，ベクトル，行列，あるいは一般に任意の深さの完全配列に使うことができる．
行列の場合，KroneckerProductは行列の直積を与える．
KroneckerProductはSparseArrayオブジェクトに使うこともできる．その場合は，可能であればSparseArrayオブジェクトを返す． »

例題

すべて開くすべて閉じる

例 (2)

ベクトルのクロネッカー積：

Wolfram Language code:

av = Array[Subscript[a, ##]&, {2}];
bv = Array[Subscript[b, ##]&, {2}];

Wolfram Language code: KroneckerProduct[av, bv]//MatrixForm

行列のクロネッカー積：

Wolfram Language code:

am = Array[Subscript[a, ##]&, {2, 2}];
bm = Array[Subscript[b, ##]&, {2, 2}];

Wolfram Language code: KroneckerProduct[am, bm]//MatrixForm

スコープ (2)

a と b は厳密項を持つ行列である：

Wolfram Language code:

a = {{0, 1}, {-1, 0}};
b = {{1, 2}, {3, 4}};

厳密演算でクロネッカー積を計算する：

Wolfram Language code: MatrixForm[KroneckerProduct[a, b]]

機械演算を使う：

Wolfram Language code: MatrixForm[KroneckerProduct[N[a], N[b]]]

20桁精度演算を使う：

Wolfram Language code: MatrixForm[KroneckerProduct[N[a, 20], N[b, 20]]]

s と t は疎行列である：

Wolfram Language code:

s = SparseArray[{i_, i_} -> i, {3, 3}];
t = SparseArray[{{i_, j_} /; Abs[i - j] == 1 -> i - j}, {4, 4}];

疎なクロネッカー積を計算する：

Wolfram Language code: KroneckerProduct[s, t]

Wolfram Language code: MatrixForm[%]

アプリケーション (5)

平坦化（ベクトル化）関係Flatten[a.x.b]=(ab^).Flatten[x]を使うことで，一般的な線形行列方程式 a₁.x.b₁+⋯+a_m.x.b_m=c を行列について解く：

Wolfram Language code: {Subscript[a, 1], Subscript[a, 2], Subscript[b, 1], Subscript[b, 2], c} = RandomReal[1, {5, 2, 2}];

Wolfram Language code:

x = Partition[LinearSolve[KroneckerProduct[Subscript[a, 1], Subscript[b, 1]] + KroneckerProduct[Subscript[a, 2], Subscript[b, 2]], Flatten[c]], 2]

Wolfram Language code: Subscript[a, 1].x.Subscript[b, 1] + Subscript[a, 2].x.Subscript[b, 2] - c//Chop

転換行列とも呼ばれるvec置換行列を定義する：

Wolfram Language code: vecPermutationMatrix[p_, q_] := PermutationMatrix[Flatten[Partition[Range[p q], p], {{2, 1}}]]

vec置換行列を可視化する：

Wolfram Language code:

p = 5;q = 3;
ArrayPlot[vecPermutationMatrix[p, q]]

vec置換行列は，単位ベクトルを持つ恒等行列のクロネッカー積の和として表すことができる：

Wolfram Language code:

vecPermutationMatrix[p, q] == Underoverscript[∑, k = 1, p]KroneckerProduct[UnitVector[p, k], IdentityMatrix[q], UnitVector[p, k]]

2つの記号行列を生成する：

Wolfram Language code:

p = 6;q = 5;
MatrixForm[m1 = Array[, {p, q}]]

Wolfram Language code:

r = 4;s = 3;
MatrixForm[m2 = Array[, {r, s}]]

vec置換行列を使って与えられた2つの行列のクロネッカー積と同じ行列の逆順のクロネッカー積の関係が表現できる：

Wolfram Language code: KroneckerProduct[m1, m2].vecPermutationMatrix[q, s] == vecPermutationMatrix[p, r].KroneckerProduct[m2, m1]

s は一次元で二次導関数を近似している微分行列である：

Wolfram Language code:

n = 4;
s = SparseArray[{Band[{2, 1}] -> 1, Band[{1, 1}] -> -2, Band[{1, 2}] -> 1}, {n, n}]

Wolfram Language code: s.Array[Subscript[u, #]&, n]

疎行列としての単位行列：

Wolfram Language code: sid = IdentityMatrix[n, SparseArray, WorkingPrecision -> MachinePrecision]

値の二次元配列：

Wolfram Language code: MatrixForm[v = Array[Subscript[u, ##]&, {n, n}]]

一次元のみを微分する行列：

Wolfram Language code: m1 = KroneckerProduct[s, sid]

Wolfram Language code: Partition[m1.Flatten[v], n][[2 ;; -2, 2 ;; -2]]//MatrixForm

ラプラシアン（微分行列とそれ自体のクロネッカー和）を近似する行列：

Wolfram Language code: lap = KroneckerProduct[s, sid] + KroneckerProduct[sid, s]

Wolfram Language code: Partition[lap.Flatten[v], n][[2 ;; -2, 2 ;; -2]]//MatrixForm

偶数の n について n×n の「蝶々」行列を定義する：

Wolfram Language code:

Subscript[b, n_] := Module[{h = Quotient[n, 2], id, w}, 
	id  = IdentityMatrix[h];
	 w = DiagonalMatrix[Exp[-π I Range[0, h - 1] / h]];
	ArrayFlatten[{{id, w}, {id, -w}}]
	]

2のベキ乗についての n の n×n の「ビット逆転」置換行列を定義する：

Wolfram Language code: Subscript[p, n_] := PermutationMatrix[IntegerReverse[Range[0, n - 1], 2, BitLength[n] - 1] + 1]

大きさ n の単位行列の簡潔な表記：

Wolfram Language code: Subscript[i, n_] := IdentityMatrix[n];

クロネッカー積の簡潔な表記：

Wolfram Language code: a_⊗b_ := KroneckerProduct[a, b]

Cooley-Tukey因数分解からの長さ16の離散フーリエ変換行列を形成する：

Wolfram Language code:

Subscript[f, 16] = Subscript[b, 16].(Subscript[i, 2]⊗ Subscript[b, 8]).(Subscript[i, 4]⊗ Subscript[b, 4]).(Subscript[i, 8]⊗ Subscript[b, 2]).Subscript[p, 16];

これはFourierMatrixの結果と同じである：

Wolfram Language code: Subscript[f, 16] == FourierMatrix[16, FourierParameters -> {1, -1}]

r は長さ16のランダムベクトルである：

Wolfram Language code: r = RandomReal[1, 16]

r の離散フーリエ変換：

Wolfram Language code: N[Subscript[f, 16].r]

Fourierは特定のベクトルについて効果的に因数分解を行うので高速である：

Wolfram Language code: Fourier[r, FourierParameters -> {1, -1}]

クロネッカー和を定義する：

Wolfram Language code:

KroneckerSum[a_ ? SquareMatrixQ, b_ ? SquareMatrixQ] := 
	KroneckerProduct[a, IdentityMatrix[Length[b], If[SparseArrayQ[a], SparseArray, List]]] + 
	KroneckerProduct[IdentityMatrix[Length[a], If[SparseArrayQ[b], SparseArray, List]], b]

一般的な記号行列に上記を使う：

Wolfram Language code: am = Array[Subscript[a, ##]&, {2, 2}];bm = Array[Subscript[b, ##]&, {2, 2}];

Wolfram Language code: KroneckerSum[am, bm]//MatrixForm

恒等式MatrixExp[a⊕b]=MatrixExp[a]⊗MatrixExp[b]を確かめる：

Wolfram Language code: {a, b} = RandomReal[1, {2, 3, 3}];

Wolfram Language code: MatrixExp[KroneckerSum[a, b]] == KroneckerProduct[MatrixExp[a], MatrixExp[b]]

Eigenvalues[a⊕b]={λ_i+μ_j|λ_i∈Eigenvalues[a],μ_j∈Eigenvalues[b]}を確かめる：

Wolfram Language code:

λa = Eigenvalues[a];
λb = Eigenvalues[b];
λab = Eigenvalues[KroneckerSum[a, b]];

Wolfram Language code: Sort[λab] == Sort[Flatten@Outer[Plus, λa, λb]]

特性と関係 (11)

KroneckerProductは多重線形（各引数について線形）のである：

Wolfram Language code:

{a, b, c} = RandomInteger[5, {3, 2, 4}];
{λ, μ} = {3, 4};

Wolfram Language code:

KroneckerProduct[λ a + μ b, c] == 
	λ KroneckerProduct[a, c] + μ KroneckerProduct[b, c]

Wolfram Language code:

KroneckerProduct[a, λ b + μ c] == 
	λ KroneckerProduct[a, b] + μ KroneckerProduct[a, c]

結合（平坦）：

Wolfram Language code:

KroneckerProduct[KroneckerProduct[a, b], c] == 
	KroneckerProduct[a, KroneckerProduct[b, c]]

非可換：

Wolfram Language code: KroneckerProduct[a, b] == KroneckerProduct[b, a]

KroneckerProductは混合積特性を満たす：

Wolfram Language code: {a, b, c, d} = RandomInteger[5, {4, 3, 3}];

Wolfram Language code:

KroneckerProduct[a, b].KroneckerProduct[c, d] == 
	KroneckerProduct[a.c, b.d]

Transposeによる分配：

Wolfram Language code: KroneckerProduct[a, b] == KroneckerProduct[a, b]

ConjugateTransposeによる分配：

Wolfram Language code: KroneckerProduct[a, b] == KroneckerProduct[a, b]

Inverseによる分配（とが可逆である場合かつその場合にのみ）：

Wolfram Language code: a = {{1, 2}, {0, 1}}; b = {{2, 1}, {0, 3}};

Wolfram Language code: Inverse[KroneckerProduct[a, b]] == KroneckerProduct[Inverse[a], Inverse[b]]

PseudoInverseによる分配PseudoInverse[ab]=PseudoInverse[a]PseudoInverse[b]：

Wolfram Language code: a = {{1, 2}, {0, 0}}; b = {{0, 1}, {0, 3}};

Wolfram Language code: PseudoInverse[KroneckerProduct[a, b]] == KroneckerProduct[PseudoInverse[a], PseudoInverse[b]]

クロネッカー積のトレースTrはTr[ab]=Tr[a]Tr[b]を満たす：

Wolfram Language code: a = RandomInteger[10, {3, 3}];b = RandomInteger[10, {4, 4}];

Wolfram Language code: Tr[KroneckerProduct[a, b]] == Tr[a]Tr[b]

行列式Detは $TemplateBox[{{a, , b}}, Det]=TemplateBox[{a}, Det]^n TemplateBox[{b}, Det]^m$ を満たす．ただし，a∈Matrices[{m,m}]かつ b∈Matrices[{n,n}]である：

Wolfram Language code: Det[KroneckerProduct[a, b]] == Det[a]^4Det[b]^3

EigenvaluesはEigenvalues[ab]={λ_iμ_j|λ_i∈Eigenvalues[a],μ_j∈Eigenvalues[b]}を満足する：

Wolfram Language code: a = RandomReal[1, {3, 3}];b = RandomReal[1, {4, 4}];

Wolfram Language code:

λa = Eigenvalues[a];
λb = Eigenvalues[b];
λab = Eigenvalues[KroneckerProduct[a, b]];

Wolfram Language code: Sort[λab] == Sort[Flatten@Outer[Times, λa, λb]]

SingularValueListは同じ関係を満たす：

Wolfram Language code:

σa = SingularValueList[a];
σb = SingularValueList[b];
σab = SingularValueList[KroneckerProduct[a, b]];

Wolfram Language code: Sort[σab] == Sort[Flatten@Outer[Times, σa, σb]]

MatrixRankはMatrixRank[ab]=MatrixRank[a]MatrixRank[b]を満たす：

Wolfram Language code: MatrixRank[KroneckerProduct[a, b]] == MatrixRank[a]MatrixRank[b]

行列についてのKroneckerProductはブロックがの平坦化されたブロック行列である：

Wolfram Language code: am = {{1, 2}, {3, 4}};bm = {{5, 6}, {7, 8}, {9, 10}};

Wolfram Language code:

KroneckerProduct[am, bm] == 
	ArrayFlatten@Table[am[[i, j]] * bm, {i, 2}, {j, 2}]

ベクトルのKroneckerProductは対応する列行列のDotに関連している：

Wolfram Language code:

av = {1, 2, 3}; bv = {4, 5};
am = {av}; bm = {bv};

列行列と行行列のドット積は，一般に外積とも呼ばれる：

Wolfram Language code: KroneckerProduct[av, bv] == am.bm

ベクトルのKroneckerProductはTensorProductと等価である：

Wolfram Language code: av = {1, 2, 3}; bv = {4, 5};

Wolfram Language code: KroneckerProduct[av, bv] == TensorProduct[av, bv]

行列については平坦化されたテンソル積である：

Wolfram Language code: am = {{1, 2}, {3, 4}};bm = {{5, 6}, {7, 8}, {9, 10}};

Wolfram Language code: KroneckerProduct[am, bm] == ArrayFlatten[TensorProduct[am, bm]]

ベクトルのKroneckerProductはOuterの特殊ケースである：

Wolfram Language code: av = {1, 2, 3}; bv = {4, 5};

Wolfram Language code: KroneckerProduct[av, bv] == Outer[Times, av, bv]

行列については平坦化された外積である：

Wolfram Language code: am = {{1, 2}, {3, 4}};bm = {{5, 6}, {7, 8}, {9, 10}};

Wolfram Language code: KroneckerProduct[am, bm] == ArrayFlatten[Outer[Times, am, bm]]

対角行列と一般行列のクロネッカー積はブロック対角行列である：

Wolfram Language code:

dm = DiagonalMatrix[Array[Subscript[d, #]&, 2]];
bm = Array[Subscript[b, ##]&, {2, 2}];

Wolfram Language code: BlockDiagonalMatrix[KroneckerProduct[dm, bm]]

Wolfram Language code: MatrixForm[%]

下三角行列と一般行列のクロネッカー積はブロック下三角行列である：

Wolfram Language code:

lm = LowerTriangularMatrix[LowerTriangularize[Array[Subscript[ℓ, #]&, {2, 2}]]];
bm = Array[Subscript[b, ##]&, {2, 2}];

Wolfram Language code: KroneckerProduct[lm, bm]

Wolfram Language code: MatrixForm[%]

上三角行列と一般行列のクロネッカー積はブロック上三角行列である：

Wolfram Language code:

um = UpperTriangularMatrix[UpperTriangularize[Array[Subscript[u, #]&, {2, 2}]]];
bm = Array[Subscript[b, ##]&, {2, 2}];

Wolfram Language code: KroneckerProduct[um, bm]

Wolfram Language code: MatrixForm[%]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

KroneckerProduct

詳細

例題

例 (2)

スコープ (2)

アプリケーション (5)

特性と関係 (11)

テキスト

CMS

APA

BibTeX

BibLaTeX

KroneckerProduct

詳細

例題

例 (2)

スコープ (2)

アプリケーション (5)

特性と関係 (11)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX