WOLFRAM

Wolfram 语言与系统参考资料中心

LogitModelFit[{{x1,y1},{x2,y2},…},{f1,f2,…},x]

构建形为 的二项式逻辑回归模型，拟合每个 xi 的 yi.

LogitModelFit[data,{f1,…},{x1,x2,…}]

构建一个二项式逻辑回归模型，形式为 ，其中 fi 与变量 xk 相关.

LogitModelFit[{m,v}]

从设计矩阵 m 和响应向量 v 构建一个二项式逻辑回归模型.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
数据  
属性  
数据与拟合函数  
残差  
离差和偏差  
参数估计诊断  
影响度量  
预测值  
拟合优度度量  
推广和延伸  
选项  
ConfidenceLevel  
CovarianceEstimatorFunction  
DispersionEstimatorFunction  
Show More Show More
IncludeConstantBasis  
LinearOffsetFunction  
NominalVariables  
Weights  
WorkingPrecision  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

LogitModelFit

LogitModelFit[{{x1,y1},{x2,y2},…},{f1,f2,…},x]

构建形为 的二项式逻辑回归模型，拟合每个 xi 的 yi.

LogitModelFit[data,{f1,…},{x1,x2,…}]

构建一个二项式逻辑回归模型，形式为 ，其中 fi 与变量 xk 相关.

LogitModelFit[{m,v}]

从设计矩阵 m 和响应向量 v 构建一个二项式逻辑回归模型.

更多信息和选项

  • LogitModelFit 尝试使用由逻辑 S 型函数组成的基函数的线性组合来对数据建模.
  • LogitModelFit 通常在分类中使用，用来模拟概率值.
  • LogitModelFit 给出形为 的通用线性模型，假定原始的 是概率为 的伯努利试验的独立实现.
  • 函数 为 LogisticSigmoid.
  • LogitModelFit 返回一个符号 FittedModel 对象，表示构建的逻辑模型. 模型的属性和诊断可以从 model["property"] 得到.
  • LogitModelFit 在特定点 x1、… 的最佳拟合函数的值可以从 model[x1,…] 求出.
  • data 的可能的形式为：
  • {y1,y2,…}与形式 {{1,y1},{2,y2},…} 等价
    {{x11,x12,…,y1},…}独立值 xij 列表和响应 yi
    {{x11,x12,…}y1,…}输入值和响应构成的规则列表
    {{x11,x12,…},…}{y1,y2,…}输入值列表和响应构成的规则
    {{x11,…,y1,…},…}n拟合矩阵的第 n 列
    Tabular[…]name拟合表格对象中名为 name 的列
  • 在多元数据的情况下，如 {{x_(11),x_(12),... ,y_(1)},{x_(21),x_(22),... ,y_(2)},...}，坐标 xi1、xi2、… 的数量应等于变量 xi 的数量.
  • yi 的概率位于 0 和 1 之间.
  • 另外，可用设计矩阵指定 data，不指定函数和变量：
  • {m,v}设计矩阵 m 和响应向量 v
  • 在 LogitModelFit[{m,v}] 中，设计矩阵 m 根据在点 {{f1,f2,…},{f1,f2,…},…} 的基函数 fi 形成. 响应向量 v 是响应列表 {y1,y2,…}.
  • 对于一个设计矩阵 m 和响应向量 v，模型是 ，其中 是估计参数的向量.
  • 当使用一个设计矩阵，基函数 fi 可以用形式 LogitModelFit[{m,v},{f1,f2,…}] 指定.
  • LogitModelFit 等价于 GeneralizedLinearModelFit，其中 ExponentialFamily->"Binomial" 和 LinkFunction->Automatic.
  • LogitModelFit 采用和 GeneralizedLinearModelFit 相同的选项，除了 ExponentialFamily 和 LinkFunction.

范例

打开所有单元 关闭所有单元

基本范例  (1)

定义一个数据集：

Wolfram Language code: data = {{1, 0}, {2, 0}, {2, 0}, {2, 1}, {2, 0}, {3, 0}, {3, 0}, {3, 0}, {3, 1}, {3, 1}, {3, 1}, {4, 1}, {4, 1}, {5, 0}, {6, 1}, {7, 1}};

拟合一个逻辑模型：

