Maximize
詳細とオプション
- Maximizeは上限(シュープレマム),記号最適化,および大域的最適化(GO)としても知られている.
- Maximizeは与えられた制約条件に従って f の最大値を求める.
- Maximizeは,通常,制約条件下で可能な最大値を求めるために使われる.分野によっては,最適な戦略,最良適合,最適な構成等と呼ばれることがある.
- Maximizeは{fmax,{x->xmax,y->ymax,…}}の形式のリストを返す.
- f および cons が線形あるいは多項式の場合,Maximizeは常に大域的な最大値を求める.
- 制約条件 cons は以下の論理結合でよい.
-
lhs==rhs 等式 lhs>rhs, lhs≥rhs, lhs<rhs, lhs≤rhs 不等式 (LessEqual,…) lhsrhs, lhsrhs, lhsrhs, lhsrhs ベクトル不等式 (VectorLessEqual,…) Exists[…], ForAll[…] 量化条件 {x,y,…}∈rdom 領域指定 - Maximize[{f,cons},x∈rdom]は,事実上,Maximize[{f,cons∧x∈rdom},x]に等しい.
- x∈rdom については,Indexed[x,i]を使って別の座標に言及することができる.
- 次は,使用可能な領域 rdom である.
-
Reals 実数スカラー変数 Integers 整数スカラー変数 Vectors[n,dom]
のベクトル変数Matrices[{m,n},dom]
の行列変数ℛ 幾何領域
に制限されたベクトル変数 - デフォルトで,すべての変数が実数であるとみなされる.
- Maximizeは入力が厳密値の場合は厳密値を返す.入力が近似値の場合は自動的にNMaximizeを呼び出す.
- Maximizeは次の形式を返す.
-
{fmax,{xxmax,…}} 有限最大値 {-∞,{xIndeterminate,…}} 実行不可能,つまり,制約条件集合が空 {∞,{xxmax,…}} 非有界,つまり,f の値は任意に大きくできる - 最大値が制約条件で定義された領域外で無限小にあるいは漸近的にしか達しなかった場合,Maximizeは上限と最も近い指定可能な点を返す.
- いくつかの点で同じ最大値に達したとしても,その中の1つしか返されない.
- N[Maximize[…]]は,記号的には解けない最適化問題についてはNMaximizeを呼び出す.
- Maximize[f,x,WorkingPrecision->n]は n 桁精度で結果を計算する. »
例題
すべて開く すべて閉じる例 (5)
Maximize[-2x ^ 2 - 3x + 5, x]Maximize[1 - (x y - 3) ^ 2, {x, y}]Maximize[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]Maximize[a x ^ 2 + b x + c, x]Maximize[x + y, {x, y}∈Disk[]]Show[ContourPlot[x + y, {x, y}∈Disk[]], Graphics[{Red, PointSize[Large], Point[{x, y} /. Last[%]]}]]スコープ (36)
基本的な用法 (7)
Maximize[Sin[x] + Cos[x], x]Maximize[{x + 2y, x ^ 2 + 2y ^ 2 ≤ 3 && x + y == 2 && x ≥ 1}, {x, y}]Maximize[{x y, x ^ 2 + y ^ 2 ≤ 1 || (x + 1) ^ 2 + (y - 1) ^ 2 ≤ 2}, {x, y}]Maximize[{x + y, x ≤ y ^ 2}, {x, y}]Maximize[{x + y, x ^ 2 + y ^ 2 < 0}, {x, y}]Maximize[-Exp[x], x]Maximize[{{-1, -1}.v, {{1, 2}, {1, 0}}.v{3, -1}}, v]一変数の問題 (7)
Maximize[-x ^ 4 + 2x ^ 3 + 5x - 7, x]Maximize[{-3x ^ 2 - x + 9, 2x ^ 3 + 5x - 7 ≥ 0}, x]Maximize[-E ^ (2E ^ x) + Log[x ^ 2 + 1] + 20x, x]Maximize[{AiryAi[x + Sin[x]] + Cos[x ^ 2], -5 ≤ x ≤ 5}, x]Plot[AiryAi[x + Sin[x]] + Cos[x ^ 2], {x, -5, 5}, Epilog -> {Red, Point[{x /. %[[2]], %[[1]]}]}]Maximize[{BesselJ[2, x] / Gamma[x + 1] + (x + 1) ^ Sin[x], 0 ≤ x ≤ 10}, x]Plot[BesselJ[2, x] / Gamma[x + 1] + (x + 1) ^ Sin[x], {x, 0, 10}, Epilog -> {Red, Point[{x /. %[[2]], %[[1]]}]}]Maximize[{Sin[x], -1 / 2 ≤ Cos[x] ≤ 1 / 2}, x]Maximize[Sin[E ^ (x / 3) - 3 x] + 2 Cos[2 E ^ (x / 3) - 6 x + 1] ^ 2, x]Maximize[Sin[Sqrt[3] x] - Exp[Cos[3 x] + 2], x]Show[{Plot[Sin[Sqrt[3] x] - Exp[Cos[3 x] + 2], {x, -50, 50}], Graphics[{Red, Line[{{-50, %[[1]]}, {50, %[[1]]}}]}]}]Maximize[{Floor[x + UnitStep[x - 1]] - x, Ceiling[Abs[x]] < 5}, x]Maximize[SinhIntegral[DawsonF[x]], x]Maximize[BesselJ[7 / 4, x ^ 2 + x + 1], x]多変数の問題 (9)
Maximize[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]Maximize[{(2x + y - z) / (5x - 7y + 3), 0 ≤ x + y + z ≤ 1 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]Maximize[x ^ 2 - 2y - 1 - (x ^ 2 - 2y) ^ 2, {x, y}]Maximize[{x y - 1, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]Maximize[{1 - x ^ 2, x y ≥ 1}, {x, y}]Maximize[{x, x y ≤ 1}, {x, y}]Maximize[{x, x ^ 2 + y ^ 2 < 0}, {x, y}]Maximize[{-(x + 7)^2 - (y - 8)^2, Subscript[∀, z]Subscript[∃, w]3 z^2 w + (x + y) z^4 - 1 == (x^3 - x y + y^2 - 1) w^2}, {x, y}]Maximize[{-x - Sqrt[x + y] , x Sqrt[y] ≥ 1}, {x, y}]Maximize[{E ^ x + Log[y], x Log[y] == 2 && -10 ≤ x ≤ 10 && 1 / 10 ≤ y ≤ 10}, {x, y}]Maximize[{-Max[x - y, Abs[y]], Min[x - 2, x - y ^ 2] ≥ Abs[x y - 1]}, {x, y}]Maximize[v.{1, -1}, {VectorGreaterEqual[{{{1, 0}, {0, 1}, {-1, -2}}.v, {0, 0, -2}}, "ExponentialCone"]}, v]res = Maximize[{Log[x + y], (| | |
| ----- | ----- |
| x + y | 1 |
| 1 | x - y |)Underscript[, {"SemidefiniteCone", 2}]0 && 1 ≤ x ≤ 10 && -1 ≤ y ≤ 1}, {x, y}]Show[Plot3D[Log[x + y], {x, 1, 10}, {y, -1, 1}, ...], Graphics3D[{Red, PointSize[0.05], Point[{x, y, Log[x + y]} /. res[[2]]]}]]パラメトリック問題 (4)
Maximize[{8x + 7y, -6 x - 4 y ≤ 8 - 5 a - 7 b && 7 x + 5 y ≤ a + 4 b && -x + y ≤ 6 + 4a - 5 b && -4 x + 7 y ≤ -1 - 2 a - 7 b && 5 y ≤ 6 - 9 b}, {x, y}]max = %[[1]];Plot3D[max, {a, -3, 3}, {b, 0, 3}]Maximize[{-(x - 1) ^ 2 - (2y - 1) ^ 2, x + 2y ≤ a + b && 2x - y ≤ a - b + 1 && x - 2y ≤ 2a - b + 1}, {x, y}]max = %[[1]];Plot3D[max, {a, -5, 5}, {b, -5, 5}]Maximize[-x ^ 4 + a x ^ 2 + b, x]Maximize[{-x ^ 2 - y ^ 2, x ^ 3 + y ^ 2 == a}, {x, y}]整数上の最適化 (3)
Maximize[{x ^ 3 Log[x] - E ^ x, x > 0}, x, Integers]Maximize[Sin[2x] + Cos[3x], x, Integers]Show[{ListPlot[Table[Sin[2x] + Cos[3 x], {x, 0, 10000}]], Graphics[{Red, Line[{{0, %[[1]]}, {10000, %[[1]]}}]}]}]Maximize[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}, Integers]Maximize[{-x ^ 2 - x y + 1, x y ≥ 1}, {x, y}, Integers]領域上の最適化 (6)
ℛ = Cylinder[{{1, 2, 3}, {3, 2, 1}}, 1];Maximize[z, {x, y, z}∈ℛ]Graphics3D[{{Opacity[0.5], Green, ℛ}, {Red, PointSize[Large], Point[{x, y, z} /. Last[%]]}}]Subscript[ℛ, 1] = Disk[];
Subscript[ℛ, 2] = Line[{{-(1/2), -(1/2)}, {-(1/2), (1/2)}, {(1/2), (1/2)}, {(1/2), -(1/2)}, {-(1/2), -(1/2)}}];Maximize[(x - u)^2 + (y - v)^2, {{x, y}∈Subscript[ℛ, 1], {u, v}∈Subscript[ℛ, 2]}]//RootReduceGraphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[{{x, y}, {u, v}} /. Last[%]]}}]Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Circle[{(1/3), (1/3)}, {2 r, r}];Maximize[{r, {x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2]}, {r, x, y}]Graphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. Last[%]]Subscript[ℛ, 3] = Disk[{a, b}, {r, 2 - r}];Maximize[{r, ({0, 0} | {1, 0} | {0, 1})∈Subscript[ℛ, 3]}, {a, b, r}]Graphics[{{LightBlue, Subscript[ℛ, 3]} /. Last[%], {Red, Point[{{0, 0}, {1, 0}, {0, 1}}]}}]ℛ = Sphere[];Maximize[x.{1, 2, 3}, x∈ℛ]Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Disk[{2, 2}, 1];Maximize[EuclideanDistance[x, y], {x∈Subscript[ℛ, 1], y∈Subscript[ℛ, 2]}]//RootReduceGraphics[{{LightBlue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. Last[%]]オプション (2)
Method (1)
Maximizeが円筒代数分解を使うように指定する:
maxcad = Maximize[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}, Method -> "CAD"]maxlm = Maximize[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}, Method -> "LagrangeMultipliers"]maxdef = Maximize[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}]RootReduce[maxcad] === RootReduce[maxlm] === RootReduce[maxdef]WorkingPrecision (1)
TimeConstrained[Maximize[{x ^ 2 + y ^ 2 + z ^ 2, x ^ 2 - 3 x y z + 9 z ^ 2 + y ^ 2 == E && x y z ≤ Pi}, {x, y, z}], 60]WorkingPrecision->200とすると,厳密な最大値が得られるが,求まった最大値は正しくないかもしれない:
Maximize[{x ^ 2 + y ^ 2 + z ^ 2, x ^ 2 - 3 x y z + 9 z ^ 2 + y ^ 2 == E && x y z ≤ Pi}, {x, y, z}, WorkingPrecision -> 200]//Timingアプリケーション (13)
基本的なアプリケーション (3)
Maximize[{x y, 2x + 2y == 1 && x > 0 && y > 0}, {x, y}]triangle = a > 0 && b > 0 && c > 0 && a + b > c && a + c > b && b + c > a;
s = 1 / 2(a + b + c);Maximize[{Sqrt[s(s - a)(s - b)(s - c)], triangle && a + b + c == 1}, {a, b, c}]Maximize[ {v Sin[α] t - 5 t ^ 2, t ≥ 0 && 0 < Sin[α] ≤ 1 && v > 0}, t]Refine[%, 0 < Sin[α] ≤ 1 && v > 0]Maximize[{v Cos[α] t, v Sin[α] t - 5 t ^ 2 == 0 && t ≥ 0 && v > 0 && 0 ≤ Sin[α] ≤ 1 && 0 ≤ Cos[α] ≤ 1 && Sin[α] ^ 2 + Cos[α] ^ 2 == 1}, {Sin[α], Cos[α], t}]Refine[%, v > 0]幾何学的距離 (9)
領域 ℛ 内の点から指定された点 p までの最大距離と,最大距離を実現する点 q はMaximize[EuclideanDistance[p,q],q∈ℛ]で与えられる.単位Disk[]内の{1,1}からの最大距離と最も遠い点を求める:
p = {1, 1};
q = {q1, q2};
ℛ = Disk[];{d, qrul} = Maximize[EuclideanDistance[p, q], q∈ℛ]//RootReduceGraphics[{{StandardBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]標準的な単位シンプレックスSimplex[2]内の{1,3/4}からの最大距離と最も遠い点を求める:
p = {1, 3 / 4};
q = {q1, q2};
ℛ = Simplex[{{0, 0}, {1, 0}, {0, 1}}];{d, qrul} = Maximize[EuclideanDistance[p, q], q∈ℛ]Graphics[{{StandardBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]標準的な単位球Sphere[]内の点{1,1,1}からの,最大距離と最も遠くにある点を求める:
p = {1, 1, 1};
q = {q1, q2, q3};
ℛ = Sphere[];{d, qrul} = Maximize[EuclideanDistance[p, q], q∈ℛ]//RootReduceGraphics3D[{{Opacity[0.5], ℛ}, {Opacity[0.3], Green, Sphere[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]標準的な単位シンプレックスSimplex[3]内の{-1/3,1/3,1/3}からの最大距離と最も遠くにある点を求める:
p = {-1 / 3, 1 / 3, 1 / 3};
q = {q1, q2, q3};
ℛ = Simplex[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];{d, qrul} = Maximize[EuclideanDistance[p, q], q∈ℛ]Graphics3D[{{Opacity[0.5], ℛ}, {Opacity[0.3], Green, Sphere[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]領域 ℛ の直径は,ℛ 内の2点間の最大距離である.ℛ の直径と,この領域内で最も遠くにある点のペアは Maximize[EuclideanDistance[p,q],{p∈ℛ,q∈ℛ}]で計算することができる.Circle[]の直径と,この中で最も遠くにある点のペアを求める:
ℛ = Circle[];{d, pqrul} = Maximize[EuclideanDistance[p, q], {p∈ℛ, q∈ℛ}]Graphics[{{ℛ}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]標準的な単位シンプレックスSimplex[2]の直径と,この中で最も遠くにある点のペアを求める:
ℛ = Simplex[{{0, 0}, {1, 0}, {0, 1}}];{d, pqrul} = Maximize[EuclideanDistance[p, q], {p∈ℛ, q∈ℛ}]Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]標準単位立方体Cuboid[]の直径と,この中で最も遠くにある点のペアを求める:
ℛ = Cuboid[];{d, pqrul} = Maximize[EuclideanDistance[p, q], {p∈ℛ, q∈ℛ}]Graphics3D[{{Opacity[0.5], ℛ}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]最も遠くにある点 p∈ と q∈,および両者の距離は,Maximize[EuclideanDistance[p,q],{p∈,q∈}]で求めることができる.Disk[{0,0}]とRectangle[{3,3}]で最も遠くにある点と両者の距離を求める:
𝒫 = Disk[{0, 0}]; 𝒬 = Rectangle[{3, 3}];{d, pqrul} = Maximize[EuclideanDistance[p, q], {p∈𝒫, q∈𝒬}]//RootReduceGraphics[{{StandardBlue, EdgeForm[Gray], 𝒫, 𝒬}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]Line[{{0,0,0},{1,1,1}}]とBall[{5,5,0},1]で最も遠くにある点と両者の距離を求める:
𝒫 = Line[{{0, 0, 0}, {1, 1, 1}}]; 𝒬 = Ball[{5, 5, 0}, 1];{d, pqrul} = Maximize[EuclideanDistance[p, q], {p∈𝒫, q∈𝒬}]//RootReduceGraphics3D[{{𝒫, {Opacity[0.5], 𝒬}}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]幾何学的中心 (1)
ℛ⊆nが全次元の領域の場合,Chebyshev center は ℛ の最大内接球の中心である.ℛ の最大内接球の中心と半径はMaximize[-SignedRegionDistance[ℛ,p], p∈ℛ]で求めることができる.Rectangle[]についての最大内接球のChebyshev Centerと半径を求める:
ℛ = Rectangle[];p = {p1, p2};{d, prul} = Maximize[-SignedRegionDistance[ℛ, p], p∈ℛ]Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p /. prul, d]}, {Red, Point[p /. prul]}}]Triangle[]についてのChebyshev Centerと最大内接球の半径を求める:
ℛ = Triangle[];{d, prul} = Maximize[-SignedRegionDistance[ℛ, p], p∈ℛ]Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p /. prul, d]}, {Red, Point[p /. prul]}}]特性と関係 (4)
Maximizeは,目的関数の厳密な大域的最大値を返す:
f = Expand[-Product[(x - i)(x - 100 - i), {i, 5}]];Maximize[f, x]Plot[f, {x, 0, 100}, Epilog -> {PointSize[Medium], Green, Point[{x /. %[[2]], %[[1]]}]}]NMaximizeは,大域的最大値を数値的に求めようとするが,求まった最大値は極大値であることがある:
NMaximize[f, x]Plot[f, {x, 0.5, 5.5}, Epilog -> {PointSize[Medium], Red, Point[{x /. %[[2]], %[[1]]}]}]FindMaximumは初期値に依存して極大値を求める:
FindMaximum[f, {x, #}]& /@ {1, 50}Plot[f, {x, 0, 100}, Epilog -> {PointSize[Medium], {Red, Point[{x /. %[[1, 2]], %[[1, 1]]}]}, {Green, Point[{x /. %[[2, 2]], %[[2, 1]]}]}}]m = Maximize[{(x - 2) ^ 2 + (y - 3 / 2) ^ 2, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]x ^ 2 + y ^ 2 ≤ 1 /. m[[2]]RegionPlot[x ^ 2 + y ^ 2 ≤ 1, {x, -1.2, 2.2}, {y, -1.2, 2.2}, Epilog -> {PointSize[Medium], {Red, Point[{x, y} /. m[[2]]]}, {Green, Point[{2, 3 / 2}]}}]最大値に達せない場合,Maximizeは境界上の点を返すことがある:
Maximize[{(x - 2) ^ 2 + (y - 3 / 2) ^ 2, x ^ 2 + y ^ 2 < 1}, {x, y}]以下では y が無限大に近付くに従って目的関数が最大値に近付いている:
Maximize[{1 - x, x y == 1 && x > 0}, {x, y}]Maximizeは線形計画法問題を解くことができる:
Maximize[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]LinearProgrammingを使って,行列で表された同じ問題を解くことができる:
c = {2, 3, -1};
m = {{1, 1, 1}, {1, 1, 1}, {1, -1, 1}, {1, -1, 1}, {1, -1, -1}};
b = {{1, 1}, {2, -1}, {1, 1}, {2, -1}, {3, 0}};LinearProgramming[-c, m, b, -Infinity]c.%RegionBoundsを使って境界ボックスを計算する:
f = x^4 + 3 x^2 y + 2 x^2 y^2 - y^3 + y^4 ≤ 0;
ℛ = ImplicitRegion@@{f, {x, y}}RegionBounds[ℛ]MaximizeおよびMinimizeを使って同じ境界を計算する:
{{x1, x2}, {y1, y2}} = {Minimize[#, {x, y}∈ℛ][[1]], Maximize[#, {x, y}∈ℛ][[1]]}& /@ {x, y}Show[{Graphics[{LightBlue, Rectangle[{x1, y1}, {x2, y2}]}], RegionPlot[f, {x, x1 - 1, x2 + 1}, {y, y1 - 1, y2 + 1}]}]考えられる問題 (1)
Maximizeの入力に使われる関数はすべて実数値を持たなければならない:
Maximize[{-x - y, Sqrt[x] - Sqrt[y] == 0}, {x, y}]{Sqrt[x] - Sqrt[y] == 0, Sqrt[x], Sqrt[y]} /. {x -> -1, y -> -1}テクニカルノート
-
▪
- 不等式 ▪
- 最小化と最大化 ▪
- 制約条件付き最適化 ▪
- 制約条件のない最適化 ▪
- 実装に関するノート: 代数と解析
履歴
2003 で導入 (5.0) | 2014 で更新 (10.0) ▪ 2021 (12.3)
テキスト
Wolfram Research (2003), Maximize, Wolfram言語関数, https://reference.wolfram.com/language/ref/Maximize.html (2021年に更新).
CMS
Wolfram Language. 2003. "Maximize." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/Maximize.html.
APA
Wolfram Language. (2003). Maximize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Maximize.html
BibTeX
@misc{reference.wolfram_2026_maximize, author="Wolfram Research", title="{Maximize}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Maximize.html}", note=[Accessed: 15-November-2026]}
BibLaTeX
@online{reference.wolfram_2026_maximize, organization={Wolfram Research}, title={Maximize}, year={2021}, url={https://reference.wolfram.com/language/ref/Maximize.html}, note=[Accessed: 15-November-2026]}