WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Manipulator[x]

0から1の範囲に x を設定したマニピュレータを表す．

Manipulator[Dynamic[x]]

動的に更新された x の現行値を設定値とする．x の値はマニピュレータが動かされるとリセットされる．

Manipulator[x,{xmin,xmax}]

xminから xmaxまでの範囲のマニピュレータを表す．

Manipulator[x,{xmin,xmax,dx}]

ステップ dx でジャンプするマニピュレータを表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
AnimationDirection  
AnimationRate  
Appearance  
Show More Show More
AppearanceElements  
AutoAction  
ContinuousAction  
Enabled  
Exclusions  
ImageSize  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
履歴
引用書式

Manipulator

Manipulator[x]

0から1の範囲に x を設定したマニピュレータを表す．

Manipulator[Dynamic[x]]

動的に更新された x の現行値を設定値とする．x の値はマニピュレータが動かされるとリセットされる．

Manipulator[x,{xmin,xmax}]

xminから xmaxまでの範囲のマニピュレータを表す．

Manipulator[x,{xmin,xmax,dx}]

ステップ dx でジャンプするマニピュレータを表す．

詳細とオプション

  • Manipulator[…]は，ノートブック上に，インタラクティブに操作できる水平のスライダーと追加的なコントロールの集合として表示する．
  • Manipulator[Dynamic[x]]は，マニピュレータの設定が変更されると x の値をリセットする．Manipulator[x]はリセットしない． »
  • Manipulateはデフォルトにより，可能な値の範囲を持つように指定されている変数については，Manipulatorオブジェクトを生成する．
  • 次のオプションを与えることができる．
  • Appearance Automaticマニピュレータの全体的な外観
    AppearanceElements Automatic表示されたマニピュレータに含む要素
    BaselinePositionAutomatic周囲のテキストとの相対的な位置付け
    ContinuousAction Trueマニピュレータのコントロールが変更されたときに継続的に更新するかどうか
    Enabled Automaticマニピュレータを有効にするか，無効にする（灰色表示する）か
    ImageMargins0表示されたマニピュレータの周囲の余白
    ImageSize Automatic表示されたマニピュレータの全体的な画像サイズ
  • Appearanceの可能な設定値にはTiny，Small，Medium，Large等がある．この他に"Open"と"Closed"や{"Open",Small}等の組合せも使うことができる．
  • Appearance->"Labeled"とすると，マニュピュレータの現行値が編集可能なラベルとして表示される．
  • デフォルトのマニピュレータは"InputField"，"StepLeftButton"，"PlayPauseButton"，"StepRightButton"，"FasterSlowerButtons"，"DirectionButton"，"InlineInputField"の要素を含んでいる．これらの要素は任意の順序で，AppearanceElementsの設定として与えられるリストで指定することができる．
  • Manipulator[]はManipulator[0]と等価である．

例題

すべて開く すべて閉じる

例  (4)

デフォルトの初期状態とデフォルトではない初期状態：

Wolfram Language code: {Manipulator[], Manipulator[0.8]}

x の値を動的に変更する：

Wolfram Language code: {Manipulator[Dynamic[x]], Dynamic[x]}

範囲を指定する：

Wolfram Language code: {Manipulator[Dynamic[x], {3, 7}], Dynamic[x]}

刻み幅と範囲を指定する：

Wolfram Language code: {Manipulator[Dynamic[x], {3, 7, 0.5}], Dynamic[x]}

スコープ  (4)

整数値のみを使う：

Wolfram Language code: {Manipulator[Dynamic[x], {0, 100, 1}], Dynamic[x]}

記号的範囲を使う：

Wolfram Language code: {Manipulator[Dynamic[x], {0, t, 0.2t}], Dynamic[x]}

アニメーションのコントロールを見る：

Wolfram Language code: Manipulator[0.8, Appearance -> "Open"]

数値でもDynamicでもないパラメータはマニピュレータとしては表示されない：

Wolfram Language code: Manipulator[x]

オプション  (16)

AnimationDirection  (1)

プレイボタンがクリックされたときにアニメーションの方向を指定する：

Wolfram Language code: Table[Manipulator[0.4, Appearance -> "Open", AnimationDirection -> d], {d, {Forward, Backward, ForwardBackward}}]

AnimationRate  (1)

プレイボタンがクリックされたときのアニメーションの速度を変える：