Wolfram Language code: logit = LogitModelFit[data, x, x]

计算在某个点的模型：

Wolfram Language code: logit[1.5]

绘制数据点和模型：

Wolfram Language code: Show[ListPlot[data, PlotStyle -> PointSize[Medium]], Plot[logit[x], {x, 0, 8}]]

范围  (13)

数据  (6)

假设增大的整数独立数值，拟合含有连续概率响应的数据：

Wolfram Language code: LogitModelFit[{1 / 3, 2 / 3, 5 / 5}, x, x]//Normal

这相当于：

Wolfram Language code: LogitModelFit[{{1, 1 / 3}, {2, 2 / 3}, {3, 5 / 5}}, x, x]//Normal

每个预期值的观察数量的权：

Wolfram Language code: LogitModelFit[{{1, 1 / 3}, {2, 2 / 3}, {3, 5 / 5}}, x, x, Weights -> {3, 6, 5}]//Normal

以下给出相同的最佳拟合函数：

Wolfram Language code: sfdata = {{1, 0}, {1, 1}, {1, 0}, {2, 0}, {2, 0}, {2, 1}, {2, 1}, {2, 1}, {2, 1}, {3, 1}, {3, 1}, {3, 1}, {3, 1}, {3, 1}}; GroupBy[sfdata, First -> Last]
Wolfram Language code: LogitModelFit[sfdata, x, x] //Normal

拟合规则列表：

Wolfram Language code: LogitModelFit[{1 -> 1 / 3, 2 -> 2 / 3, 3 -> 3 / 3}, x, x]

拟合输入值和响应构成的规则：

Wolfram Language code: LogitModelFit[{1, 2, 3} -> {1 / 3, 2 / 3, 3 / 3}, x, x]

指定一列数据作为响应：

Wolfram Language code: data = {...};
Wolfram Language code: fit = LogitModelFit[data -> 1, {1, x, y}, {x, y}]
Wolfram Language code: Show[ Plot3D[fit[x, y], {x, -5, 5}, {y, -5, 5}], ListPointPlot3D[data[[All, {2, 3, 1}]]], PlotRange -> All ]

拟合一个设计矩阵和响应向量给出的模型：

Wolfram Language code: dm = {{1, 1}, {1, 2}, {1, 3}, {1, 4}}; resp = {0, 1, 0, 1};LogitModelFit[{dm, resp}]

查看函数形式：

Wolfram Language code: Normal[%]

拟合涉及 x 和 y 的基函数的模型：

Wolfram Language code: LogitModelFit[{dm, resp}, {x, y}]//Normal

获取现有属性列表：

Wolfram Language code: logit = LogitModelFit[RandomReal[1, 10], x, x]
Wolfram Language code: logit["Properties"]

属性  (7)

数据与拟合函数  (1)

拟合一个逻辑模型：

Wolfram Language code: data = Join[RandomReal[10, {10, 2}], Transpose[{RandomReal[1, 10]}], 2];
Wolfram Language code: logit = LogitModelFit[data, {x, y}, {x, y}]

提取原数据：

Wolfram Language code: logit["Data"]

得到并绘制最佳拟合：

Wolfram Language code: fit = logit["BestFit"]
Wolfram Language code: Show[Plot3D[fit, {x, 0, 10}, {y, 0, 10}], Graphics3D[{PointSize[0.025], Point[logit["Data"]]}]]

得到纯函数形式的拟合函数：

Wolfram Language code: logit["Function"]

得到拟合的设计矩阵和响应向量：

Wolfram Language code: MatrixForm /@ logit[{"DesignMatrix", "Response"}]

残差  (1)

检查拟合的残差：

Wolfram Language code: data = Join[RandomReal[10, {100, 2}], Transpose[{RandomReal[1, 100]}], 2];
Wolfram Language code: logit = LogitModelFit[data, {x, y}, {x, y}]
Wolfram Language code: {fr, ar, spr} = logit[{"FitResiduals", "StandardizedPearsonResiduals", "AnscombeResiduals"}];

可视化显示原残差：

Wolfram Language code: ListPlot[fr]

在图形中可视化显示 Anscombe 残差和标准化 Pearson 残差：

