WOLFRAM

Wolfram 语言与系统参考资料中心

N[expr]

给出 expr 的数值值.

N[expr,n]

尝试给出具有 n 位精度的结果.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数学常数  
普通表达式  
机器精度和相应精度  
数据对象和特定规则  
定义特定规则  
推广和延伸  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

N

N[expr]

给出 expr 的数值值.

N[expr,n]

尝试给出具有 n 位精度的结果.

更多信息

  • 除非 expr 中的数是精确的，或者具有足够高的精度，否则 N[expr,n] 可能无法给出具有 n 位精度的结果.
  • N[expr,n] 可能在内部计算时会超过 n 位精度.
  • $MaxExtraPrecision 指定将会在内部使用到的最大超额精度.
  • 精度 n 以 10 进制数给出；它不必是一个整数.
  • n 必须在 $MinPrecision 和 $MaxPrecision 之间. $MaxPrecision 可以被设置为 Infinity.
  • n 可以小于 $MachinePrecision.
  • N[expr] 给出一个机器精度数，只要它的大小在 $MinMachineNumber 和 $MaxMachineNumber 之间.
  • N[expr] 等价于 N[expr,MachinePrecision].
  • N[0] 给出具有机器精度的数 0..
  • N 将所有非零数转化为 Real 或 Complex 形式.
  • N 把它所遇到的任何函数的每个参数依次转换成数值形式，除非该函数的头具有一个诸如 NHoldAll 的属性.
  • 你可以使用 N[f[args]]:=value 和 N[f[args],n]:=value 来定义函数的数值值.
  • N[expr,{p,a}] 尽可能产生精度最多 p、准确度最多 a 的结果.
  • N[expr,{Infinity,a}] 尽可能产生准确度 a 的结果.
  • N[expr,{Infinity,1}] 尽可能求出 expr 整数部分的近似值.

范例

打开所有单元 关闭所有单元

基本范例  (3)

数值运算：

Wolfram Language code: N[1 / 7]

50 位精度的数值运算：

Wolfram Language code: N[1 / 7, 50]

对机器精度的输入，结果总是机器精度：

Wolfram Language code: N[Gamma[3.3], 50]

对精确的输入，结果可以达到指定的精度：

Wolfram Language code: N[Gamma[33 / 10], 50]

范围  (20)

数学常数  (4)

将数学常数计算到任意精度：

Wolfram Language code: N[Pi, 50]
Wolfram Language code: N[Khinchin, 50]

大型整数的近似值：

Wolfram Language code: N[1000!]
Wolfram Language code: N[2 ^ 1000000]

复数结果：

Wolfram Language code: N[ArcSin[3]]

用 NumericQ 可以检验更复杂一些的符号式数学常量：

Wolfram Language code: c = Exp[Sin[Sqrt[2]] + BesselJ[3, 4]];
Wolfram Language code: NumericQ[c]

在通常情况下，NumericQ 表达式表示可以计算到任意精度的数：

Wolfram Language code: N[c]
Wolfram Language code: N[c, 47]

普通表达式  (3)

数值计算矩阵元：

Wolfram Language code: m = {{Cos[1], Sin[1]}, {-Sin[1], Cos[1]}};
Wolfram Language code: N[m]

数值计算符号表达式的数值部分：

Wolfram Language code: N[(Pi + 2 x) / (E - x), 20]

将多项式系数变为数值值：

Wolfram Language code: poly = Expand[Product[(x - i), {i, 10}]]
Wolfram Language code: N[poly]

机器精度和相应精度  (4)

N[e] 通常用机器数替代并计算结果：

Wolfram Language code: e[h_] = Cos[1] - (Sin[1 + h] - Sin[1 - h]) / (2 h)
Wolfram Language code: N[e[10 ^ -12]]

这等价于机器数的表达式：

Wolfram Language code: e[10. ^ -12]

在差商误差的对数-对数图上可清楚显示机器舍入误差：

Wolfram Language code: ListLogLogPlot[h = 10 ^ -k;Table[{h, Abs[N[e[h]]]}, {k, 0, 16}]]

当 p 不是 MachinePrecision 时，N[e,p] 用任意精度数自适应地进行计算：

Wolfram Language code: e[h_] = Cos[1] - (Sin[1 + h] - Sin[1 - h]) / (2 h);
Wolfram Language code: N[e[10 ^ -12], 20]

用自适应精度，差商误差与理论值匹配：

Wolfram Language code: Show[ListLogLogPlot[h = 10 ^ -k;Table[{h, Abs[N[e[h], 20]]}, {k, 0, 16}]], LogLogPlot[Cos[1] h^2 / 6, {h, 10 ^ -16, 1}]]