Wolfram Language code: Table[Manipulator[0.4, Appearance -> "Open", AnimationRate -> r], {r, {0.01, 0.1, 0.5, 1}}]

Appearance  (3)

現行値を使う：

Wolfram Language code: Table[Manipulator[0.5, Appearance -> a], {a, {Tiny, Small, Medium, Large}}]

要素エリアを開くか閉じるか：

Wolfram Language code: Table[Manipulator[0.5, Appearance -> a], {a, {"Open", "Closed"}}]

2つの外観オプションを組み合せる：

Wolfram Language code: Manipulator[0.5, Appearance -> {"Open", Tiny}]

AppearanceElements  (3)

スライダーバーの下にどのコントロールを表示するか指定する：

Wolfram Language code: Manipulator[0.8, Appearance -> "Open", AppearanceElements -> {"StepRightButton", "PlayPauseButton", "FasterSlowerButtons"}]

すべての可能な外観の要素：

Wolfram Language code: Table[Manipulator[0.8, Appearance -> "Open", AppearanceElements -> {ae}], {ae, {"InputField", "StepLeftButton", "PlayPauseButton", "StepRightButton", "FasterSlowerButtons", "DirectionButton"}}]

外観要素のランダム選択：

Wolfram Language code: Manipulator[0.8, Appearance -> "Open", AppearanceElements -> RandomChoice[{"InputField", "StepLeftButton", "PlayPauseButton", "StepRightButton", "FasterSlowerButtons", "DirectionButton"}, 2]]

AutoAction  (2)

デフォルトで，マニピュレータはマウスのクリックに反応する：

Wolfram Language code: Manipulator[]

AutoActionを設定すると，マウスがマニピュレータの上を移動すると値が変わるようになる：

Wolfram Language code: Manipulator[AutoAction -> True]

ContinuousAction  (2)

デフォルトで，変数は継続的に更新される：

Wolfram Language code: {Manipulator[Dynamic[x]], Dynamic[x]}

マウスがリリースされたときだけ値を更新する：

Wolfram Language code: {Manipulator[Dynamic[x], ContinuousAction -> False], Dynamic[x]}

Enabled  (1)

デフォルトでManipulatorは有効になっている：

Wolfram Language code: Manipulator[0.5]

Enabled->Falseとすると，マニピュレータは無効となるが，現行状態が可視で残る：

Wolfram Language code: Manipulator[0.3, Enabled -> False]

Exclusions  (1)

範囲から値を除く：

Wolfram Language code: {Manipulator[Dynamic[x], {0, 5, 1}, Exclusions -> {2, 4}], Dynamic[x]}

ImageSize  (2)

予め設定された値のみを用いてサイズを制御する：

Wolfram Language code: Table[Manipulator[.3, ImageSize -> s], {s, {Tiny, Small, Medium, Large}}]//Column

あるいは，任意の値を使う：

Wolfram Language code: Column[Table[Manipulator[0.5, ImageSize -> i], {i, {50, 150, 300, 500}}]]

アプリケーション  (1)

振動数を調節する：

Wolfram Language code: DynamicModule[{f = 1}, {Manipulator[Dynamic[f], {0.25, 5}], Dynamic[Plot[Sin[f x], {x, -2π, 2π}]]}]

特性と関係  (1)

Manipulateは自動的にManipulatorのコントロールを使う：

Wolfram Language code: {Manipulate[a, {a, 0, 10}], Column[{Manipulator[Dynamic[b], {0, 10}], Dynamic[b]}]}
Wolfram Research (2007), Manipulator, Wolfram言語関数， https://reference.wolfram.com/language/ref/Manipulator.html.

テキスト

Wolfram Research (2007), Manipulator, Wolfram言語関数， https://reference.wolfram.com/language/ref/Manipulator.html.

CMS

Wolfram Language. 2007. "Manipulator." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Manipulator.html.

APA

Wolfram Language. (2007). Manipulator. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Manipulator.html

BibTeX

@misc{reference.wolfram_2026_manipulator, author="Wolfram Research", title="{Manipulator}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Manipulator.html}", note=[Accessed: 18-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_manipulator, organization={Wolfram Research}, title={Manipulator}, year={2007}, url={https://reference.wolfram.com/language/ref/Manipulator.html}, note=[Accessed: 18-June-2026]}