Wolfram Language code: Map[ListPlot[#, Filling -> 0]&, {ar, spr}]

离差和偏差  (1)

对某些数据拟合一个逻辑模型：

Wolfram Language code: SeedRandom[1]; data = Flatten[Table[{x, y, 1 / (1 + Exp[.2 + .3x + .1y + RandomReal[{-1, 1}]])}, {x, RandomReal[5, 10]}, {y, RandomReal[5, 10]}], 1];logit = LogitModelFit[data, {x, y}, {x, y}]

缺省下估计的离差是 1：

Wolfram Language code: logit["EstimatedDispersion"]

用 Pearson 作为离差估计：

Wolfram Language code: logit["EstimatedDispersion", DispersionEstimatorFunction -> "PearsonChiSquare"]

绘制每个点的异常：

Wolfram Language code: ListPlot[logit["Deviances"], Filling -> 0]

分析偏差表：

Wolfram Language code: logit["DevianceData"]

从表格得到残差异常：

Wolfram Language code: logit["DevianceData"][All, "ResidualDeviance"]//Normal

参数估计诊断  (1)

从参数信息中得到一个格式化的表：

Wolfram Language code: SeedRandom[1]; data = Table[{i, RandomInteger[BinomialDistribution[20, .05 + i / 30 + Sin[i] / 10]] / 20}, {i, 1, 20, .2}]; logit = LogitModelFit[data, {x, Sin[x], Cos[x]}, x];
Wolfram Language code: logit["ParameterEstimates"]

提取 -统计值的列：

Wolfram Language code: logit["ParameterEstimates"][All, "ZStatistic"]//Normal

影响度量  (1)

在逻辑模型中拟合包含极值的某些数据：

Wolfram Language code: SeedRandom[3];data = Table[{i, 1 / (1 + Exp[2 + 4i - Log[i] + RandomReal[]])}, {i, RandomReal[{1, 10}, 20]}]; data[[{3, 8}, -1]] = 1 - data[[{3, 8}, -1]];
Wolfram Language code: ListPlot[data]
Wolfram Language code: logit = LogitModelFit[data, {x, Log[x]}, x]

检查库克距离，识别更高的影响点：

Wolfram Language code: ListPlot[logit["CookDistances"], PlotRange -> {0, All}, Filling -> 0]

检查帽子矩阵的对角元素，估计拟合的数据点的影响：

Wolfram Language code: ListPlot[logit["HatDiagonal"], PlotRange -> {0, All}, Filling -> 0]

预测值  (1)

拟合一个逻辑模型：

Wolfram Language code: SeedRandom[3];data = Flatten[Table[{x, y, 1 / (1 + Exp[.3x - .5y + RandomReal[{-1, 1}]])}, {x, RandomReal[5, 3]}, {y, RandomReal[5, 3]}], 1];logit = LogitModelFit[data, {x, y}, {x, y}]

绘制与观察值对应的预期值：

Wolfram Language code: ListPlot[Transpose[logit[{"Response", "PredictedResponse"}]], FrameLabel -> {"observed", "predicted"}, Frame -> True, Axes -> False]

拟合优度度量  (1)

得到一个逻辑模型的拟合优度度量的表格：

Wolfram Language code: SeedRandom[3];data = Flatten[Table[{i, j, RandomReal[10], 1 / (1 + Exp[30i - 10j + RandomReal[5]])}, {i, RandomReal[10, 5]}, {j, RandomReal[10, 5]}], 1];
Wolfram Language code: logit = LogitModelFit[data, {x, y, z}, {x, y, z}]
Wolfram Language code: Grid[Transpose[{#, logit[#]}&[{"AIC", "BIC", "LikelihoodRatioIndex", "PearsonChiSquare"}]], Alignment -> Left]

计算所有预期变量的子集的拟合优度度量：

Wolfram Language code: sub = Table[Join[{i}, LogitModelFit[data, i, {x, y, z}][{"AIC", "BIC", "LikelihoodRatioIndex", "PearsonChiSquare"}]], {i, Subsets[{x, y, z}]}]

按 AIC 将模型排序：

Wolfram Language code: Grid[Join[{{"Model", "AIC", "BIC", "LikelihoodRatioIndex", "PearsonChiSquare"}}, SortBy[sub, -#[[2]]&]]]

推广和延伸  (1)

在模型的函数形式上执行其它的数学操作：

Wolfram Language code: logit = LogitModelFit[Table[{i, RandomReal[{i - 1, i}] / 10}, {i, 10}], x, x]

符号积分和数值积分：

Wolfram Language code: Integrate[logit[x], x]
Wolfram Language code: NIntegrate[logit[x], {x, 1, 5}]

求出一个预期值，给出模型的一个特定值：

Wolfram Language code: FindRoot[logit[x] == .5, {x, 5}]

选项  (8)

ConfidenceLevel  (1)

缺省给出 95% 置信区间：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 1}, {5, 0}};
Wolfram Language code: logit = LogitModelFit[data, x, x]
Wolfram Language code: logit["ParameterEstimates"][All, "ConfidenceInterval"]//Normal

用 99% 的置信区间：

Wolfram Language code: logit = LogitModelFit[data, x, x, ConfidenceLevel -> .99]
Wolfram Language code: logit["ParameterEstimates"][All, "ConfidenceInterval"]//Normal

在 FittedModel 中设置级别为 90%：

Wolfram Language code: logit["ParameterEstimates", ConfidenceLevel -> .9][All, "ConfidenceInterval"]//Normal

CovarianceEstimatorFunction  (1)

拟合一个逻辑模型：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 1}, {5, 0}};
Wolfram Language code: logit = LogitModelFit[data, x, x]

用预期的信息矩阵计算协方差矩阵：

Wolfram Language code: logit["CovarianceMatrix"]

用观察信息矩阵：

Wolfram Language code: logit["CovarianceMatrix", CovarianceEstimatorFunction -> "ObservedInformation"]

DispersionEstimatorFunction  (1)

拟合一个逻辑模型：

Wolfram Language code: data = {{1, 0}, {1, 1}, {1, 1}, {2, 0}, {2, 0}, {2, 1}, {2, 1}, {2, 1}, {2, 1}};
Wolfram Language code: logit = LogitModelFit[data, x, x]

计算协方差矩阵：

Wolfram Language code: logit["CovarianceMatrix"]

计算协方差矩阵，估计 Pearson 的散布：

Wolfram Language code: logit["CovarianceMatrix", DispersionEstimatorFunction -> "PearsonChiSquare"]

IncludeConstantBasis  (1)

拟合一个逻辑模型：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 1}, {5, 0}};
Wolfram Language code: LogitModelFit[data, x, x]//Normal

拟合有零常数项的模型：

Wolfram Language code: LogitModelFit[data, x, x, IncludeConstantBasis -> False]//Normal

LinearOffsetFunction  (1)

拟合一个逻辑模型：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 1}, {5, 0}};
Wolfram Language code: LogitModelFit[data, x, x]//Normal