自适应精度控制对超额精度有一个默认的界限，$MaxExtraPrecision：

Wolfram Language code: N[1 - Sqrt[1 - Exp[-1000]], 20]

达到界限时，您可以增加 $MaxExtraPrecision 来解决问题：

Wolfram Language code: Block[{$MaxExtraPrecision = 500}, N[1 - Sqrt[1 - Exp[-1000]], 20]]

N 不会提高输入中近似数的精度：

Wolfram Language code: e = 1. + 2`20 x + 3`30x ^ 2
Wolfram Language code: N[e, 25]

结果的精度和输入相同：

Wolfram Language code: {Precision[%], Precision[e]}

您可以用 SetPrecision 增加输入表达式的精度：

Wolfram Language code: SetPrecision[e, 20]

数据对象和特定规则  (5)

N 不会影响明确的数值幂：

Wolfram Language code: N[x ^ (3 / 2)]

但会改变底数：

Wolfram Language code: N[Pi ^ x]

如果幂不是 NumericQ，它会改变：

Wolfram Language code: N[E ^ (x + Pi)]
Wolfram Language code: NumericQ[x + Pi]

对 SparseArray 对象的处理是以所表示的数组为基础的：

Wolfram Language code: s = SparseArray[{{i_, j_} /; Abs[i - j] ≤ 1 -> 3Abs[i - j] - 2}, {5, 5}]
Wolfram Language code: ns = N[s]
Wolfram Language code: {MatrixForm[s], MatrixForm[ns]}

通常，N[Normal[s]] 恒等于 Normal[N[s]]：

Wolfram Language code: N[Normal[s]] === Normal[N[s]]

类似 InterpolatingFunction 的数据对象有特定的规则以使得仅仅数据受到影响：

Wolfram Language code: ifun = ListInterpolation[{0, 1, 1, 0}, {{0, 1}}]
Wolfram Language code: nifun = N[ifun]

仅对相关的数据做了改变，新函数用机器数：

Wolfram Language code: {ifun[1 / 2], nifun[1 / 2]}

类似 Integrate 的运算适当时用相应 N-函数：

Wolfram Language code: int = Integrate[Sinc[Exp[-1 / x]], {x, 0, 1}]
Wolfram Language code: N[int]

下面用 NIntegrate：

Wolfram Language code: NIntegrate[Sinc[Exp[-1 / x]], {x, 0, 1}]

对于较高的精度需求，数值算法花费较多的时间或需要调整：

Wolfram Language code: Timing[N[int, 20]]

在这个例子中，直接使用 NIntegrate 或许更好一些：

Wolfram Language code: Timing[NIntegrate[Sinc[Exp[-1 / x]], {x, 0, 1}, WorkingPrecision -> 20]]

对多数表达式，N 影响 FullForm 形式中的树：

Wolfram Language code: e = 2 - x;
Wolfram Language code: N[e]

1. 出现在 x 之前起因于 e 的表示方式：

Wolfram Language code: FullForm[e]

e 中的整数转换为机器数：

Wolfram Language code: FullForm[N[e]]

定义特定规则  (4)

用 NHoldAll 属性避免一个加指标变量受到 N 的影响：

Wolfram Language code: SetAttributes[x, NHoldAll]

此时 N 仅影响系数：

Wolfram Language code: N[1 + 2 x[1] + 3 x[2] + 4 x[1] x[2]]

若没有这个设置， N 同时影响到指标：

Wolfram Language code: N[1 + 2y[1] + 3 y[2] + 4 y[1] y[2]]

定义一个等于 的数值常量：

Wolfram Language code: N[pit] := N[Pi / 2]

在精确符号表达式中，常量不计算：

Wolfram Language code: Sin[pit]

在 N 中则计算：

Wolfram Language code: N[%]

加一个对任意精度或准确度都适用的定义：

Wolfram Language code: N[pit, pa_] := N[Pi / 2, pa]

以准确度 20 数值计算一个表达式：

Wolfram Language code: N[π - 2 pit, {∞, 20}]

定义一个函数，表示实数根 ，其中 为正， 为正整数：