拟合有已知 Sqrt[x] 常数项的模型：

Wolfram Language code: LogitModelFit[data, x, x, LinearOffsetFunction -> (Sqrt[#]&)]//Normal

NominalVariables  (1)

Wolfram Language code: data = {{a, 0, 0}, {b, 2, 1}, {a, 2, 0}, {b, 0, 1}, {a, 2, 1}, {b, 0, 0}};

拟合数据，将第一个变量视为一个名义变量：

Wolfram Language code: nom = LogitModelFit[data, {x, y}, {x, y}, NominalVariables -> x]
Wolfram Language code: Normal[nom]

将两个变量视为名义变量：

Wolfram Language code: LogitModelFit[data, {x, y}, {x, y}, NominalVariables -> All]//Normal

Weights  (1)

用相等权拟合一个模型：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 1}, {5, 0}};
Wolfram Language code: LogitModelFit[data, x, x]//Normal

对于数据点给出明确的权：

Wolfram Language code: LogitModelFit[data, x, x, Weights -> {1, (1/2), (1/3), (1/4)}]//Normal

WorkingPrecision  (1)

用 WorkingPrecision 在参数估计中得到更高的精度：

Wolfram Language code: data = Table[{x, (10 - x) / 10}, {x, 10}]
Wolfram Language code: logit = LogitModelFit[data, x, x, WorkingPrecision -> 30]

得到拟合函数：

Wolfram Language code: logit["BestFit"]

在拟合后，化简属性计算中的精度：

Wolfram Language code: logit["BestFit", WorkingPrecision -> MachinePrecision]

属性和关系  (4)

GeneralizedLinearModelFit 中一个缺省的 "Binomial" 模型等价于 LogitModelFit 的模型：

Wolfram Language code: data = Table[{i, RandomReal[{i - 1, i}] / 10}, {i, 10}];
Wolfram Language code: GeneralizedLinearModelFit[data, x, x, ExponentialFamily -> "Binomial"]//Normal
Wolfram Language code: LogitModelFit[data, x, x]//Normal

ProbitModelFit 等价于有 "ProbitLink" 的一个 "Binomial" 模型：

Wolfram Language code: GeneralizedLinearModelFit[data, x, x, ExponentialFamily -> "Binomial", LinkFunction -> "ProbitLink"]//Normal
Wolfram Language code: ProbitModelFit[data, x, x]//Normal

LogitModelFit 假设二项分布响应：

Wolfram Language code: data = Table[{i, RandomReal[{i - 1, i}] / 10}, {i, 10}];
Wolfram Language code: lm = LogitModelFit[data, x, x]

NonlinearModelFit 通常假设分布响应：

Wolfram Language code: nm = NonlinearModelFit[data, 1 / (1 + Exp[a + b x]), {a, b}, x]

拟合结果不相同：

Wolfram Language code: {Normal[lm], Normal[nm]}
Wolfram Language code: Plot[{lm[x], nm[x]}, {x, 1, 5}]

LogitModelFit 会将 TimeSeries 的时间戳用作变量：

Wolfram Language code: ts1 = TemporalData[TimeSeries, {{{0.7758532198866042, 0.20426632015371096, 0.2353690565215641, 0.4448009174525732, 0.5081575045542254, 0.5371908040104083, 0.6223323745794831, 0.669522447912184, 0.7204685251554224, 0.7633871517003976}}, {{0, 9, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];
Wolfram Language code: ts1["Times"]
Wolfram Language code: LogitModelFit[ts1, x, x]

对时间戳进行缩放，重新进行拟合：

Wolfram Language code: ts2 = TimeSeriesRescale[ts1, {.1, 2}]
Wolfram Language code: ts2["Times"]
Wolfram Language code: LogitModelFit[ts2, x, x]

对数值进行拟合：

Wolfram Language code: LogitModelFit[ts1["Values"], x, x]

对于多路径 TemporalData，LogitModelFit 按路径分别处理：

Wolfram Language code: LogitModelFit[TemporalData[Automatic, {{{0.009753347177267509, 0.18455899093641098, 0.20260886672737863, 0.37977270854029854, 0.45927203330240407, 0.5010683896315415, 0.6468842072138713, 0.7452632634563319, 0.8683334166368966, 0.9876532168951402}, ... 2138713, 0.7452632634563319, 0.8683334166368966, 0.9876532168951402}}, {{0, 9, 1}, {0.1, 2., 0.2111111111111111}}, 2, {"Continuous", 2}, {"Discrete", 2}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1], x, x]

可能存在的问题  (1)

在 0 到 1 范围外的响应对于逻辑模型可能没有效果：

Wolfram Language code: LogitModelFit[Range[5], x, x]
Wolfram Language code: LogitModelFit[Table[{i, 2i}, {i, 10}], x, x]
Wolfram Research (2008)，LogitModelFit，Wolfram 语言函数，https://reference.wolfram.com/language/ref/LogitModelFit.html （更新于 2025 年）.

文本

Wolfram Research (2008)，LogitModelFit，Wolfram 语言函数，https://reference.wolfram.com/language/ref/LogitModelFit.html （更新于 2025 年）.

CMS

Wolfram 语言. 2008. "LogitModelFit." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/LogitModelFit.html.

APA

Wolfram 语言. (2008). LogitModelFit. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/LogitModelFit.html 年

BibTeX

@misc{reference.wolfram_2026_logitmodelfit, author="Wolfram Research", title="{LogitModelFit}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/LogitModelFit.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_logitmodelfit, organization={Wolfram Research}, title={LogitModelFit}, year={2025}, url={https://reference.wolfram.com/language/ref/LogitModelFit.html}, note=[Accessed: 03-November-2026]}