Wolfram Language code: nthroot[x_ ? InexactNumberQ /; Positive[x], n_Integer /; Positive[n]] := FixedPoint[((n - 1) # ^ n + x) / (n # ^ (n - 1))&, N[1, Precision[x]]]

用 NHoldRest 避免它的第二个自变量转换为实数：

Wolfram Language code: SetAttributes[nthroot, NHoldRest]

2 的立方根的精确表示：

Wolfram Language code: crt = nthroot[2, 3]

机器数近似值：

Wolfram Language code: N[crt]

47 位数的近似值：

Wolfram Language code: N[crt, 47]

定义一个数据对象，以稀疏形式 表示一个多项式 {{c_(1),p_(1)},...}：

Wolfram Language code: spoly[cp_][x_] := Module[{c, n, p, y}, {p, c} = Transpose[SortBy[cp, Last]]; n = p[[-1]]; y = c[[-1]]; Do[y = c[[k]] + x ^ (n - p[[k]]) * y;n = p[[k]], {k, Length[p] - 1, 1, -1}]; If[n > 0, y *= x ^ n]; y]

注意要确保 N 仅影响系数，而不是幂：

Wolfram Language code: N[e : spoly[cp_], pa_] := Module[{p, c, nc}, {c, p} = Transpose[cp]; nc = N[c, pa]; If[nc === c, e, spoly[Transpose[{nc, p}]]]]

要使规则有效，需要阻止默认对参变量的 N 计算：

Wolfram Language code: SetAttributes[spoly, NHoldAll]

多项式 的表示：

Wolfram Language code: sp = spoly[{{1, 1}, {2, 2}, {3, 4}, {4, 8}}]
Wolfram Language code: {sp[x], Expand[sp[x]]}

获得具有近似实数系数的表示：

Wolfram Language code: nsp = N[sp]

在 处的计算：

Wolfram Language code: nsp[π]

推广和延伸  (3)

5 位数准确度和任意精度：

Wolfram Language code: N[Pi ^ 10, {Infinity, 5}]

1 位准确度，仅对应整数部分：

Wolfram Language code: N[Pi ^ 10, {Infinity, 1}]

获得 20 位精度或 30 位准确度：

Wolfram Language code: val = N[1 - Sqrt[1 + Exp[-1000]], {20, 30}]
Wolfram Language code: {Accuracy[val], Precision[val]}

属性和关系  (3)

N[e] 的结果通常有精度 MachinePrecision：

Wolfram Language code: N[Exp[Sin[1000]]]
Wolfram Language code: Precision[%]

如果结果对于机器数来说过大，精度可能不同：

Wolfram Language code: ne = N[Exp[1000]]
Wolfram Language code: Precision[%]

N[e,p] 的结果通常有 Precision 等于 p：

Wolfram Language code: N[Exp[Sin[1000]], 47]
Wolfram Language code: Precision[%]

如果不能达到，Wolfram 语言将给出信息：

Wolfram Language code: N[1 - Sqrt[1 - Exp[-1000]], 20]

通常增加 $MaxExtraPrecision 将解决这个问题：

Wolfram Language code: Block[{$MaxExtraPrecision = 500}, N[1 - Sqrt[1 - Exp[-1000]], 20]]
Wolfram Language code: Precision[%]

对于隐藏的零，不能达到正精度，因此您需要使用准确度：

Wolfram Language code: N[1 / GoldenRatio + 1 - GoldenRatio, 20]
Wolfram Language code: N[1 / GoldenRatio + 1 - GoldenRatio, {∞, 20}]
Wolfram Language code: Accuracy[%]

N[e,{∞,a}] 的结果通常有 Accuracy 等于 a：

Wolfram Language code: N[Exp[100], {∞, -10}]
Wolfram Language code: Accuracy[%]

如果不能达到，Wolfram 语言将给出信息：

Wolfram Language code: N[10000000000(Exp[100] - Exp[999999999999 / 10000000000]), {∞, 20}]

通常增加 $MaxExtraPrecision 将解决这一问题：

Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[10000000000(Exp[100] - Exp[999999999999 / 10000000000]), {∞, 20}]]
Wolfram Language code: Accuracy[%]

巧妙范例  (1)

的位数的一个展示：

Wolfram Language code: Style[N[Pi, 10 ^ 5], 4]
Wolfram Research (1988)，N，Wolfram 语言函数，https://reference.wolfram.com/language/ref/N.html （更新于 2003 年）.

文本

Wolfram Research (1988)，N，Wolfram 语言函数，https://reference.wolfram.com/language/ref/N.html （更新于 2003 年）.

CMS

Wolfram 语言. 1988. "N." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2003. https://reference.wolfram.com/language/ref/N.html.

APA

Wolfram 语言. (1988). N. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/N.html 年

BibTeX

@misc{reference.wolfram_2026_n, author="Wolfram Research", title="{N}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/N.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_n, organization={Wolfram Research}, title={N}, year={2003}, url={https://reference.wolfram.com/language/ref/N.html}, note=[Accessed: 03-November-2026]}